Nhờ giúp ListBox lấy 5 dòng cuối và nhiều cột

[thomtv]

Do kiến thức hạn hẹp nên chỉ làm được listbox 5 dòng 1 cột.
Nhờ các bạn giúp đoạn code sau: thành 5 dòng nhiều cột.
Private Sub tao_ArrTen()
Dim i As Long
Last = Cells(Rows.Count, "B").End(xlUp).Row
For i = Last To 6 Step -1
With Me.ListBox1
.AddItem Cells(i, "B").Value
End With
If Me.ListBox1.ListCount = 5 Then Exit Sub
Next i
End Sub
Lấy từ cột B đến cột N

 

[snow25]

Do kiến thức hạn hẹp nên chỉ làm được listbox 5 dòng 1 cột.
Nhờ các bạn giúp đoạn code sau: thành 5 dòng nhiều cột.
Private Sub tao_ArrTen()
Dim i As Long
Last = Cells(Rows.Count, "B").End(xlUp).Row
For i = Last To 6 Step -1
With Me.ListBox1
.AddItem Cells(i, "B").Value
End With
If Me.ListBox1.ListCount = 5 Then Exit Sub
Next i
End Sub
Lấy từ cột B đến cột N

Thử.

Private Sub tao_ArrTen()
Dim i As Long
    last = Cells(Rows.Count, "B").End(xlUp).Row
    Me.ListBox1.List = Cells(last - 4, 2).Resize(5, 13).Value
End Sub

 

[thomtv]

Thử.

Private Sub tao_ArrTen()
Dim i As Long
    last = Cells(Rows.Count, "B").End(xlUp).Row
    Me.ListBox1.List = Cells(last - 4, 2).Resize(5, 13).Value
End Sub

Bạn có thể giúp mình thêm đoạn code: khi add vào listbox chỉ add những dòng có dữ liệu, các dòng trống không add lên listbox.

 

[thomtv]

Bạn có thể giúp mình thêm đoạn code: khi add vào listbox chỉ add những dòng có dữ liệu, các dòng trống không add lên listbox.

Bạn có thể giúp mình thêm đoạn code: khi add vào listbox chỉ add những dòng có dữ liệu, các dòng trống không add lên listbox.

 

[snow25]

Bạn có thể giúp mình thêm đoạn code: khi add vào listbox chỉ add những dòng có dữ liệu, các dòng trống không add lên listbox.

Cả bảng hay là chỉ 5 dòng cuối nhỉ bạn.

 

[ppc0312]

Bạn có thể giúp mình thêm đoạn code: khi add vào listbox chỉ add những dòng có dữ liệu, các dòng trống không add lên listbox.

Chắc biết sơ về code rồi, nên xem hướng dẫn sau:
- Lọc từng dòng ngược vào Array, lấy 5 dòng có số liệu
- Gán Array đó cho List box, .List()

 

[thomtv]

Cả bảng hay là chỉ 5 dòng cuối nhỉ bạn.

Cả bảng luôn bạn ah.
Mình còn gà VBA nên nhờ các bạn viết và hướng dẫn, để mình được học hỏi thêm ạ.
cảm ơn các bạn đã quan tâm.

 

[snow25]

Cả bảng luôn bạn ah.
Mình còn gà VBA nên nhờ các bạn viết và hướng dẫn, để mình được học hỏi thêm ạ.
cảm ơn các bạn đã quan tâm.

Thử.

Private Sub tao_ArrTen()
Dim i As Long, arr, kq, a As Long, j As Long, lr As Long
    With Sheets("GP text")
         lr = .Range("B" & Rows.Count).End(xlUp).Row
         arr = .Range("b4:N" & lr).Value
         ReDim kq(1 To UBound(arr), 1 To UBound(arr, 2))
         For i = 1 To UBound(arr)
             If Len(arr(i, 1)) > 0 Then
                a = a + 1
                For j = 1 To UBound(arr, 2)
                    kq(a, j) = arr(i, j)
                Next j
            End If
        Next i
        If a Then Me.ListBox1.List = kq
   End With
End Sub

 

[thomtv]

Thử.

Cảm ơn bạn rất nhiều Code chạy tốt nhưng vẫn còn vần đề là lấy 5 dòng cuối ạ.
Mong bạn giúp đỡ lần nửa.

 

[snow25]

for i=ubound(ARR)-5 TO UBOUND(ARR)

Cảm ơn bạn rất nhiều Code chạy tốt nhưng vẫn còn vần đề là lấy 5 dòng cuối ạ.
Mong bạn giúp đỡ lần nửa.

Bạn sửa dòng.

 

[VetMini]

for i=ubound(ARR)-5 TO UBOUND(ARR)

Từ A-5 đến A thì khoảng cách là 5, nhưng số phần tử là 6.

 

[ppc0312]

Từ A-5 đến A thì khoảng cách là 5, nhưng số phần tử là 6.

Vậy thì nên là A-1 đến A-5?

 

[VetMini]

Vậy thì nên là A-1 đến A-5?

n phần tử kể từ A trở lên là A0, A1, A2, ... An-1
n phần tử kể từ A trở xuống là A0, A-1, A-2, A-n+1

Tại sao? Tại vì ta tính luôn cả A (tức A0)

 

[CHAOQUAY]

for i=ubound(ARR)-5 TO UBOUND(ARR)

Bạn sửa dòng.

Chắc có lẽ mỏi tay nên -5+1 lại gõ đến -5 thì nghỉ mệt đây mà

 

[thomtv]

Thử.

Private Sub tao_ArrTen()
Dim i As Long, arr, kq, a As Long, j As Long, lr As Long
    With Sheets("GP text")
         lr = .Range("B" & Rows.Count).End(xlUp).Row
         arr = .Range("b4:N" & lr).Value
         ReDim kq(1 To UBound(arr), 1 To UBound(arr, 2))
         For i = 1 To UBound(arr)
             If Len(arr(i, 1)) > 0 Then
                a = a + 1
                For j = 1 To UBound(arr, 2)
                    kq(a, j) = arr(i, j)
                Next j
            End If
        Next i
        If a Then Me.ListBox1.List = kq
   End With
End Sub

Nhờ các bạn giúp tiếp đoạn Code, xóa các dòng trống trong listbox "hình và file đính kèm"

Xin cảm ơn

 

[snow25]

Nhờ các bạn giúp tiếp đoạn Code, xóa các dòng trống trong listbox "hình và file đính kèm"
View attachment 242426
Xin cảm ơn

Sửa thành thế này bạn nhé.

Sub tao()
Dim i As Long, arr, kq, a As Long, j As Long, lr As Long
    With Sheet1
         lr = .Range("B" & Rows.Count).End(xlUp).Row
         arr = .Range("b3:G" & lr).Value
         UserForm1.ListBox1.Clear
         For i = 1 To UBound(arr)
             If Len(arr(i, 1)) > 0 Then
                UserForm1.ListBox1.AddItem arr(i, 1)
                For j = 1 To UBound(arr, 2) - 1
                    UserForm1.ListBox1.List(a, j) = arr(i, j + 1)
                Next j
                a = a + 1
            End If
        Next i
   End With
End Sub

 

[Hai Lúa Miền Tây]

Nhờ các bạn giúp tiếp đoạn Code, xóa các dòng trống trong listbox "hình và file đính kèm"
View attachment 242426
Xin cảm ơn

Bạn thử code sau nhé:

Private Sub CommandButton1_Click()
    Dim cn As Object, rst As Object
    Set cn = CreateObject("ADODB.Connection")
    Set rst = CreateObject("ADODB.Recordset")
    cn.Open ("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0;HDR=NO""")
    rst.Open ("Select * From [Sheet1$B3:G100] where F1 is not null"), cn
    ListBox1.Column = rst.getrows

End Sub

Hoặc :

Private Sub CommandButton1_Click()
    With CreateObject("ADODB.Connection")
        .Open ("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0;HDR=NO""")
        ListBox1.Column = .Execute("Select * From [Sheet1$B3:G100] where F1 is not null").getrows
    End With
End Sub

Điều kiện là cột B không có cell rỗng.