Liệt kê số hóa đơn theo từng ngày (1 người xem)

[AnhThu-1976]

Các Thầy và anh/Chị giúp em như sau:
Tại sheet NhapMua, em muốn liệt kê số hóa đơn (cột F) theo ngày (cột G) với điều kiện, Nếu tại cột H có chữ "Xóa" thì không liệt kê số hóa đơn đó
Kết quả chạy code em muốn giống như kết quả ở Sheet KQ
Em cảm ơn!

 

[PacificPR]

Các Thầy và anh/Chị giúp em như sau:
Tại sheet NhapMua, em muốn liệt kê số hóa đơn (cột F) theo ngày (cột G) với điều kiện, Nếu tại cột H có chữ "Xóa" thì không liệt kê số hóa đơn đó
Kết quả chạy code em muốn giống như kết quả ở Sheet KQ
Em cảm ơn!

Bác dùng tạm cái này xem:

Sub LocHD()
    Dim Dic As Object, Tem As String
    Dim sArr(), dArr()
    Dim i As Long, K As Long
Set Dic = CreateObject("Scripting.Dictionary")
With Sheets("NhapBan")
    sArr = .Range("F18", .Range("F65535").End(3)).Resize(, 3).Value
End With
ReDim dArr(1 To UBound(sArr), 1 To 2)
For i = 1 To UBound(sArr)
    If sArr(i, 3) <> "X" & ChrW$(243) & "a" Then
        Tem = sArr(i, 2)
        If Not Dic.Exists(Tem) Then
            K = K + 1
            Dic.Add Tem, K
            dArr(K, 1) = sArr(i, 2)
            dArr(K, 2) = sArr(i, 1)
        Else
            dArr(Dic.Item(Tem), 2) = dArr(Dic.Item(Tem), 2) & ";" & sArr(i, 1)
        End If
    End If
Next i
With Sheets("KQ")
    With .Range("A5:B" & .Range("A65535").End(3).Row)
        .ClearContents
        .Borders.LineStyle = xlNone
    End With
    .Range("A5").Resize(K, 2) = dArr
    With .Range("A5").Resize(K, 2)
        .Borders.LineStyle = xlContinuous
        .Borders(xlInsideHorizontal).Weight = xlHairline
    End With
End With
End Sub

 

[AnhThu-1976]

Cảm ơn bạn rất nhiều