Giúp mình Hàm IF với loại bài này

[kieuviet]

Nếu A< 3 thì C= 15%
Nếu 3 <= A < 5 thì C =14%
Nếu 5<= A < 7 thì C =13%
Neu 7<=A < 9 thì C= 12 %
Nếu 9<= A <11 thì C=11%
Nếu 11 <=A <13 thì C = 10%
Nếu 13<= A < 15 thì C=9%
Nếu 15<=A<20 thì C= 8%
Nếu A >= 20 thì C= 7%

-Mọi người giúp mình mới đang làm cái bảng tính giá mà tắc ở đoạn này.
Thanks!

 

[duongdv]

Bạn thử xem có được không ( Giả sử ô A3 là ô chứa dữ liệu)

=IF(A3>=20,7%,IF(AND(A3>15,A3<20),8%,IF(AND(A3>=15,A3<15),9%,IF(AND(A3>11,A3<13),10%,IF(AND(A3>9,A3<11),11%,IF(AND(A3>7,A3<9),12%,IF(AND(A3>5,A3<7),14%,15%)))))))

 

[hoangminhtien]

Bài này bạn nên dùng hàm VLOOKUP thì tôt hơn. Bạn xem trong file nhé!

 

[duongdv]

Bài này bạn nên dùng hàm VLOOKUP thì tôt hơn. Bạn xem trong file nhé!

Cách mà hoangminhtien dùng hàm vlookup rất gọn về mặt công thức nhưng phải tạo thêm một bảng dữ liệu phụ.

 

[hoangdanh282vn]

Nếu A< 3 thì C= 15%
Nếu 3 <= A < 5 thì C =14%
Nếu 5<= A < 7 thì C =13%
Neu 7<=A < 9 thì C= 12 %
Nếu 9<= A <11 thì C=11%
Nếu 11 <=A <13 thì C = 10%
Nếu 13<= A < 15 thì C=9%
Nếu 15<=A<20 thì C= 8%
Nếu A >= 20 thì C= 7%

-Mọi người giúp mình mới đang làm cái bảng tính giá mà tắc ở đoạn này.
Thanks!

Bạn dùng tạm cái này nha, có thể mở rộng thêm cho nhiều trường hợp nữa. Nếu If thì chỉ có 7 thôi.

=((A1>0)*(A1<3)*15+(A1>=3)*(A1<5)*14+(A1>=5)*(A1<7)*13+(A1>=7)*(A1<9)*12+(A1>=9)*(A1<11)*11+(A1>=11)*(A1<13)*10+(A1>=13)*(A1<15)*9+(A1>=15)*(A1<20)*8+(A1>=20)*7)%

 

[BNTT]

Bạn thử xem có được không ( Giả sử ô A3 là ô chứa dữ liệu)

=IF(A3>=20,7%,IF(AND(A3>15,A3<20),8%,IF(AND(A3>=15,A3<15),9%,IF(AND(A3>11,A3<13),10%,IF(AND(A3>9,A3<11),11%,IF(AND(A3>7,A3<9),12%,IF(AND(A3>5,A3<7),14%,15%)))))))

Cái chỗ màu đỏ í... sẽ làm cho công thức này ra kết quả như thế nào nhỉ ?

 

[hoangdanh282vn]

Bạn thử xem có được không ( Giả sử ô A3 là ô chứa dữ liệu)

=IF(A3>=20,7%,IF(AND(A3>15,A3<20),8%,IF(AND(A3>=15,A3<15),9%,IF(AND(A3>11,A3<13),10%,IF(AND(A3>9,A3<11),11%,IF(AND(A3>7,A3<9),12%,IF(AND(A3>5,A3<7),14%,15%)))))))

Cái này chưa chính xác
Gửi bạn thêm 1 công thức :

=LOOKUP(A1+1,{0;4;6;8;10;12;14;16;21},{15;14;13;12;11;10;9;8;7})%

 

[BNTT]

Cái này chưa chính xác
Gửi bạn thêm 1 công thức :

=LOOKUP(A1+1,{0;4;6;8;10;12;14;16;21},{15;14;13;12;11;10;9;8;7})%

Góp thêm một cái, ngắn hơn một tí ti:

=IF(A1>=20,7,IF(A1>=15,8,16-(MOD(A1,15)+MOD(A1,2))/2))%

 

[hoangdanh282vn]

Góp thêm một cái, ngắn hơn một tí ti:

=IF(A1>=20,7,IF(A1>=15,8,16-(MOD(A1,15)+MOD(A1,2))/2))%

Ngắn hơn tí tí nữa

=IF(A1>=20,7,MAX(INT(16-(A1/2)),8))%

 

[ndu96081631]

Ngắn hơn tí tí nữa

=IF(A1>=20,7,MAX(INT(16-(A1/2)),8))%

Chưa chính xác à nha ---> Hãy thử với số <= 0 xem
chắc hoangdanh quên "rào" vụ này bằng hàm MIN
=IF(A1>=20,7,MIN(MAX(INT(16-(A1/2)),8),15))%