Lọc mọi người trong cùng hộ gđ (1 người xem)

[cuonghoa176]

E cần in GCN hộ nghèo từ một DS gồm 1000 hộ. Các thông tin cần xuất ra: Tên chủ hộ; STT hộ: các thành viên trong hộ, các pác có cách nào giúp em với, e xin chân thành cảm ơn!

 

[nhat chi mai]

Cứu!..C.ứ..u e vo..i!
E cần in GCN hộ nghèo từ một DS gồm 1000 hộ. Các thông tin cần xuất ra: Tên chủ hộ; STT hộ: các thành viên trong hộ, các pác có cách nào giúp em với, e xin chân thành cảm ơn!

Dùng filter đi bạn.
(tớ chỉ lọc được danh sách hộ nghèo thôi, còn cái nhập bảng chi tiết nhờ "Anh NGHĨA", Anh ý có cách lọc mà dùng Data validation hay lắm...) , tớ làm nhưng nó chưa có nhảy sang sheet bên được.

 

[Hoàng Trọng Nghĩa]

Dùng filter đi bạn.
(tớ chỉ lọc được danh sách hộ nghèo thôi, còn cái nhập bảng chi tiết nhờ "Anh NGHĨA", Anh ý có cách lọc mà dùng Data validation hay lắm...) , tớ làm nhưng nó chưa có nhảy sang sheet bên được.

Trời, bài này mà dùng Data Validation chắc khiếp quá! Gõ số còn nhanh hơn.

Cứu!..C.ứ..u e vo..i!
E cần in GCN hộ nghèo từ một DS gồm 1000 hộ. Các thông tin cần xuất ra: Tên chủ hộ; STT hộ: các thành viên trong hộ, các pác có cách nào giúp em với, e xin chân thành cảm ơn!

Cách làm như sau:

1) Chèn một cột phụ C tại sheet DS HO NGHEO, có công thức tại ô C7 là =IF(B7="",C6,B7) , fill từ trên xuống đến hết tên, nhằm ghi lại số hộ của từng thành viên trong 1 hộ.

2) Đặt 3 name động:

2.1) Name DataDS:

=OFFSET('DS HO NGHEO'!$C$7,-6,0,COUNTA('DS HO NGHEO'!$C$7:$C$65536)+6,8)

2.2) Name SttHo:

=OFFSET('DS HO NGHEO'!$C$7,0,0,COUNTA('DS HO NGHEO'!$C$7:$C$65536),)

2.3) Name Filter:

=IF(SttHo=GCN!$D$13,ROW(SttHo),"")

3) Viết công thức tại sheet GCN:

3.1) Cột STT:

=IF(B17="","",MAX($A$16:A16)+1)

3.2) Cột Họ và tên:

=IF(ROW(1:1)>COUNT(Filter),"",INDEX(DataDS,SMALL(Filter,ROW(1:1)),2))

3.3) Cột Năm sinh:

=IF(B17="","",INDEX(DataDS,SMALL(Filter,ROW(1:1)),3))

3.4) Cột Giới tính:

=IF(B17="","",INDEX(DataDS,SMALL(Filter,ROW(1:1)),4))

3.5) Cột Quan hệ với chủ hộ:

=IF(B17="","",INDEX(DataDS,SMALL(Filter,ROW(1:1)),7))

3.6) Tại ô C10 (Họ tên chủ hộ), dĩ nhiên nó là hàng đầu của cột Họ và tên, nên ta chỉ bằng hàng đó thôi: =$B$17

Rồi, bây giờ bạn chỉ việc gõ số hộ vào ô D13 để thưởng thức các món ăn chơi của Name!

Nói đến Name mới nói nha, file bạn hàng ngàn name rác, ẩn có, hiện có, tôi đã xóa sạch hết rồi!

 

[cuonghoa176]

Bác Nghĩa làm mấy cái name này hay quá xá, e chỉ bíet xài thôi chứ hổng bíet..làm đâu. Phiền bác cho xuất hiện luôn cọc ngoài cùng trong GCN (HS lớp), e sẽ đánh vào cọc Ghi chú trong Sheet "SD HO NGHEO". E làm nhưng hàng nào ko có nó cho luôn số 0 bực mình! (bực vì mình hỏng bíet!...) Thank Pác!

 

[Hoàng Trọng Nghĩa]

Bác Nghĩa làm mấy cái name này hay quá xá, e chỉ bít xài thôi chứ hổng bít..làm đâu. Phiền bác cho xuất hiện luôn cọc ngoài cùng trong GCN (HS lớp), e sẽ đánh vào cọc Ghi chú trong Sheet "SD HO NGHEO". E làm nhưng hàng nào ko có nó cho luôn số 0 bực mình! (bực vì mình hỏng bít!...) Thank Pác!

Có phải bạn muốn lấy cột H/S Lớp là cột Ghi chú? Thế thì thay công thức chút xíu:

Tại ô F17:

=IF(B17="","",INDEX(DataDS,SMALL(Filter,ROW(1:1)),[B][COLOR=#ff0000]8[/COLOR][/B]))

Khi gặp ô không có giá trị gì nó sẽ ra giá trị = 0

Vậy thì giải quyết vấn đề bằng cách nào? Có nhiều cách nhưng tôi giới thiệu cho bạn một cách đơn giản nhất, nhưng lại nhẹ nhàng nhất đó là định dạng!

Sau khi đặt công thức tại F17 xong, bạn vào format cells (Ctrl+1) và chọn Number, Custom và tại Type bạn gõ như sau: [<>0]0;

Cuối cùng bạn fill công thức từ F17 xuống đến F31 là xong!