Hỏi về hàm tách dữ liệu trên nhiều cột

[nhunguyet0103]

Các bác chỉ bảo giúp em với, Thanks!
Ví dụ: Em có danh sách học sinh của cả 1 trường gồm vài trăm học sinh (mẫu như file đính kèm và ảnh)

​

Bây giờ, ở cột Khối em tách kí tự đầu của các lớp ra thì dùng hàm gì ạ? (Trước em chỉ biết dùng hàm Left để tách dữ liệu trên 1 cột, ở đây lại có đến 4 cột liền ạ).

 

[khuongvietphong]

Bạn dùng CT này tại ô B4:

=MAX(IFERROR(--LEFT(C4:F4),0))

Nhấn Ctrl+Shift+Enter rồi fill xuống dưới

 

[befaint]

Bạn dùng CT này tại ô B4:

=IFERROR(LEFT(LOOKUP(2,1/(C4:F4<>""),C4:F4),1),"")

Enter bình thường.

 

[Phuocam]

Nếu danh sách từ lớp 6 đến 9, bạn có thể dùng:

=IFERROR(LEFT(LOOKUP("zzzzz",C4:F4)),"")

 

[nhunguyet0103]

Cảm ơn các bác đã chỉ bảo! Nhưng sao em sử dụng các công thức trên đều bị lỗi #Name? nhỉ?

 

[befaint]

Cảm ơn các bác đã chỉ bảo! Nhưng sao em sử dụng các công thức trên đều bị lỗi #Name? nhỉ?

Chào nhunguyet0103,

Hàm IFERROR() áp dụng với Excel 2007 trở lên. Chắc bạn dùng Excel 2003 nên các công thức trên báo lỗi #Name.
Bạn thử công thức sau nhé. Tại B4:

=IF(ISNA(LOOKUP(2,1/(C4:F4<>""),C4:F4)),"",LEFT(LOOKUP(2,1/(C4:F4<>""),C4:F4)))

Kéo fill xuống.

 

[concogia]

Cảm ơn các bác đã chỉ bảo! Nhưng sao em sử dụng các công thức trên đều bị lỗi #Name? nhỉ?

Với dữ liệu trong bài của bạn, thử dùng công thức:

=LOOKUP(1,1/(C4:F4<>""),ROW($6:$9))

Hay:

=INDEX(ROW($6:$9),MATCH("*",C4:F4,0))

Kéo xuống
Thân

 

[befaint]

Với dữ liệu trong bài của bạn, thử dùng công thức:
=LOOKUP(1,1/(C4:F4<>""),ROW($6:$9))
Hay:
=INDEX(ROW($6:$9),MATCH("*",C4:F4,0))
Kéo xuống
Thân

Chưa bẫy lỗi #N/A anh!

 

[concogia]

Chưa bẫy lỗi #N/A anh!

Theo mình, bài này không cần bẫy lỗi bạn ạ, chắc chắn mỗi hàng chỉ có 1 cell chứa dữ liệu
Thân

 

[nhunguyet0103]

Theo mình, bài này không cần bẫy lỗi bạn ạ, chắc chắn mỗi hàng chỉ có 1 cell chứa dữ liệu
Thân

Cảm ơn Bác nhiều...nhiều!