Hàm If lồng hàm Vlookup

[LuuAnh980]

Chào các anh chị, mong các anh chi làm cho em công thức sau:
Diễn giải : Nếu A10=3193, thì lấy giá trị G10 dò trong Bảng B, lấy cột số 3, nếu A10=3160, thì lấy giá trị G10, dò trong Bảng C, lấy cột số 2, ngược lại (A10 không = 3193 và 3160 thì lấy giá trị G10 dò trong Bảng A, lấy cột số 3.
Em có lập công thức sau, mà kết quả sai.

=IFERROR(IF($A10=3193,VLOOKUP($G10,'BangB'!$I$37:$K$44,3,0),IF($A10=3160,VLOOKUP($G110,'BangC'!$J$46:$K$48,2,0),VLOOKUP($G10,'Bâng'!$I$3:$K$35,3,0)),"")

 

[SA_DQ]

		1	GPE1	95​			1	GPE01	15		1	123
		2	GPE3	90​			2	GPE02	20		2	234
		3	GPE5	85​			3	GPE03	25		3	345
		4	GPE7	80​			4	GPE04	30		4	456
		5	GPE9	75​			5	GPE05	35		5	567
		6	GPE11	70​			6	GPE06	40		6	678
		7	GPE13	65​			7	GPE07	45		7	789
		8	GPE15	60​			8	GPE08	50		8	900
		9	GPE17	55​			9	GPE09	55		9	1011
3177			60			8

=IF(A10=3193,VLOOKUP(G10,BangB,3,FALSE),IF(A10=3160,VLOOKUP(G10,BangC,2,FALSE),VLOOKUP(G10,BangA,3,FALSE)))

 

[ptm0412]

G110 kìa cô nàng ơi

Lại còn Sheet "Bâng"

 

[LuuAnh980]

Dạ em cám ơn anh @SA_DQ nhiều ạ. Đúng rồi ạ. À mà sao phải là "False" vậy anh @SA_DQ ???
Tới Thầy Mỹ: cái đó em gõ vào sai thôi Thầy ơi.

 

[ptm0412]

Dạ em cám ơn anh @SA_DQ nhiều ạ. Đúng rồi ạ. À mà sao phải là "False" vậy anh @SA_DQ ???
Tới Thầy Mỹ: cái đó em gõ vào sai thôi Thầy ơi.

False là 0
Công thức sai ở chỗ thiếu 1 dấu )
Hay là vẫn do "gõ vào sai"?

 

[SA_DQ]

Dạ em cám ơn. . . . . . À mà sao phải là "False" vậy anh. . . . . . . . . .

Vì mình gõ 'false' thì Excel tài lanh sửa giúp mình thành 'FALSE' làm mình an tâm hơn nhiều so với gõ 'O' như bạn!

 

[LuuAnh980]

Anh @SA_DQ và Thầy Mỹ cho em hỏi thêm tý, ngoài dùng If và Vlookup, còn dùng hàm nào cho gọn được không ạ.

 

[ptm0412]

Anh @SA_DQ và Thầy Mỹ cho em hỏi thêm tý, ngoài dùng If và Vlookup, còn dùng hàm nào cho gọn được không ạ.

Có, Lookup và If gọn hơn

=IFERROR(VLOOKUP(G10,IF(A10=3193,'BangB'!$I$37:$K$44,IF(A10=3160,'BangC'!$J$46:$K$48,'BangA'!$I$3:$K$35)),IF(A10=3160,2,3),0),"")

 

[VetMini]

Có, Lookup và If gọn hơn

=IFERROR(VLOOKUP(G10,IF(A10=3193,'BangB'!$I$37:$K$44,IF(A10=3160,'BangC'!$J$46:$K$48,'BangA'!$I$3:$K$35)),IF(A10=3160,2,3),0),"")

Bài này khá rắc rối ở cái chỗ bảng C. Nếu muốn đồng bộ hơn (chưa chắc gọn hơn) thì có thể sửa bảng C bằng cách tạo thêm cột giữa:

ở vị trí BangC : Choose({1,2,3}, 'BangC'!$J$46:$J$48, 'BangC'!$L$46:$L$48, 'BangC'!$K$46:$K$48)

Đồng bộ thì sẽ được cái lợi tránh A10 bị tính nhiều lần (nếu là một con toán thay vì chỉ truy cập trị). Đương nhiên với phiên bản 365 thì việc tránh tính nhiều lần không thành vấn đề.

 

[LuuAnh980]

Vậy em chèn cho Bảng C cột giữa, thì công thức sao vậy anh @VetMini ??

 

[VetMini]

Vậy em chèn cho Bảng C cột giữa, thì công thức sao vậy anh @VetMini ??

Nếu bảng C chèn thêm 1 cột giữa J và K thì cột mới ấy là K, cột dữ liệu trở thành L.
(để ý những chỗ tô đỏ.

=IFERROR(VLOOKUP(G10,IF(A10=3193, 'BangB'!$I$37:$K$44,IF(A10=3160, 'BangC'!$J$46:$L$48, 'BangA'!$I$3:$K$35)), 3, 0),"")

Nếu chèn cột bằng công thức như tôi nói ở bài #9 thì:

=IFERROR(VLOOKUP(G10,IF(A10=3193, 'BangB'!$I$37:$K$44,IF(A10=3160, Choose({1,2,3}, 'BangC'!$J$46:$J$48, 'BangC'!$L$46:$L$48, 'BangC'!$K$46:$K$48), 'BangA'!$I$3:$K$35)), 3, 0),"")

Hàm IF tuy trông rườm rà nhưng thực tế nó rất hiệu quả. Nó tính theo kiểu cần đâu tính đấy. Khác với nhiều hàm trông gọn nhưng làm việc theo kiểu có là tính, không cần biết gọn hay không.

Bài này muốn công thức trông gọn, đẹp thì dùng Names:
DULIEU_A = 'BangA'!$I$3:$K$35
DULIEU_B = 'BangB'!$I$37:$K$44
DULIEU_C = Choose({1,2,3}, 'BangC'!$J$46:$J$48, 'BangC'!$L$46:$L$48, 'BangC'!$K$46:$K$48)

=IFERROR(VLOOKUP(G10,IF(A10=3193, DULIEU_B, IF(A10=3160, DULIEU_C, DULIEU_A)), 3,0),"")