Giúp em công thức tăng giá với ạ

[ThuyTrang79]

Em chào anh chị !
Em có gởi file mô tả kèm theo (mô tả ở cột H), trong file em muốn tạo giá mới theo chiếu khấu mới, nhưng giá mới sau chiết khấu mới bằng hoặc cao hơn 1 tí so với chiếu khấu cũ, và làm tròn với bội số 50k,
Nhờ anh chị giúp công thức ở cột E với ạ, em cảm ơn anh chị nhiều !

 

[VetMini]

Công thức tínhn giá bạn dùng nhiều IF's quá; nhìn hơi rối.
Nếu có thể sửa lại.
Giá cũ (sau CK):
=C2*CHOOSE(MATCH(C2+0.001, {0,1000,4000,10000,40000}, 1), 70%, 75%, 80%,85%, 90%)
Giá mới (sau CK):
=E2*CHOOSE(MATCH(E2+0.001, {0,1000,5000,50000,200000}, 1), 70%, 75%, 80%,85%, 90%)
Để bảo đảm là nó phải lớn hơn hoặc bằng giá cũ, thêm hàm MAX
=MAX(D2, E2*CHOOSE(MATCH(E2+0.001, {0,1000,5000,50000,200000}, 1), 70%, 75%, 80%,85%, 90%))

Tôi không hiểu làm tròn là trước hay sau khi so sánh giá cũ. Bạn tự tìm hiểu lấy phần làm tròn.

Chỉnh sửa: công thức trên tôi nhầm một chút ở chỗ nâng trị cần tìm lên một chút bằng cách +0.001
Trong bài này điều kiện là >= [ 0, 1000, 4000, ... ] cho nên không cần phải cộng 0.001

 

[ThuyTrang79]

Công thức tínhn giá bạn dùng nhiều IF's quá; nhìn hơi rối.
Nếu có thể sửa lại.
Giá cũ (sau CK):
=C2*CHOOSE(MATCH(C2+0.001, {0,1000,4000,10000,40000}, 1), 70%, 75%, 80%,85%, 90%)
Giá mới (sau CK):
=E2*CHOOSE(MATCH(E2+0.001, {0,1000,5000,50000,200000}, 1), 70%, 75%, 80%,85%, 90%)
Để bảo đảm là nó phải lớn hơn hoặc bằng giá cũ, thêm hàm MAX
=MAX(D2, E2*CHOOSE(MATCH(E2+0.001, {0,1000,5000,50000,200000}, 1), 70%, 75%, 80%,85%, 90%))

Tôi không hiểu làm tròn là trước hay sau khi so sánh giá cũ. Bạn tự tìm hiểu lấy phần làm tròn.

Dạ trong file vd thì em thay đổi CK mặc định mới theo "CK mới", em cần công thức tạo ra giá mới ở cột E, cột E em đang nhập đó là em nhập vd ạ
Điều kiện để tạo ra giá mới cột E là khi áp dụng theo CK mới thì kết quả ra bằng hoặc lớn hơn kết quả của CK cũ sao cho thay đổi nhỏ nhất có thể ạ.

 

[ThuyTrang79]

Nhờ anh chị giúp em với ạ !

 

[huuthang_bd]

Bạn nên nêu rõ điều kiện ra. Tính toán bằng những con số cố định mà "Sao cho thay đổi nhỏ nhất có thể" là sao.

 

[HieuCD]

Em chào anh chị !
Em có gởi file mô tả kèm theo (mô tả ở cột H), trong file em muốn tạo giá mới theo chiếu khấu mới, nhưng giá mới sau chiết khấu mới bằng hoặc cao hơn 1 tí so với chiếu khấu cũ, và làm tròn với bội số 50k,
Nhờ anh chị giúp công thức ở cột E với ạ, em cảm ơn anh chị nhiều !

E2 =CEILING(INDEX(D2/{0.7;0.75;0.8;0.85;0.9},MATCH(D2,{0;1000;5000;50000;200000}*{0.7;0.75;0.8;0.85;0.9}),),50)
E2 =CEILING(INDEX(D2/{0.7;0.75;0.8;0.85;0.9},MATCH(D2,{0;750;4000;42500;180000}),),50)

Copy xuống

 

[ThuyTrang79]

Bạn nên nêu rõ điều kiện ra. Tính toán bằng những con số cố định mà "Sao cho thay đổi nhỏ nhất có thể" là sao.

E2 =CEILING(INDEX(((D2/{0.7;0.75;0.8;0.85;0.9})>=C2)*(D2/{0.7;0.75;0.8;0.85;0.9}),MATCH(D2,{0;1000;5000;50000;200000}*{0.7;0.75;0.8;0.85;0.9}),),50)

Copy xuống

Dạ công thức hay, chạy OK rồi ạ, em cảm ơn anh nhiều !

 

[huuthang_bd]

Tôi cứ tưởng là tính giá chiết khấu mới.
Giá chiết khấu cũ:

D2=C2*(13+MATCH(C2,{0;1;4;10;40}*1000))*5%

Giá mới:

E2=CEILING(D2/(13+MATCH(D2,{0;0.75;4;42.5;180}*1000))/5%,50)

Giá chiết khấu mới:

F2=E2*(13+MATCH(E2,{0;1;5;50;200}*1000))*5%

 

[ThuyTrang79]

Tôi cứ tưởng là tính giá chiết khấu mới.
Giá chiết khấu cũ:

D2=C2*(13+MATCH(C2,{0;1;4;10;40}*1000))*5%

Giá mới:

E2=CEILING(D2/(13+MATCH(D2,{0;0.75;4;42.5;180}*1000))/5%,50)

Giá chiết khấu mới:

F2=E2*(13+MATCH(E2,{0;1;5;50;200}*1000))*5%

E2 =CEILING(INDEX(D2/{0.7;0.75;0.8;0.85;0.9},MATCH(D2,{0;1000;5000;50000;200000}*{0.7;0.75;0.8;0.85;0.9}),),50)
E2 =CEILING(INDEX(D2/{0.7;0.75;0.8;0.85;0.9},MATCH(D2,{0;750;4000;42500;180000}),),50)

Copy xuống

Em cảm ơn anh ạ !