Giúp mình cách gửi mail cho tất cả có trong file excel

[TuyenNgo85]

Mình ko rành về Excel lắm mong mọi người giúp,
Mình muốn gữi mail cho mọi người vào buổi sáng mà sl quá nhiều nên làm tay rất khó.
Nội dung đại loại:
" Dear Mr or Ms AAAA
Hello Chuc buoi sang tot lanh "

Chỉ vậy thôi, mình có gữi file excel cho rõ mong mọi người giúp.

Thanks

 

[Hai Lúa Miền Tây]

Mình ko rành về Excel lắm mong mọi người giúp,
Mình muốn gữi mail cho mọi người vào buổi sáng mà sl quá nhiều nên làm tay rất khó.
Nội dung đại loại:
" Dear Mr or Ms AAAA
Hello Chuc buoi sang tot lanh "

Chỉ vậy thôi, mình có gữi file excel cho rõ mong mọi người giúp.

Thanks

Code theo file của bạn sẽ như sau:

Sub SendMail()
    Dim OutApp As Object, OutMail As Object, Addresslist As Object
    Dim cell As Range
    Application.ScreenUpdating = False
    Set Addresslist = CreateObject("Scripting.Dictionary")
    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon

    For Each cell In Columns("e").Cells.SpecialCells(xlCellTypeConstants)
        If cell.Value Like "?*@?*.?*" Then
            On Error Resume Next
            Addresslist.Add cell.Value, cell.Value
            If Err.Number = 0 Then
                Set OutMail = OutApp.CreateItem(0)
                With OutMail
                    .To = cell.Value
                    .Subject = "Hello: " & Cells(cell.Row, "b").Value
                    .Body = "Dear " & IIf(Cells(cell.Row, "c").Value = "M", "Mr ", "Ms ") & _
                            Cells(cell.Row, "b").Value & _
                            vbNewLine & vbNewLine & _
                            [d2] & _
                            vbNewLine & vbNewLine & _
                            "Thanks and best regards" & _
                            vbNewLine & _
                            "HLMT"
                    .Display  'Or use Send
                End With
                Set OutMail = Nothing
            End If
            On Error GoTo 0
        End If
    Next cell

    Set OutApp = Nothing
    Set Addresslist = Nothing
    Application.ScreenUpdating = True
End Sub

P/S: Bạn định spam hay là quảng cáo mà gửi mail như thế?
Đừng làm phiền mọi người nhé.

 

[TuyenNgo85]

Thank bạn nhiều, không mình ko có spam đâu, nội dung mình muốn đơn giản lại câu hỏi nên ghi linh tinh vậy đó. Lúc vào việc sẻ thay đỗi lại nội dung mà.