Hàm Importrangetreen Google sheet không chạy khi điều kiện là ngày

[Salemok]

Mình có đoạn công thức trên Google sheet
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheet...EBcAvRenuJ0SmMov0AXVt1jqE/edit#gid=1917302966";"NT!A2:O5000");"select Col6 where Col5 = 'Cuối Ca 1'")
Khi mình thay điều kiện Col5 bằng các cột Col2,3,4 đều chạy tốt. Tuy nhiên nếu thay bằng Col1 (là cột ngày tháng) thì nó không chạy.
Xin nhờ các cao thủ chỉ giáo

 

[befaint]

Query xét có 2 cột thì importRange lấy 2 cột thôi, ôm một mớ vậy cho nặng.

Dữ liệu là Date thì trong câu lệnh query phải thêm hàm Date vào.

Muốn có bài sẵn thì chia sẻ và gửi link file lên đây.

 

[Salemok]

chi tiết tại link đây. Nhờ các bạn chỉ giáo. Trân trọng
Mình cần công thứ tại Sheet1 ô B1

Copy of Phân tích KD - NLF2022

docs.google.com

 

[befaint]

"chi tiết tại link đây"

 

[Salemok]

"chi tiết tại link đây"

View attachment 278074

Mình muốn thay Col1 = A1 nhưng ko chạy. =QUERY(IMPORTRANGE("https://docs.google.com/spreadsheet...fGaiJP7KT5tOg24fSAqlGr19VU/edit#gid=152118611";"NT!A2:O5000");"select Col6 where Col1 = A1")
Bạn xemlaij link giúp mình nhé

Copy of Phân tích KD - NLF2022

docs.google.com

 

[befaint]

;"select Col6 where Col2 = Date '" & text(A1;"yyyy-mm-dd") & "'";0)

 

[Salemok]

Khâm phục. Nhờ bạn chỉ giùm dịch công thức thế nào

 

[batman1]

Khâm phục. Nhờ bạn chỉ giùm dịch công thức thế nào

Muốn biết dùng hàm bất kỳ của google sheets hay của Excel hay trong bất cứ cái gì thì phải đọc tài liệu. Không có cách nào khác. Chả ai tự nhiên biết dùng đồ do người khác tạo dựng.

Khi dùng QUERY trong chuỗi truy vấn có thể có những so sánh vd. =, ở đây là với mệnh đề WHERE, thì phải dùng cái gọi là Literals.

Khi giá trị cần so sánh là ngày tháng thì phải dùng cú pháp date 'yyyy-mm-dd'. Ví dụ nếu nhập cứng ngày 2202-06-26 thì phải dùng date '2202-06-26'

Nếu ngày tháng nằm ở vd. A1 = 2202-06-26 thì phải dùng hàm, vd. "'" & text(A1;"yyyy-mm-dd") & "'" để tạo '2202-06-26'

Lúc đó
"select Col6 where Col2 = date '" & text(A1;"yyyy-mm-dd") & "'" chẳng qua là
"select Col6 where Col2 = date '2202-06-26'"

Chú ý là date trong cú pháp trên không phải là hàm. Hàm DATE có 3 tham số là năm, tháng và ngày. DATE trong cú pháp ở trên là TỪ KHÓA (keyword)

Query Language Reference (Version 0.7) | Charts | Google for Developers

Learn how to use this language and discover detailed documentation for its classes, functions, and element.

developers.google.com

 

[Salemok]

Học phương pháp tư duy mới là quan trọng.
Cám ơn bạn đã chỉ giáo tận tình
Trân trọng

 

[Salemok]

Thực ra cuối cùng là mình cần cho sheet KQKD.
- Mình ko muốn tạo thêm sheet trung gian mới nên dùng Query và Importan. (nhưng công thức dài và bị N/A phải khử N/A)
- Chịu khó tạo thêm sheet trung gian (thì file nhiều sheet quá) thì dùng SUMPRODUCT và sheet trung gian
Trường hợp 1 khử N/A thế nào bạn chỉ giáo nhé.
Theo bạn dùng phương án 1 (Cột C) hay phương án 2 (Cột D)

Copy of Phân tích KD - NLF2022

PT 20NT CÁN HV Chậu , 1,26 , 1,88 , 2,07 , 2,25 , 2,44 , 2,63 , 2,82 , 3,01 , 3,19 , 3,38 , 3,57 , 3,76 , 3,95 , 4,13 , 4,32 , 4,51 kg , 20,74 , 31,00 , 34,10 , 37,20 , 40,30 , 43,40 , 46,50 , 49,60 , 52,70 , 55,80 , 58,90 , 62,00 , 65,10 , 68,20 , 71,30 , 74,4...

docs.google.com

 

[befaint]

Khóa trái lại thì mấy mùa quýt cũng không xong.



Google Sheets khác xa Excel, không phải kể nể cái gì cả. Mọi thứ rất đơn giản: Cứ nêu cụ tỉ yêu cầu, minh họa kết quả là có đáp án. Không phải dài dòng, lòng vòng.

 

[Salemok]

Mình mở hết rồi mà. Bạn giúp vậy là quá ok rồi.
DATE trong cú pháp ở trên là TỪ KHÓA (keyword)
Khái niệm này lần đầu được nghe. Mình cần tìm hiểu và học về cú pháp này

 

[befaint]

Mình mở hết rồi mà. Bạn giúp vậy là quá ok rồi.
DATE trong cú pháp ở trên là TỪ KHÓA (keyword)
Khái niệm này lần đầu được nghe. Mình cần tìm hiểu và học về cú pháp này

Mắc mệt quá. Google Sheets là thế giới khác rất xa MS Excel.

Chỉ cần duy nhất 1 công thức này là đủ.

=ArrayFormula(if(A5:A="";;iferror(vlookup(A5:A; query(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1aUwGP5sPxEjZVdjJffGaiJP7KT5tOg24fSAqlGr19VU";"NT!B2:F");"select Col1,Sum(Col5) group by Col1";0);2;0);0)))

 

[Salemok]

Cám ơn bạn rất nhiều

 

[batman1]

Thực ra cuối cùng là mình cần cho sheet KQKD.
- Mình ko muốn tạo thêm sheet trung gian mới nên dùng Query và Importan. (nhưng công thức dài và bị N/A phải khử N/A)
- Chịu khó tạo thêm sheet trung gian (thì file nhiều sheet quá) thì dùng SUMPRODUCT và sheet trung gian
Trường hợp 1 khử N/A thế nào bạn chỉ giáo nhé.

Tôi không hiểu ý bạn.

Đằng nào cũng dùng IMPORTRANGE, dùng ở sheet này hay ở sheet khác thì vẫn thế. Vậy thì tạo thêm sheet làm gì?

Mỗi bài toán có muôn vàn cách giải. Công thức

=SUM(QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1aUwGP5sPxEjZVdjJffGaiJP7KT5tOg24fSAqlGr19VU";"NT!A2:O5000");"select Col6 where Col2 = Date '" & TEXT(A5;"yyyy-mm-dd") & "'";0))

là của bạn hay của ai? Nếu là của bạn thì công thức đó đơn giản rồi, bạn còn muốn gì nữa? Theo tôi không có công thức đơn giản hơn đâu. Tất nhiên đây chỉ là ý kiến riêng, không phải là chân lý. Muốn bỏ kết quả lỗi khi dữ liệu không thỏa điều kiện? Google sheets cũng có hàm IFERROR. Nói chung có rất nhiều hàm giống như trong Excel. Nếu bạn muốn phục vụ trường hợp lỗi thì

=IFERROR(SUM(QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1aUwGP5sPxEjZVdjJffGaiJP7KT5tOg24fSAqlGr19VU";"NT!A2:F5000");"select Col6 where Col2 = date '" & TEXT(A5;"yyyy-mm-dd") & "'";0));0)

Trong google sheets bạn thao tác: chọn ô bất kỳ -> thẻ Insert -> Function thì bạn sẽ thấy nhiều hàm bạn đã gặp trong Excel. Và nhiều hàm, tất nhiên không phải tất cả, hoạt động y như trong Excel.

 

[Salemok]

Cám ơn bạn rất nhiều

 

[Salemok]

Mình copy công thức ang cột B. Thay Col6 thành Col8. Sao không thấy chạy. NHờ các bạn chỉ giúp nhé.

Copy of Phân tích KD - NLF2022

docs.google.com

 

[batman1]

Mình copy công thức ang cột B. Thay Col6 thành Col8. Sao không thấy chạy. NHờ các bạn chỉ giúp nhé.

Copy of Phân tích KD - NLF2022

docs.google.com

Nhìn bài #15 thì thấy tôi trích công thức của bạn với "NT!A2:O5000", nhưng do chỉ xét tới Col6 nên sau đó tôi sửa lại thành "NT!A2:F5000". Từ A tới F có 6 cột.

Nếu bây giờ bạn xét tới Col8 thì phải mở rộng vùng thành 8 cột tức A:H

=IFERROR(SUM(QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1aUwGP5sPxEjZVdjJffGaiJP7KT5tOg24fSAqlGr19VU";"NT!A2:H5000");"select Col8 where Col2 = date '" & TEXT(A5;"yyyy-mm-dd") & "'";0));0)

Ít nhất phải xét tới cột H. Còn nếu bạn muốn như ban đầu thì sửa thành "NT!A2:O5000"

 

[Salemok]

Đúng rồi ko để ý bạn sửa cái đó.
Cám ơn bạn rất nhiều

 

[hongducon]

Các bạn cho mình hỏi, có hàm importrange tương tự trong excel ko ạ?