Giải bài tập Excel: "Bảng Lương Nhân Viên"

[giotdang907]

Nhờ các Bác Pro Giúp mình cột "Thưởng". Thank You.

 

[phuongtrinh]

Tui hoàn thành cột "Thưởng" giúp bạn rồi. Xem lại đúng không nha bạn.

 

[BNTT]

Tôi không biết bài này do ai làm, nhưng công thức tính LƯƠNG sai rồi.

Yêu cầu để tính lương là:

2. LƯƠNG = HỆ SỐ * LCB * N.CÔNG, nhưng nếu số ngày công làm việc >=25 ngày thì mỗi ngày làm vượt giờ được tính gấp đôi.

Có 2 chuyện:

1. "Nếu số ngày công >= 25", có nghĩa là từ ngày thứ 25 đã được tính gấp đôi (thành 2 ngày), mà công thức IF trong bài (xem hình) gài điều kiện >25, là sai. Vì như vậy thì >25 mới tính, trong khi yêu cầu nói là lớn hơn hoặc bằng 25 mà.
   
   
2. Bi giờ, cứ giả sử là từ ngày 26 mới tính (>25), thì công thức để tính cũng sai.
   Bạn xem nhé, sai ở điều kiện đúng đấy, phần tôi tô màu đỏ:
   
   =IF(E5>25, (E5-25)*2*D5*E5*$K$2, D5*E5*$K$2​
   Đã lấy (E5-25)*2 rồi, mà lại nhân tiếp với E5 thêm một lần nữa, hóa ra nhân số ngày công (E5) lên làm mấy lần sao?
   Giả sử có một người làm 26 ngày (E5=26), bạn lấy E5-25=1, nhân 2 lên, là 2, rồi nhân tiếp E5, nó thành ra 26*2 = 52 ngày được tính lương ? Nếu bạn là kế toán tiền lương mà tính kiểu này thì bạn móc túi ra đền không biết bao nhiêu cho đủ!
   
   Phải sửa lại công thức đó như vầy:
   
   =Lương cơ bản * Hệ số * (Ngày công + IF(Ngày công>25, Ngày công - 25))​
   Nói ngoài lề: Hàm IF trên đây tôi chỉ dùng 1 điều kiện đúng thôi, còn sai (Ngày công < 25) thì mặc kệ. Không sao cả, khi gặp điều kiện sai, IF tự động trả về FALSE, tương đương số 0, cho nên E5 + 0 thì vẫn bằng E5 thôi.
   
   Để tôi tính thử bằng tay nhé: Giả sử có một người làm 27 ngày, theo như bạn (chứ không phải theo đề bài), thì người này làm dư 2 ngày, phải không. 2 ngày này được tính gấp đôi, nghĩa là thành 4 ngày, cộng với 25 ngày bình thường, ra 29 ngày. OK?
   
   Cái này:
   
   Ngày công + IF(Ngày công>25, Ngày công - 25)
   =27 + IF(27>25, 27-25)
   =27 + (27-25) (vì điều kiện của IF đúng)
   =29
   ​

Tuy nhiên, đã làm thì làm cho thật đúng, do yêu cầu nói là nếu ngày công >= 25, nên chúng ta phải theo cái đó. Công thức đúng để tính Lương như vầy:

=Lương cơ bản * Hệ số * (Ngày công + IF(Ngày công>=25, Ngày công - 24))

Hay là:

= $K$2 * D5 * (E5 + IF(E5>=25, E5-24))

Hay là (cái này thì hơi khó hiểu tí, phải động não):

= $K$2 * D5 * (E5 + MAX(0, E5-24))​

---------------
P/S: Mới coi có câu tính lương thôi, còn mấy câu sau nữa tôi chưa xem hết... Nhưng, phải đi nấu cơm... tối tôi xem tiếp.

 

[BNTT]

Tiếp tục xử bài BẢNG LƯƠNG NHÂN VIÊN.

Tui hoàn thành cột "Thưởng" giúp bạn rồi. Xem lại đúng không nha bạn.

Cái hình tôi chụp ở bài trước chính là cái bảng tính mà bạn nói rằng đã hoàn thành cột thưởng. Không biết rằng bạn làm giúp cột Thưởng là làm gì? Bởi vì, công thức mà bạn làm cho cột Thưởng chính là công thức để tính phụ cấp!!

Tiền thưởng cho từng người = (TỔNG QUỸ THƯỞNG / TỔNG NGÀY CÔNG) * NGAYCÔNG của từng người, làm tròn đến hàng trăm.
Riêng tiền thưởng người cuối cùng = TỔNG QUỸ THƯỞNG - Số tiền đã phân bố cho những người trước.​

Trong đó:

TỔNG QUỸ THƯỞNG = QUỸ LƯƠNG - ( TỔNG PHỤ CẤP + TỔNG LƯƠNG)​

Tổng quỹ thưởng = Quỹ lương - (Tổng Phụ Cấp + Tổng Lương) = $I$2-($F$26+$G$26)

Thưởng (từ người thứ 1 đến 19) = (Tổng quỹ lương / Tổng ngày công) * Ngày công = ($I$2-($F$26+$G$26))/$E$26*E5
Thêm chuyện làm tròn đến hàng trăm, ta có công thức cuối cùng là:

[H5:H24]: =ROUND(($I$2-($F$26+$G$26))/$E$26*E5, -2)​

Thưởng người cuối cùng (theo kiểu lời ăn lỗ chịu):

[H25]: =ROUND($I$2-($F$26+$G$26)-SUM(H5:H24), -2)​

 

[ndu96081631]

Thêm vài chiêu
1> Tính lương:

G5 =D5*$K$2*((MAX(E5,24)-24)+E5)

2> Tính thưởng:

H5 =ROUND(($I$2-($F$26+$G$26))/$E$26*E5,-2)

và thưởng cho người cuối cùng:

H25 =ROUND(($I$2-($F$26+$G$26))-SUM($H$5:$H$24),-2)

3> Tính Tạm ứng:

I5 =MIN(ROUND(2/3*($G5+$F5),-2),95000)