Code cập nhật dữ liệu từ form xuống sheet?

[Nguoiay]

Em đang thiết lập form cập nhật dữ liệu từ form xuống sheet. Em muốn nhờ mọi người tạo giúp em đoạn code cập nhật dữ liệu từ các ô trên xuống các trường của sheet tương ứng?
Cám ơn nhiều ạ!

 

[batman1]

1. Dùng OFFSET và mảng text

Private Sub cLuu_Click()
Dim c As Long, text
    text = Array("txtNgay", "txtSoPhieu", "txtMSKH", "txtTenKH", "txtDienGiai", "txtThu")
    With ThisWorkbook.Worksheets("Database").Cells(Rows.Count, "A").End(xlUp).Offset(1)
        For c = LBound(text) To UBound(text)
            .Offset(0, c).Value = Me.Controls(text(c)).Value
        Next c
    End With
End Sub

2. Không dùng OFFSET và mảng text

Private Sub cLuu_Click()
Dim lastRow As Long
    With ThisWorkbook.Worksheets("Database")
        lastRow = .Cells(Rows.Count, "A").End(xlUp).Row + 1
        .Range("A" & lastRow).Value = txtNgay.Value
        .Range("B" & lastRow).Value = txtSoPhieu.Value
        .Range("C" & lastRow).Value = txtMSKH.Value
        .Range("D" & lastRow).Value = txtTenKH.Value
        .Range("E" & lastRow).Value = txtDienGiai.Value
        .Range("F" & lastRow).Value = txtThu.Value
    End With
End Sub

Dùng mảng text (và OFFSET) nên dùng được FOR ... NEXT. Code rút ngắn được