Lấy tất cả dữ liệu các cell có trong cột A nhưng dữ liệu không giống cộtB

[anhtai88nbk]

Hi all ! .

Em đang có một vấn đề về việc lấy cả các cell trong Cột A mà không có cell nào trùng dữ liệu với Cột B một cách nhanh nhất .Có nghĩa là em có một list mã trong cột A (N0123,N0124,...Nxxx) .Và cột B có dữ liệu ít hơn nhưng cell để có dữ liệu nằm trong Cột A.Giờ em muốn lấy Các cell có trong Cột A nhưng không có trong cột B một cách nhanh nhất . Em không biết dùng hàm nào để xử lý . rất mong các anh chị tiền bố giải đáp giúp em.

Best Regards !

 

[dhn46]

Bạn có thể dùng advance fillter lọc những phần tử của B trong A sau đó xoá chúng đi =>show all => sẽ còn các phần tử trong A nhưng không có trong B

 

[bebo021999]

Hi all ! .

Em đang có một vấn đề về việc lấy cả các cell trong Cột A mà không có cell nào trùng dữ liệu với Cột B một cách nhanh nhất .Có nghĩa là em có một list mã trong cột A (N0123,N0124,...Nxxx) .Và cột B có dữ liệu ít hơn nhưng cell để có dữ liệu nằm trong Cột A.Giờ em muốn lấy Các cell có trong Cột A nhưng không có trong cột B một cách nhanh nhất . Em không biết dùng hàm nào để xử lý . rất mong các anh chị tiền bố giải đáp giúp em.

Best Regards !

Gỉa sử có 2 vùng từ A2:A100, B2:B100
Tại C2 bạn nhập

=INDEX($A$2:$A$10,MATCH(1,(1-COUNTIF($B$2:$B$100,$A$2:$A$100))*IF(COUNTIF($C$1:C1,$A$2:$A$100),0,1),0))

kết thúc bằng Ctrl-shift-Enter
Kéo xuống đến khi nào báo lỗi thì thôi.
Cột C sẽ gồm những phần tử trong cột A mà không có trong B

 

[hoamattroicoi]

Theo file của anh bebo nếu lọc ra những dữ liệu chứa trong danh sách ở cột A mà không có trong cột B tôi có thêm 1 công thúc này cho bạn : tại ô C2 nhập công thức :

=INDEX($A$2:$A$6;MATCH(1;(COUNTIF($B$2:$B$4;$A$2:$A$6)=0)+COUNTIF($C$1:C1;$A$2:$A$6);0))

Kết thúc bằng ctrl+shift+Enter.

 

[linhngoc]

Hi all ! .

Em đang có một vấn đề về việc lấy cả các cell trong Cột A mà không có cell nào trùng dữ liệu với Cột B một cách nhanh nhất .Có nghĩa là em có một list mã trong cột A (N0123,N0124,...Nxxx) .Và cột B có dữ liệu ít hơn nhưng cell để có dữ liệu nằm trong Cột A.Giờ em muốn lấy Các cell có trong Cột A nhưng không có trong cột B một cách nhanh nhất . Em không biết dùng hàm nào để xử lý . rất mong các anh chị tiền bố giải đáp giúp em.

Best Regards !

Bạn cũng có thể dùng công thức sau:
=IF(COUNTIF($B$2:$B$100,A2)=0,A2,"") (giả sử dữ liệu bắt đầu từ dòng 2)
sau đó dùng Auto filter để lọc bỏ những dòng trống ra.

 

[ndu96081631]

Dạng bài này đã làm nhiều lần trên diễn đàn rồi
- Cách tối ưu nhất: Dùng VBA
- Cách đơn giản nhất, dùng Advanced Filter với 1 công thức cho cell điều kiện. Gần giống như ví dụ dưới đây:
[video=youtube;6dM5zBb2Hm4]http://www.youtube.com/watch?v=6dM5zBb2Hm4[/video]

Giá như có file đính kèm sẽ dễ dàng hơn

 

[vodoi2x]

Gỉa sử có 2 vùng từ A2:A100, B2:B100
Tại C2 bạn nhập

=INDEX($A$2:$A$10,MATCH(1,(1-COUNTIF($B$2:$B$100,$A$2:$A$100))*IF(COUNTIF($C$1:C1,$A$2:$A$100),0,1),0))

kết thúc bằng Ctrl-shift-Enter
Kéo xuống đến khi nào báo lỗi thì thôi.
Cột C sẽ gồm những phần tử trong cột A mà không có trong B

Công thức này có vấn đề chỗ tại sao không phải là =INDEX($A$2:$A$100, mà lại chỉ là =INDEX($A$2:$A$10, - đợi tác giả trả lời

Hơn nữa nếu vẫn sử dụng công thức đó thì , cũng không cần IF ở đây,

=INDEX($A$2:$A$100,MATCH(1,(1-COUNTIF($B$2:$B$100,$A$2:$A$100))*(COUNTIF($C$1:C1,$A$2:$A$100)=0),0))

Ctrl+Shift+Enter
---------------
Về ứng dụng thì:
nếu danh sách vừa thì công thức nhanh hơn - công thức như của hoamattroicoi post#4 topic này (ngắn gọn)
nếu dài thì nên dùng Advance filter như a Ndu đề cập,

 

[bebo021999]

Công thức này có vấn đề chỗ tại sao không phải là =INDEX($A$2:$A$100, mà lại chỉ là =INDEX($A$2:$A$10, - đợi tác giả trả lời

Hơn nữa nếu vẫn sử dụng công thức đó thì , cũng không cần IF ở đây,

=INDEX($A$2:$A$100,MATCH(1,(1-COUNTIF($B$2:$B$100,$A$2:$A$100))*(COUNTIF($C$1:C1,$A$2:$A$100)=0),0))

Ctrl+Shift+Enter
---------------
Về ứng dụng thì:
nếu danh sách vừa thì công thức nhanh hơn,
nếu dài thì nên dùng Advance filter như a Ndu đề cập,

Thanks vodoi2x, đúng như bạn nói, không phải là A10 mà là A100. Còn bỏ if, sửa thành countif()=0, đều đúng, công thức ngắn hơn 1 chút.
Nếu danh sách là cố định, dùng advance filter; nếu danh sách thường xuyên cập nhật, nên dùng công thức.

 

[phihndhsp]

Hi all ! .

Em đang có một vấn đề về việc lấy cả các cell trong Cột A mà không có cell nào trùng dữ liệu với Cột B một cách nhanh nhất .Có nghĩa là em có một list mã trong cột A (N0123,N0124,...Nxxx) .Và cột B có dữ liệu ít hơn nhưng cell để có dữ liệu nằm trong Cột A.Giờ em muốn lấy Các cell có trong Cột A nhưng không có trong cột B một cách nhanh nhất . Em không biết dùng hàm nào để xử lý . rất mong các anh chị tiền bố giải đáp giúp em.

Best Regards !

Bạn xem bài này nha, bài này không có lỗi #NA và không cần trích lọc có bao nhiêu dữ liệu không trùng thì nó cũng ra hết bình thường

B1   data =IF(COUNTIF($B$2:$B$4,$A$2:$A$6)=0,ROW($A$2:$A$6),"")
B2   C2=IF(ROWS($1:1)<=COUNT(data),OFFSET($A$1,SMALL(data,ROWS($1:1))-1,0),"")

 

[anhtai88nbk]

Em xin cảm ơn tất cả mọi người đã giúp đỡ em . Thanks All!