Giúp sửa code: Tính tổng cho từng nhóm (1 người xem)

Liên hệ QC

Người dùng đang xem chủ đề này

Đang trực tuyến: 1 (Thành viên: 0, Khách: 1)
Hong.Van

Hong.Van

Busy
Tham gia
7/5/12
Bài viết
2,330
Được thích
1,767
Em chào thầy cô & anh chị
Xin giúp em sửa code tính tổng cho từng nhóm như sau:
Nếu Mã là 131 thì cộng các mã con có ký tự đầu là B
Nếu Mã là 331 thì cộng các mã con có ký tự đầu là M
Nếu Mã là 1388 thì cộng các mã con có ký tự đầu là Y
Nếu Mã là 3388 thì cộng các mã con có ký tự đầu là Z
Mã: 
Sub KetQua()    Dim sArray, Arr()
    Dim i As Long
    Dim n7 As Range, n8 As Range
    Dim B As String, M As String, Y As String, Z As String
    Dim Wf As WorksheetFunction


    With ActiveSheet
        sArray = Range([B11], [B65536].End(3)).Value
        Set n7 = Range([B11], [B65536].End(3))
        Set n8 = n7.Offset(, 1)
    End With




    ReDim Arr(1 To UBound(sArray, 1), 1 To 1)
    For i = 1 To UBound(sArray, 1)
        If IsNumeric(sArray(i, 1)) Then


            If sArray(i, 1) = 131 Then
                [COLOR=#ff0000]Arr(i, 1) = Wf.SumIf(n7, "B" & "*", n8)[/COLOR]
            ElseIf sArray(i, 1) = 331 Then
                [COLOR=#ff0000]Arr(i, 1) = Wf.SumIf(n7, "M" & "*", n8)[/COLOR]
            ElseIf sArray(i, 1) = 1388 Then
                [COLOR=#ff0000]Arr(i, 1) = Wf.SumIf(n7, "Y" & "*", n8)[/COLOR]
            Else: sArray(i, 1) = 3388
               [COLOR=#ff0000] Arr(i, 1) = Wf.SumIf(n7, "Z" & "*", n8)[/COLOR]
            
            End If
        End If


    Next i
    Range("C11").Resize(UBound(Arr, 1)).Value = Arr


End Sub
Xin vui lòng xem File, Muốn kết quả chạy code như những cell tô màu vàng
Em cảm ơn
---------
P/s: code báo lỗi ở những dòng màu đỏ
 

File đính kèm

Lần chỉnh sửa cuối:
Sắp xếp theo thời gian sắp xếp theo bầu chọn
Bài trên em thiếu
Set Wf = WorksheetFunction
---
Nhưng phát sinh thêm vấn đề sau khi chạy code thì số liệu bên cột C tương ứng với các mã là chuỗi như b1, b2 ... z3 bị xóa
Bây giờ em muốn giữ lại các số liệu này thì phải sửa code như thế nào?
Em cảm ơn!
 
Upvote 0
Hong.Van đã viết:
Bài trên em thiếu
Set Wf = WorksheetFunction
---
Nhưng phát sinh thêm vấn đề sau khi chạy code thì số liệu bên cột C tương ứng với các mã là chuỗi như b1, b2 ... z3 bị xóa
Bây giờ em muốn giữ lại các số liệu này thì phải sửa code như thế nào?
Em cảm ơn!
Nhấp chuột vào đây để mở rộng...

Thay vì
ReDim Arr(1 To UBound(sArray, 1), 1 To 1)
Ta sửa thành
Arr = n8.Value
là được rồi
Ngoài ra, chổ này:
Mã: 
With ActiveSheet
  sArray = Range([B11], [B65536].End(3)).Value
  Set n7 = Range([B11], [B65536].End(3))
  Set n8 = n7.Offset(, 1)
End With
Sửa thành vầy sẽ "đẹp" hơn
Mã: 
With ActiveSheet
  Set n7 = [SIZE=5][COLOR=#ff0000].[/COLOR][/SIZE]Range([SIZE=5][COLOR=#ff0000].[/COLOR][/SIZE][B11], [SIZE=5][COLOR=#ff0000].[/COLOR][/SIZE][B65536].End(3))
  Set n8 = n7.Offset(, 1)
  sArray = n7.Value
End With
Chú ý các dấu chấm (.) màu đỏ nha (nêu không thì With ActiveSheet làm quái gì)
 
Upvote 0
Cho em hỏi câu lệnh dưới cũng có nghĩa là Xóa mảng Arr và tính tóan lại?
Mã: 
ReDim Arr(1 To UBound(sArray, 1), 1 To 1)
Em cảm ơn!
 
Upvote 0
Mình nói thêm 2 chổ chưa "đẹp" ở code trên
1> With ActiveSheet
Có nghĩa là code này có thể chạy ở bất cứ sheet nào cũng được (nó sẽ lấy dữ liệu tại sheet đó) ---> Vậy thì With ActiveSheet hóa ra thừa
Vậy: Hoặc là bỏ cái With ấy đi, hoặc là With Sheets("Sheet1") (hay With chính xác tên 1 sheet nào đó)
2> Wf.SumIf(n7, "B" & "*", n8)
Có phải ghi gọn vầy sẽ hợp lý không
Wf.SumIf(n7, "B*", n8)
tương tự cho các SUMIF khác
Hong.Van đã viết:
Cho em hỏi câu lệnh dưới cũng có nghĩa là Xóa mảng Arr và tính tóan lại?
Mã: 
ReDim Arr(1 To UBound(sArray, 1), 1 To 1)
Em cảm ơn!
Nhấp chuột vào đây để mở rộng...

Câu lệnh này khởi tạo mảng nhưng chưa có phần tử nào bên trong ---> Lúc bạn IF, ElseIF... gì gì đó, chổ nào thỏa mản đ/k sẽ được nạp vào mảng... còn lại thì vẫn rổng như thường
Trong khi nếu Arr= n8.Value thì mảng này được khởi tạo và có giá trị luôn ---> Lúc bạn IF, ElseIF... gì gì đó, chổ nào thỏa mản đ/k sẽ được nạp vào mảng... còn lại thì vẫn giữ giá trị cũ
Vậy thôi
 
Lần chỉnh sửa cuối:
Upvote 0
Bây giờ em áp dụng vào bài thực tế của em như sau:
Yêu cầu của em là tính tồn cuối kỳ tại cột H & I
1/ Nếu mã Khách hàng (cột B) là chuỗi Text, thì cthức có dạng
Ví dụ tại cell H12 =MAX(D12+F12-E12-G12;0)
Ví dụ tại cell I12=MAX(E12+G12-D12-F12;0)

2/ Nếu mã Khách hàng (cột B) là Number (ví dụ 131, 331, 1388, 3388), thì cthức có dạng
tính tổng cho từng nhóm như sau:
Nếu Mã là 131 thì cộng các mã con có ký tự đầu là B
Ví dụ tại cell H11 =SUMIF($B$11:$B$83;"B*";$H$11:$H$83)
Ví dụ tại cell I11=SUMIF($B$11:$B$83;"B*";$I$11:$I$83)

Tương tự cho các mã dưới
Nếu Mã là 331 thì cộng các mã con có ký tự đầu là M
Nếu Mã là 1388 thì cộng các mã con có ký tự đầu là Y
Nếu Mã là 3388 thì cộng các mã con có ký tự đầu là Z
(Em có lập cthức tại cột H & I)
Em viết code như sau:
Mã: 
Sub cuoiky_2()
    Dim sArray, Arr()
    Dim i As Long
    Dim n1 As Range, n2 As Range, n3 As Range, n4 As Range, n5 As Range, n6 As Range, n7 As Range, n8 As Range, n9 As Range
    Dim B As String, M As String, Y As String, Z As String
    Dim Wf As WorksheetFunction
    Set Wf = WorksheetFunction
    With ActiveSheet
        Set n7 = .Range(.[B11], .[B65536].End(3))
        Set n8 = n7.Offset(, 6)
        Set n9 = n7.Offset(, 7)
        sArray = n7.Resize(, 8).Value


    End With
    ReDim Arr(1 To UBound(sArray, 1), 1 To 2)
    For i = 1 To UBound(sArray, 1)
        ' tao so lieu cot H
        If Not IsNumeric(sArray(i, 1)) Then
            If sArray(i, 3) + sArray(i, 5) - sArray(i, 4) - sArray(i, 6) > 0 Then
                Arr(i, 1) = sArray(i, 3) + sArray(i, 5) - sArray(i, 4) - sArray(i, 6)
            Else
                If sArray(i, 1) = 131 Then
                    Arr(i, 1) = Wf.SumIf(n7, "B*", n8)
                ElseIf sArray(i, 1) = 331 Then
                    Arr(i, 1) = Wf.SumIf(n7, "M*", n8)
                ElseIf sArray(i, 1) = 1388 Then
                    Arr(i, 1) = Wf.SumIf(n7, "Y*", n8)
                ElseIf sArray(i, 1) = 3388 Then
                    Arr(i, 1) = Wf.SumIf(n7, "Z*", n8)
                End If
            End If
        End If
        ' tao so lieu cot I
        If Not IsNumeric(sArray(i, 1)) Then
            If sArray(i, 4) + sArray(i, 6) - sArray(i, 3) - sArray(i, 5) > 0 Then
                Arr(i, 2) = sArray(i, 4) + sArray(i, 6) - sArray(i, 3) - sArray(i, 5)
            Else
                If sArray(i, 1) = 131 Then
                    Arr(i, 2) = Wf.SumIf(n7, "B*", n9)
                ElseIf sArray(i, 1) = 331 Then
                    Arr(i, 2) = Wf.SumIf(n7, "M*", n9)
                ElseIf sArray(i, 1) = 1388 Then
                    Arr(i, 2) = Wf.SumIf(n7, "Y*", n9)
                ElseIf sArray(i, 1) = 3388 Then
                    Arr(i, 2) = Wf.SumIf(n7, "Z*", n9)
                End If
            End If
        End If
    Next i
    Range("H11").Resize(UBound(Arr, 1), 2).Value = Arr


End Sub
Khi chạy code, thì chỉ kết quả khi các cell tại cột B có giá trị là chuỗi Text (ví dụ: BKVL, B004...)
Còn các cell của cột B có giá trị là số (ví dụ :131, 331, 1388, 3388) thì CODE KHÔNG CHO KẾT QỦA (trong File em có tô các cell màu vàng)
Xin vui lòng chỉ chỗ sai của code, em cảm ơn!
 

File đính kèm

Upvote 0
Hong.Van đã viết:
Khi chạy code, thì chỉ kết quả khi các cell tại cột B có giá trị là chuỗi Text (ví dụ: BKVL, B004...)
Còn các cell của cột B có giá trị là số (ví dụ :131, 331, 1388, 3388) thì CODE KHÔNG CHO KẾT QỦA (trong File em có tô các cell màu vàng)
Xin vui lòng chỉ chỗ sai của code, em cảm ơn!
Nhấp chuột vào đây để mở rộng...

Sửa lại đây:
Mã: 
Sub cuoiky_2()
  Dim sArray, Arr()
  Dim i As Long
  Dim n1 As Range, n2 As Range, n3 As Range, n4 As Range, n5 As Range, n6 As Range, n7 As Range, n8 As Range, n9 As Range
  Dim B As String, M As String, Y As String, Z As String
  Dim dTmp1 As Double, dTmp2 As Double
  Dim Wf As WorksheetFunction
  Set Wf = WorksheetFunction
  With Sheets("CNT11")
    Set n7 = .Range(.[B11], .[B65536].End(3))
    Set n8 = n7.Offset(, 6)
    Set n9 = n7.Offset(, 7)
    sArray = n7.Resize(, 8).Value
  End With
  For i = 1 To UBound(sArray, 1)
    If Not IsNumeric(sArray(i, 1)) Then
      dTmp1 = sArray(i, 3) + sArray(i, 5) - sArray(i, 4) - sArray(i, 6)
      dTmp2 = sArray(i, 4) + sArray(i, 6) - sArray(i, 3) - sArray(i, 5)
      If dTmp1 > 0 Then sArray(i, 7) = dTmp1
      If dTmp2 > 0 Then sArray(i, 8) = dTmp2
    Else
      If sArray(i, 1) = 131 Then
        sArray(i, 7) = Wf.SumIf(n7, "B*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "B*", n9)
      ElseIf sArray(i, 1) = 331 Then
        sArray(i, 7) = Wf.SumIf(n7, "M*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "M*", n9)
      ElseIf sArray(i, 1) = 1388 Then
        sArray(i, 7) = Wf.SumIf(n7, "Y*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "Y*", n9)
      ElseIf sArray(i, 1) = 3388 Then
        sArray(i, 7) = Wf.SumIf(n7, "Z*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "Z*", n9)
      End If
    End If
  Next i
  n7.Resize(, 8).Value = sArray
End Sub
Bạn tự so sánh và suy nghĩ xem mình sai chổ nào nhé
(Khai báo biến chi cả "rừng" vậy, có xài hết đâu)
 
Upvote 0
ndu96081631 đã viết:
Sửa lại đây:
Mã: 
Sub cuoiky_2()
  Dim sArray, Arr()
  Dim i As Long
  Dim n1 As Range, n2 As Range, n3 As Range, n4 As Range, n5 As Range, n6 As Range, n7 As Range, n8 As Range, n9 As Range
  Dim B As String, M As String, Y As String, Z As String
  Dim dTmp1 As Double, dTmp2 As Double
  Dim Wf As WorksheetFunction
  Set Wf = WorksheetFunction
  With Sheets("CNT11")
    Set n7 = .Range(.[B11], .[B65536].End(3))
    Set n8 = n7.Offset(, 6)
    Set n9 = n7.Offset(, 7)
    sArray = n7.Resize(, 8).Value
  End With
  For i = 1 To UBound(sArray, 1)
    If Not IsNumeric(sArray(i, 1)) Then
      dTmp1 = sArray(i, 3) + sArray(i, 5) - sArray(i, 4) - sArray(i, 6)
      dTmp2 = sArray(i, 4) + sArray(i, 6) - sArray(i, 3) - sArray(i, 5)
      If dTmp1 > 0 Then sArray(i, 7) = dTmp1
      If dTmp2 > 0 Then sArray(i, 8) = dTmp2
    Else
      If sArray(i, 1) = 131 Then
        sArray(i, 7) = Wf.SumIf(n7, "B*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "B*", n9)
      ElseIf sArray(i, 1) = 331 Then
        sArray(i, 7) = Wf.SumIf(n7, "M*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "M*", n9)
      ElseIf sArray(i, 1) = 1388 Then
        sArray(i, 7) = Wf.SumIf(n7, "Y*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "Y*", n9)
      ElseIf sArray(i, 1) = 3388 Then
        sArray(i, 7) = Wf.SumIf(n7, "Z*", n8)
        sArray(i, 8) = Wf.SumIf(n7, "Z*", n9)
      End If
    End If
  Next i
  n7.Resize(, 8).Value = sArray
End Sub
Bạn tự so sánh và suy nghĩ xem mình sai chổ nào nhé
(Khai báo biến chi cả "rừng" vậy, có xài hết đâu)
Nhấp chuột vào đây để mở rộng...
Em xin cảm ơn Thầy!
Code này chạy lần thứ nhất thì chỉ tạo kết qủa cho những mã khách hàng là chuỗi Text
Vẫn để tồn tại kết code lần thứ 1, chạy code lần thứ 2 thì mới cho kết quả cùa các mã 131, 331, 1388, 3388
Thầy xem lại giúp em.
 
Upvote 0
Hong.Van đã viết:
Em xin cảm ơn Thầy!
Code này chạy lần thứ nhất thì chỉ tạo kết qủa cho những mã khách hàng là chuỗi Text
Vẫn để tồn tại kết code lần thứ 1, chạy code lần thứ 2 thì mới cho kết quả cùa các mã 131, 331, 1388, 3388
Thầy xem lại giúp em.
Nhấp chuột vào đây để mở rộng...

Tại vỉ muốn SUMIF có kết quả thì mấy thằng tính MAX kia phải có kết quả trước (không thể đồng thời được)
Tôi sơ suất chút! Bạn tự nghiên cứu xem
 
Upvote 0
ndu96081631 đã viết:
Tại vỉ muốn SUMIF có kết quả thì mấy thằng tính MAX kia phải có kết quả trước (không thể đồng thời được)
Tôi sơ suất chút! Bạn tự nghiên cứu xem
Nhấp chuột vào đây để mở rộng...
Em tách IF ra, gán giá trị lần thứ nhất và cho chạy For thêm 1 lần nữa
Hổng biết nhìn có buồn cười không!

Mã: 
Sub cuoiky_2()
    Dim sArray, arr()
    Dim i As Long
    Dim n1 As Range, n2 As Range, n3 As Range, n4 As Range, n5 As Range, n6 As Range, n7 As Range, n8 As Range, n9 As Range
    Dim B As String, M As String, Y As String, Z As String
    Dim dTmp1 As Double, dTmp2 As Double
    Dim Wf As WorksheetFunction
    Set Wf = WorksheetFunction
    With Sheets("CNT11")
        Set n7 = .Range(.[B11], .[B65536].End(3))
        Set n8 = n7.Offset(, 6)
        Set n9 = n7.Offset(, 7)
        sArray = n7.Resize(, 8).Value
    End With
    For i = 1 To UBound(sArray, 1)
        If Not IsNumeric(sArray(i, 1)) Then
            dTmp1 = sArray(i, 3) + sArray(i, 5) - sArray(i, 4) - sArray(i, 6)
            dTmp2 = sArray(i, 4) + sArray(i, 6) - sArray(i, 3) - sArray(i, 5)
            If dTmp1 > 0 Then sArray(i, 7) = dTmp1
            If dTmp2 > 0 Then sArray(i, 8) = dTmp2
        End If
    Next i
    n7.Resize(, 8).Value = sArray
    
    For i = 1 To UBound(sArray, 1)
        If sArray(i, 1) = 131 Then
            sArray(i, 7) = Wf.SumIf(n7, "B*", n8)
            sArray(i, 8) = Wf.SumIf(n7, "B*", n9)
        ElseIf sArray(i, 1) = 331 Then
            sArray(i, 7) = Wf.SumIf(n7, "M*", n8)
            sArray(i, 8) = Wf.SumIf(n7, "M*", n9)
        ElseIf sArray(i, 1) = 1388 Then
            sArray(i, 7) = Wf.SumIf(n7, "Y*", n8)
            sArray(i, 8) = Wf.SumIf(n7, "Y*", n9)
        ElseIf sArray(i, 1) = 3388 Then
            sArray(i, 7) = Wf.SumIf(n7, "Z*", n8)
            sArray(i, 8) = Wf.SumIf(n7, "Z*", n9)
        End If


    Next i
    n7.Resize(, 8).Value = sArray
End Sub
 
Upvote 0
Hong.Van đã viết:
Em tách IF ra, gán giá trị lần thứ nhất và cho chạy For thêm 1 lần nữa
Hổng biết nhìn có buồn cười không!
Nhấp chuột vào đây để mở rộng...

Thì chắc chắn phải vậy rồi (gì mà buồn cười chứ)
Có điều tôi chắc rằng bài này vẫn có thể dùng 1 vòng lập, nhưng khi ấy phải có sự tham gia của Dictionary (để đánh dấu vị trí)... đồng thời khỏi cần phải SUMIF luôn
E rằng hơi quá sức của bạn, tuy nhiên nếu bạn có hứng thú thì cứ việc nghiên cứu (làm được sẽ là bước đột phá cho bản thân đấy)
 
Upvote 0
Tham gia cho vui. 1 vòng lặp, không dùng Sumif, không dùng Dic. Liều thôi, nhưng nếu hỏng trúng thì H Van chịu.

PHP: 
Sub test()
Dim dl(), tam7 As Double, tam8 As Double
Dim i As Long, a As Long, b As Long, c As Long, d As Long
[H11:I83].ClearContents
dl = Range([B11], [B65536].End(3)).Resize(, 8).Value
For i = 1 To UBound(dl)
   If Not IsNumeric(dl(i, 1)) Then
      tam7 = dl(i, 3) + dl(i, 5) - dl(i, 4) - dl(i, 6)
         tam8 = dl(i, 4) + dl(i, 6) - dl(i, 3) - dl(i, 5)
            If tam7 > 0 Then dl(i, 7) = tam7
               If tam8 > 0 Then dl(i, 8) = tam8
    Else
      If dl(i, 1) = 131 Then a = i
         If dl(i, 1) = 331 Then b = i
            If dl(i, 1) = 1388 Then c = i
               If dl(i, 1) = 3388 Then d = i
    End If
    If dl(i, 1) Like "B*" Then
        dl(a, 7) = dl(a, 7) + dl(i, 7)
        dl(a, 8) = dl(a, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "M*" Then
        dl(b, 7) = dl(b, 7) + dl(i, 7)
        dl(b, 8) = dl(b, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "Y*" Then
        dl(c, 7) = dl(c, 7) + dl(i, 7)
        dl(c, 8) = dl(c, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "Z*" Then
        dl(d, 7) = dl(d, 7) + dl(i, 7)
        dl(d, 8) = dl(d, 8) + dl(i, 8)
    End If
Next
[B11].Resize(i - 1, 8) = dl
End Sub
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
Tham gia cho vui. 1 vòng lặp, không dùng Sumif, không dùng Dic. Liều thôi, nhưng nếu hỏng trúng thì H Van chịu.
Nhấp chuột vào đây để mở rộng...

Bố trí code gì mà thụt ra thụt vào tùy tiện quá... nhìn.. đuối luôn
Bố trí như vậy nhìn vào chẳng ai hiểu được dòng nào thuộc "cấp bậc" nào
Bố trí lại đây:
Mã: 
Sub test()
  Dim dl(), tam7 As Double, tam8 As Double
  Dim i As Long, a As Long, b As Long, c As Long, d As Long
  [H11:I83].ClearContents
  dl = Range([B11], [B65536].End(3)).Resize(, 8).Value
  For i = 1 To UBound(dl)
    If Not IsNumeric(dl(i, 1)) Then
      tam7 = dl(i, 3) + dl(i, 5) - dl(i, 4) - dl(i, 6)
      tam8 = dl(i, 4) + dl(i, 6) - dl(i, 3) - dl(i, 5)
      If tam7 > 0 Then dl(i, 7) = tam7
      If tam8 > 0 Then dl(i, 8) = tam8
    Else
      If dl(i, 1) = 131 Then a = i
      If dl(i, 1) = 331 Then b = i
      If dl(i, 1) = 1388 Then c = i
      If dl(i, 1) = 3388 Then d = i
    End If
    If dl(i, 1) Like "B*" Then
      dl(a, 7) = dl(a, 7) + dl(i, 7)
      dl(a, 8) = dl(a, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "M*" Then
      dl(b, 7) = dl(b, 7) + dl(i, 7)
      dl(b, 8) = dl(b, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "Y*" Then
      dl(c, 7) = dl(c, 7) + dl(i, 7)
      dl(c, 8) = dl(c, 8) + dl(i, 8)
    ElseIf dl(i, 1) Like "Z*" Then
      dl(d, 7) = dl(d, 7) + dl(i, 7)
      dl(d, 8) = dl(d, 8) + dl(i, 8)
    End If
  Next
  [B11].Resize(i - 1, 8) = dl
End Sub
Dám cá rằng bài này quanghai chưa tính đến trường hợp mà dl(1,1) không phải là number ---> Có nghĩa là cột 1 của dl người ta bố trí ngược lại
Hay nói cách khác: a, b, c, d là vị trí mà ta đánh dấu. Vậy ngay từ đầu vào vòng lập, gặp ngay thằng Text chứ không phải Number thì cái dấu hiệu ấy ở đâu mà ra?
Ẹc... Ẹc...
Viết code phải tổng quát chút đồng chí à
 
Lần chỉnh sửa cuối:
Upvote 0
ndu96081631 đã viết:
Bố trí code gì mà thụt ra thụt vào tùy tiện quá... nhìn.. đuối luôn
Bố trí như vậy nhìn vào chẳng ai hiểu được dòng nào thuộc "cấp bậc" nào
Bố trí lại đây:

Dám cá rằng bài này quanghai chưa tính đến trường hợp mà dl(1,1) không phải là number ---> Có nghĩa là cột 1 của dl người ta bố trí ngược lại
Hay nói cách khác: a, b, c, d là vị trí mà ta đánh dấu. Vậy ngay từ đầu vào vòng lập, gặp ngay thằng Text chứ không phải Number thì cái dấu hiệu ấy ở đâu mà ra?
Ẹc... Ẹc...
Viết code phải tổng quát chút đồng chí à
Nhấp chuột vào đây để mở rộng...
Em đã nói rồi mà, hỏng trúng thì H Van chịu mà. Ý tưởng thuật toán của em là thế, nếu chưa chuẩn thì trao chuốt tí nữa chắc ok mà.

Cái vụ thụt vào xéo xéo cho đẹp thôi mà.

Còn cái vụ tổng quát gì gì đó thì em chưa đủ kinh nghiệm để soi hết các tình huống. Tuy nhiên em vẫn thích nuôi bệnh hơn là cho uống thuốc 1 liều như anh. Em ở gần nhà bác sĩ mà.
 
Lần chỉnh sửa cuối:
Upvote 0
Đọc mãi mà vẫn cóc hiểu gì ráo
Nhìn vào dữ liệu sắp xếp trong bài thì đây là bài toán tổng con đơn giản mà, viết code chỉ vài dòng là Ok, chỉ khi nào sắp xếp lung tung, mới quan tâm tới mấy em "số" với chả phải "số", "Bê" "Y" với "Bê Em" chứ nhỉ ????
"Kế với chả toán", rắc rối "bà cố". Híc
 
Upvote 0
concogia đã viết:
Đọc mãi mà vẫn cóc hiểu gì ráo
Nhìn vào dữ liệu sắp xếp trong bài thì đây là bài toán tổng con đơn giản mà, viết code chỉ vài dòng là Ok, chỉ khi nào sắp xếp lung tung, mới quan tâm tới mấy em "số" với chả phải "số", "Bê" "Y" với "Bê Em" chứ nhỉ ????
"Kế với chả toán", rắc rối "bà cố". Híc
Nhấp chuột vào đây để mở rộng...

Gần giống như tổng con mà hổng phải tổng con. (vì vùng cần lấy tổng sẽ lấy tất từ trên xuống)
- Chổ nào mà cột 1 là number thì tính SUMIF (sumif theo điều kiện gì thì đã mô tả ở bài 6 đó anh)...
- Còn lại, chổ nào mà cột 1 là Text thì tính MAX
- Mà vùng tính tổng của SUMIF lại lấy kết quả từ MAX ở trên
- Vậy nên, muốn đơn giản thì ta tính MAX trước, xong sẽ tính SUMIF
- Như vậy code phải có 2 vòng lập
- Ở đây em tin rằng bài toán này vừa có thể tính MAX vừa có thể tính SUMIF (kiểu như tính MAX đến đâu thì cộng dồn đến nấy)
Vậy đấy! Mời anh tham gia
Ẹc... Ẹc...
-------------------
quanghai1969 đã viết:
Còn cái vụ tổng quát gì gì đó thì em chưa đủ kinh nghiệm để soi hết các tình huống. Tuy nhiên em vẫn thích nuôi bệnh hơn là cho uống thuốc 1 liều như anh. Em ở gần nhà bác sĩ mà.
Nhấp chuột vào đây để mở rộng...
Cái chữ TỔNG QUÁT ở đây mình muốn nói rằng: Dữ liệu bố trí sao cũng ra kết quả chính xác, thế thôi!
 
Upvote 0
ndu96081631 đã viết:
Gần giống như tổng con mà hổng phải tổng con. (vì vùng cần lấy tổng sẽ lấy tất từ trên xuống)
- Chổ nào mà cột 1 là number thì tính SUMIF (sumif theo điều kiện gì thì đã mô tả ở bài 6 đó anh)...
- Còn lại, chổ nào mà cột 1 là Text thì tính MAX
- Mà vùng tính tổng của SUMIF lại lấy kết quả từ MAX ở trên
- Vậy nên, muốn đơn giản thì ta tính MAX trước, xong sẽ tính SUMIF
- Như vậy code phải có 2 vòng lập
- Ở đây em tin rằng bài toán này vừa có thể tính MAX vừa có thể tính SUMIF (kiểu như tính MAX đến đâu thì cộng dồn đến nấy)
Vậy đấy! Mời anh tham gia
Ẹc... Ẹc...
-------------------
Nhấp chuột vào đây để mở rộng...
Ý mình là thế này, hông biết đúng hông
1)- Bạn chủ topic nói:
-Nếu Mã là 131 thì cộng các mã con có ký tự đầu là B
-Nếu Mã là 331 thì cộng các mã con có ký tự đầu là M
-Nếu Mã là 1388 thì cộng các mã con có ký tự đầu là Y
-Nếu Mã là 3388 thì cộng các mã con có ký tự đầu là Z
Nhưng trong bài bạn í đã sắp xếp dữ liệu "Mã con" nằm đúng vị trí với "Mã...cha" rồi mà, thế thì mình không cần quan tâm tới Mã con nào thuộc nhóm Mã nào nữa
2)- Bi giờ chỉ cần cho chạy từ dưới lên trên, ở cột , em nào là "text"_ Mã con_ thì tính Max dựa theo các cột D, E, F & G ( các cột này bạn í hỏi trong cái topic "Phát sinh công nợ" hay cái quái gì đó dùng Sumproduct ), em nào là "Number" _Mã....cha_thì tính tổng.
Túm lại, nếu mình hiểu trúng dữ liệu luôn được sắp xếp như thế thì code đại khái thế này:
Mã: 
Public Sub LungTungXeng()
    Dim Vung As Variant, ArrKq As Variant, I As Long, TongNo As Double, TongCo As Double, VungTong As Range
    Vung = Range([B11], [B50000].End(xlUp)).Resize(, 6)
    ReDim ArrKq(1 To UBound(Vung), 1 To 2)
        For I = UBound(Vung) To 1 Step -1
            If IsNumeric(Vung(I, 1)) Then
                ArrKq(I, 1) = TongNo:        ArrKq(I, 2) = TongCo
                TongNo = 0:                  TongCo = 0
            Else
                ArrKq(I, 1) = IIf(Vung(I, 3) + Vung(I, 5) > Vung(I, 4) + Vung(I, 6), Vung(I, 3) + Vung(I, 5) - Vung(I, 4) - Vung(I, 6), 0)
                ArrKq(I, 2) = IIf(Vung(I, 3) + Vung(I, 5) < Vung(I, 4) + Vung(I, 6), Vung(I, 4) + Vung(I, 6) - Vung(I, 3) - Vung(I, 5), 0)
                TongNo = TongNo + ArrKq(I, 1): TongCo = TongCo + ArrKq(I, 2)
            End If
        Next I
    [H11].Resize(UBound(Vung), 2) = ArrKq
            Set VungTong = Range([B11], [B50000].End(xlUp))
                For I = 2 To 7
                    [B50000].End(xlUp)(2).Offset(, I) = Application.WorksheetFunction.Sum(VungTong.Offset(, I)) / 2
                Next I
End Sub
Còn nếu hiểu sai thì ...."tèo"
Đã nói "kế với chả toán" rắc rối bà cố
Híc
 
Upvote 0
quanghai1969 đã viết:
Em đã nói rồi mà, hỏng trúng thì H Van chịu mà. Ý tưởng thuật toán của em là thế, nếu chưa chuẩn thì trao chuốt tí nữa chắc ok mà.
Nhấp chuột vào đây để mở rộng...
Hi, anh Hải cứ tưởng em giỏi rồi để em fải đóan mò! Topic này là của em hỏi, nhưng anh còn phải để các thành viên khác học nữa anh ạ!


quanghai1969 đã viết:
Còn cái vụ tổng quát gì gì đó thì em chưa đủ kinh nghiệm để soi hết các tình huống. Tuy nhiên em vẫn thích nuôi bệnh hơn là cho uống thuốc 1 liều như anh. Em ở gần nhà bác sĩ mà.
Nhấp chuột vào đây để mở rộng...
Hên cho anh là không làm bác sỉ, nếu không anh bị bịnh nhân ném đá chết!
 
Upvote 0
Bạn phải đăng nhập hoặc đăng ký để trả lời bài viết tại đây.
Web KT

Bài viết mới nhất

hoangluongvinh
Cách nhặt các dữ liệu bị trùng của 1 đối tượng (3 người xem)
Trả lời
6
Đọc
128
Hai Lúa Miền Tây
Hai Lúa Miền Tây
N
  • Question Question
Cách viết tiếng việt có dấu trong msgbox,....... Hoàn toàn mới (2 người xem)
    • Thích
2
Trả lời
35
Đọc
4K
ligktit
L
T
  • Question Question
Lọc dữ liệu có nhiều điều kiện (3 người xem)
Trả lời
2
Đọc
84
tt_kimbai
T
H
xin mọi người giúp em làm tròn với ạ
Trả lời
4
Đọc
84
NguyenHoangDiep
N
longhungvnpost
cả nhà giúp e tạo ô tìm kiếm gợi ý trong danh sách nhé
Trả lời
3
Đọc
103
longhungvnpost
longhungvnpost
S
Cố định độ rộng/ cao của cột/hàng?
Trả lời
12
Đọc
17K
khanhnth02
K
ongke0711
  • Question Question
Tải hóa đơn điện tử (https://hoadondientu.gdt.gov.vn/) Excel Vba
    • Thích
    • Yêu thích
    • Cảm ơn
15 16 17
Trả lời
329
Đọc
26K
tt_kimbai
T
dung1983
Hỏi về import - Table/ XML cho bảng, trang có chứa JS
Trả lời
0
Đọc
58
dung1983
dung1983
HeSanbi
  • Đã giải quyết
VBA_FastCode v2.22 - Công cụ học và viết mã VBA một cách nhanh nhất (*27/10/2023) (1 người xem)
    • Thích
    • Yêu thích
    • Cảm ơn
2 3
Trả lời
51
Đọc
15K
HeSanbi
HeSanbi
Manhhung90
Mail merge in ấn theo từng trang mong muốn.
Trả lời
1
Đọc
106
Hoàng Tuấn 868
H
L
Xin giúp đỡ đổi màu chữ trong mathtype powerpoint sang màu đen (4 người xem)
Trả lời
4
Đọc
128
LINHCM
L
ongke0711
  • Question Question
Form Đăng nhập và phân quyền cơ bản
    • Thích
2 3
Trả lời
40
Đọc
5K
Gà Công Nghệ
Gà Công Nghệ
vnxgiokinhtoi
Nhờ giúp đỡ công thức lưu dữ liệu và mở lại dữ liệu cũ đã save
Trả lời
6
Đọc
212
DeTong
D
A
  • Question Question
Addin lúc hiện lúc không
Trả lời
1
Đọc
108
anhdepjai
A
T
  • Question Question
Ẩn hiện các sheet khi click vào HyperLink
Trả lời
6
Đọc
295
Gà Công Nghệ
Gà Công Nghệ
20050911
File Excel lỗi ''The file could not be accessed. Try one of the following:.."
Trả lời
17
Đọc
3K
chienthang2682
C
C
Tải kết quả xổ số 3 miền về excel
    • Thích
3 4 5
Trả lời
98
Đọc
13K
HNam_Phan
H
S
Xuất các bảng công phụ từ bảng công chính trong gg sheet
Trả lời
0
Đọc
113
sirhungvla
S
T
Nhờ ACE chỉ giáo công thức Gộp nhiều dữ liệu vào một ô trong excel
Trả lời
11
Đọc
380
Hoàng Tuấn 868
H
PhanTuHuong
Nên chọn điện thoại nào?
2
Trả lời
21
Đọc
1K
minhminh27
minhminh27
Xem thêm…

Thành viên có số lượng bài viết cao nhất tháng

Thành viên có điểm tương tác cao nhất tháng

Đếm ngược thời gian

000
Ngày
00
Giờ
00
phút
00
giây
TALKSHOW KHÁM PHÁ SỨC MẠNH HÀM FILTER TRONG EXCEL 365
Back
Top Bottom