Nhờ mọi người giúp tôi đoạn code coppy sau với ! (1 người xem)

[nam0099]

Đây là đoạn tôi dùng để mở đến 1 Workbook nguồn coppy giá trị 1 vùng dữ liệu của sheet "CUOI NAM" sang 1 Workbook đích vào Sheet "DIEM5A" . Nhưng khi chạy nó không coppy đc dữ liệu sang mong mọi người giúp đỡ.
Sub connect_bangdiem5A()
Dim fname
On Error Resume Next
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
fname = Application.GetOpenFilename("Excel Files (*.xls*), *.xls")
With Workbooks.Open(fname, , , , "password") ' PW can dat trong dau ngoac kep, neu ko co password thi de trong
Sheets("CUOI NAM").Range("A6:AP60").Value = ThisWorkbook.Sheets("DIEM5A").Range("A6").Value
.Close False
End With
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub
Đây là đoạn tôi sưu tầm về và chỉnh sửa. Tôi vẫn chưa biết nhiều về VBA mong mọi người giúp đỡ.

 

[giaiphap]

Ngay dòng này đã có vấn đề rồi.

Sheets("CUOI NAM").Range("A6:AP60").Value = ThisWorkbook.Sheets("DIEM5A").Range("A6").Value

Bạn up file lên đây để mọi người biết mặt mũi nó ra sao mới giúp được.

 

[nam0099]

Điều tôi muốn là bấm nút chạy đoạn code này nó sẽ coppy vùng A6:AP60 ở sheet CUOI NAM trong Workbook "Lớp 5A" sang sheet DIEM5A của Workbook T_HOP coppy giá trị thôi không coppy công thức. Tôi gửi tệp đinh kèm mong mọi người giúp đỡ.

 

[giaiphap]

Bạn sửa code lại thế này thử xem.

Sub connect_5A()
Dim fname
'On Error Resume Next
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
fname = Application.GetOpenFilename("Excel Files (*.xls*), *.xls")
If fname <> False Then
    Application.DisplayAlerts = False
    With Workbooks.Open(fname, , , , "password") ' PW can dat trong dau ngoac kep, neu ko co password thi de trong
        ThisWorkbook.Sheets("DIEM5A").Range("A6:AP60").Value = .Sheets("CUOI NAM").Range("A6:AP60").Value
        .Close False
    End With
    Application.DisplayAlerts = True
End If
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

 

[nam0099]

Ôi! tuyệt vời quá đc rồi bạn ơi. Từ cái code này giúp GV chúng tôi giảm được nhiều phiền hà trong công việc lắm. Cảm ơn bạn nhiều!!!

 

[giaiphap]

Ôi! tuyệt vời quá đc rồi bạn ơi. Từ cái code này giúp GV chúng tôi giảm được nhiều phiền hà trong công việc lắm. Cảm ơn bạn nhiều!!!

Tôi cũng hứng thú với những cái thuộc về lĩnh vực giáo dục (Do mình cùng nghề).