Hàm UDF tính từng dòng trong một vùng ô.

[htin1997]

Xin chào các thành viên diễn đàn.

Nhờ các thành viên viết giúp em hàm UDF tính trung bình, biên độ, rả kết quả theo từng dòng trong vùng đã chọn(vùng của hàm trả mảng động trong Excel365, ví dụ: E2#,...).
Mục đích: Tự động tăng/giảm dòng tuỳ theo số dòng của hàm FILTER mà không cần phải kéo hoặc xoá công thức tính.

Chi tiết trong file đính kèm, chỗ nào chưa rõ em sẽ giải thích thêm.
Xin cám ơn.

 

[viethung78]

Theo tôi thực hành thấy các hàm số Excel có đối số là vùng (range), thì đối số đó không áp dụng cho hàm mảng động của Excel được.

 

[befaint]

Theo tôi thực hành thấy các hàm số Excel có đối số là vùng (range), thì đối số đó không áp dụng cho hàm mảng động của Excel được.

Thực hành kiểu gì hay vậy bạn?

Đối số của hàm này thì liên quan gì đối số của hàm khác?

Có sự liên quan bí mật khủng khiếp nào ở đây chăng?

 

[hocexcel_1991]

Xin chào các thành viên diễn đàn.

Nhờ các thành viên viết giúp em hàm UDF tính trung bình, biên độ, rả kết quả theo từng dòng trong vùng đã chọn(vùng của hàm trả mảng động trong Excel365, ví dụ: E2#,...).
Mục đích: Tự động tăng/giảm dòng tuỳ theo số dòng của hàm FILTER mà không cần phải kéo hoặc xoá công thức tính.

Chi tiết trong file đính kèm, chỗ nào chưa rõ em sẽ giải thích thêm.
Xin cám ơn.

Bạn thử dùng công thức này:

=BYROW(J4#,LAMBDA(a,AVERAGE(a)))
=BYROW(J4#,LAMBDA(a,MAX(a)-MIN(a)))

 

[Nhattanktnn]

Xin chào các thành viên diễn đàn.

Nhờ các thành viên viết giúp em hàm UDF tính trung bình, biên độ, rả kết quả theo từng dòng trong vùng đã chọn(vùng của hàm trả mảng động trong Excel365, ví dụ: E2#,...).
Mục đích: Tự động tăng/giảm dòng tuỳ theo số dòng của hàm FILTER mà không cần phải kéo hoặc xoá công thức tính.

Chi tiết trong file đính kèm, chỗ nào chưa rõ em sẽ giải thích thêm.
Xin cám ơn.

Nếu muốn lấy luôn cả kết quả filter thì tại J4 dùng hàm này:

=LET(src,$A$4:INDEX($H:$H,MATCH("zzzz",A:A)),des,FILTER(INDEX(src,SEQUENCE(ROWS(src)),SEQUENCE(1,5,4)),INDEX(src,,1)=$K$3),c_des,COLUMNS(des)+2,IF(SEQUENCE(1,c_des)>c_des-1,BYROW(des,LAMBDA(arr,MAX(arr)-MIN(arr))),IF(SEQUENCE(1,7)>c_des-2,BYROW(des,LAMBDA(arr,AVERAGE(arr))),des)))

 

[ptm0412]

Hàm ByRow và ByCol hay tuyệt. MS tạo ra nó để áp hàm Lambda cho đối số theo dòng hoặc theo cột.

 

[Nhattanktnn]

Hàm ByRow và ByCol hay tuyệt. MS tạo ra nó để áp hàm Lambda cho đối số theo dòng hoặc theo cột.

Dùng 365 xong quay lại 2010 thấy hụt hững vô cùng thầy ạ! ByRow và ByCol này hình như mới có phải không thầy nhỉ

 

[ptm0412]

Nếu muốn lấy luôn cả kết quả filter thì tại J4 dùng hàm này:

=LET(src,$A$4:INDEX($H:$H,MATCH("zzzz",A:A)),des,FILTER(INDEX(src,SEQUENCE(ROWS(src)),SEQUENCE(1,5,4)),INDEX(src,,1)=$K$3),
c_des,COLUMNS(des)+2,IF(SEQUENCE(1,c_des)>c_des-1,BYROW(des,LAMBDA(arr,MAX(arr)-MIN(arr))),
IF(SEQUENCE(1,7)>c_des-2,BYROW(des,LAMBDA(arr,AVERAGE(arr))),des)))

Viết gọn hơn:

=LET(d,D4:H12,it,A4:A12,f,FILTER(d,it=K3),r,ROWS(f),c,COLUMNS(f),c_2,c+2,IF(SEQUENCE(1,c_2)<=c,INDEX(f,SEQUENCE(r ),
SEQUENCE( 1,c)),IF(SEQUENCE(1,c_2)=c+1,BYROW(f,LAMBDA(a,AVERAGE(a))),BYROW(f,LAMBDA(a,MAX(a)-MIN(a))))))

Nếu có hàm HStack:

=LET(d,D4:H12,it,A4:A12,f,FILTER(d,it=K3),HSTACK(f,BYROW(f,LAMBDA(a,AVERAGE(a))),BYROW(f,LAMBDA(a,MAX(a)-MIN(a)))))

 

[htin1997]

Bạn thử dùng công thức này:

=BYROW(J4#,LAMBDA(a,AVERAGE(a)))
=BYROW(J4#,LAMBDA(a,MAX(a)-MIN(a)))

Thật là tuyệt vời, cám ơn anh.
Vậy mới biết em tìm hiểu chưa thể hết tất cả các hàm, cứ có gì nằm ngoài các hàm phổ biến lại nghĩ ngay tới VBA. Thật hạn hẹp.
Cám ơn các anh/chú đã giúp đỡ.