Chuyên mục GIẢI THÍCH CÔNG THỨC (4 người xem)

[lthl86]

Hi cả nhà.
Cả nhà cho mình hỏi câu này với nhé?
trong exell mình muốn quy đổi thời gian VD 5:50p thành giờ (5h50p = 5.83h) thì dùng công thức gì được ạ.

Cả nhà giúp mình với nhé, cám ơn nhiều

 

[LinDan]

Nhờ các bác giải thích dùm tôi công thức của thày Ndu

=SUMPRODUCT((COUNTIF(D3,"*"&$A$3:$A$13&"*")*$B$3:$B$13))

trong đó đặc biệt là thành phần "*"&$A$3:$A$13&"*" tôi chẳng hiểu gì cả (mặc dù đọc trên diễn đàn thấy bảo * là đại diện cho các ký tự bằng chữ ---> nhưng vẫn không hiểu)

Xin cảm ơn.

 

[readme]

Giải thích giúp công thức tính số ngày chủ nhật trong một khoảng thời gian

Chào cả nhà!
Mình có gặp hàm tính số ngày chủ nhật trong một khoảng thời gian.
công thức như sau:
=INT((F12-E12-WEEKDAY(F12)+8)/7)
Mình thấy ra kết quả đúng nhưng không hiểu lắm về thuật toán của nó.
Cả nhà giúp mình dùm nha.
Cảm ơn cả nhà!

 

[tvxdgt]

Chào cả nhà!
Mình có gặp hàm tính số ngày chủ nhật trong một khoảng thời gian.
công thức như sau:
=INT((F12-E12-WEEKDAY(F12)+8)/7)
Mình thấy ra kết quả đúng nhưng không hiểu lắm về thuật toán của nó.
Cả nhà giúp mình dùm nha.
Cảm ơn cả nhà!

Bạn đọc giải thích của anh NDU , hàm này giãi thích thuật toán khó thật:

=INT((A2-A1-WEEKDAY(A2-6,2) +8)/7)
Công thức này phải khai triển thế này mới có thể hiểu được
=INT(((A2 - WEEKDAY(A2-6,2)+7)-A1+1))/7)
Với WEEKDAY(A2-6,2) chính bằng WEEKDAY(A2)
Vậy viết lại công thức:
=INT(((A2 - WEEKDAY(A2)+7)-A1+1))/7)
Ta xét (A2 - WEEKDAY(A2)+7) ----> Một ngày trừ đi WEEKDAY của ngày ấy rồi cộng thếm 7 sẽ luôn luôn là ngày thứ 7 tới ---> Và sự gia giảm này không hề làm thay đổi tổng số ngày CN (Ý nghĩa của sự gia giảm này là "dịch" ngày cuối cùng đến ngày thứ 7 tới gần nhất)
Giả sử ta đặt NCGL = (A2 - WEEKDAY(A2)+7) tạm gọi là ngày cuối giả lập
(A2 - WEEKDAY(A2)+7)-A1+1 = NCGL- A1+1 Chính là tổng số ngày
Phần nguyên của phép chia NCGL- A1+1 với 7 chính là tổng số ngày CN ---> Vậy thôi
---------------------
Thuật toán có thể hiểu ngay (nằm ở chổ A2 - WEEKDAY(A2)+7 ấy), nhưng giải thích quả thật là khó... Hic...

 

[PHONGGANHHAO]

1/ IF(TYPE(MATCH($B$1;HDTU!$E$3:$E$4385;0))=16;"";MAT CH($B$1;HDTU!$E$3:$E$4385;0))
<Hàm này có ý nghĩa gì ? Và Số “16” có ý nghĩa gì?>

2/ IF(TYPE(MATCH($B$1;OFFSET(HDTU!$E$3;G5;0):HDTU!$E$ 4385;0)+G5)=16;"";MATCH($B$1;OFFSET(HDTU!$E$3;G5;0 ):HDTU!$E$4385;0)+G5)
<Hàm này có ý nghĩa gì ? >
Tại sao 2 hàm này nằm cùng 1 cột mà công thức khác nhau. VDỤ: Có 10 hàng thì Hàng1 là công thức 1. Còn 9 hàng kia là cthức 2


3/ IF(ISNA(VLOOKUP(E6;DMNV!$A$2:$K$4258;2;0)); ;VLOOKUP(E6;DMNV!$A$2:$K$4258;2;0))
<Hàm này có ý nghĩa gì ? Tại sao lại có 2 dấu “chấm phẩy: ; ; nằm gần nhau>​

​

 

[bebo021999]

1- Hàm TYPE sẽ trả về 1 con số quy định loại của biểu thức bên trong. Nếu biểu thức trả về lỗi thì TYPE() = 16. Trường hợp của bạn là MATCH không tìm thấy.
2- Từ dòng thứ 2 trở đi , phạm vi tìm kiếm sẽ thay đổi vào giá trị tại ô G5
3- Nếu VLOOKUP không tìm thấy thì trả về 0. Hai dấu ;; tương đương với ;0;

 

[lthl86]

Huhu có ai giúp mình trả lời câu hỏi này hộ mình với.
Cám ơn rất nhiều

Hi cả nhà.
Cả nhà cho mình hỏi câu này với nhé?
trong exell mình muốn quy đổi thời gian VD 5:50p thành giờ (5h50p = 5.83h) thì dùng công thức gì được ạ.

Cả nhà giúp mình với nhé, cám ơn nhiều

 

[Ba Tê]

Huhu có ai giúp mình trả lời câu hỏi này hộ mình với.
Cám ơn rất nhiều

Nếu kiểu dữ liệu của bạn là kiểu text 5:50p thì tôi cũng hu hu luôn.
Nếu là kiểu Time thì lấy nó nhân với 24, định dạng kiểu số là ra kết quả.
Ví dụ A1 = 5:50:00
A2= A1*24
Định dạng A1 kiểu Number, 2 số lẻ, sẽ thành 5.83
Định dạng kiểu General sẽ thành 5.833333... Tùy bạn thích.

 

[lthl86]

Cám ơn Cạo Rổi Khỏi Gội rất nhiều. mình đã áp dụng và làm được rồi giờ thì khồn phải huhu mà là hihihi rùi.
Nhưng bác cho em hỏi tẹo nữa nhá. A2= A1*24 nghĩa là gì vậy? sao lại nhân với 24 nhỉ? nêu em chỉ biết áp dụng thôi mà không hiểu hì ngại lắm,phiền bác chỉ thêm cho em với nhé. thanks bác nhiều

Nếu kiểu dữ liệu của bạn là kiểu text 5:50p thì tôi cũng hu hu luôn.
Nếu là kiểu Time thì lấy nó nhân với 24, định dạng kiểu số là ra kết quả.
Ví dụ A1 = 5:50:00
A2= A1*24
Định dạng A1 kiểu Number, 2 số lẻ, sẽ thành 5.83
Định dạng kiểu General sẽ thành 5.833333... Tùy bạn thích.

 

[nghiaphuc]

Nhưng bác cho em hỏi tẹo nữa nhá. A2= A1*24 nghĩa là gì vậy? sao lại nhân với 24 nhỉ? nêu em chỉ biết áp dụng thôi mà không hiểu hì ngại lắm,phiền bác chỉ thêm cho em với nhé. thanks bác nhiều

1 ngày có giá trị là 1, trong 1 ngày lại có 24 giờ, như vậy 1 giờ có giá trị là 1/24. Tóm lại là muốn máy hiểu 1 giờ tương ứng với số 1 thì phải lấy giờ nhân với 24.

 

[lthl86]

1 ngày có giá trị là 1, trong 1 ngày lại có 24 giờ, như vậy 1 giờ có giá trị là 1/24. Tóm lại là muốn máy hiểu 1 giờ tương ứng với số 1 thì phải lấy giờ nhân với 24.

Cám ơn Bác nghiaphuc nhiều nhé. Em vẫn hơi lơ mơ nhưng cũng... hơi hiểu rồi ạ hihi. Túm lại là nếu ai hỏi thì em sẽ giải thích giống Bác hi.

 

[vodoi2x]

Cám ơn Bác nghiaphuc nhiều nhé. Em vẫn hơi lơ mơ nhưng cũng... hơi hiểu rồi ạ hihi. Túm lại là nếu ai hỏi thì em sẽ giải thích giống Bác hi.

Nghĩa là :
Đơn vị thời gian trong excel (time hay date) đều là theo ngày hết
Vì thế muốn quy đổi giờ / phút / giây --> thành số liệu ngày thì phải nhân theo tỷ lệ hợp lý, dựa vào:

1 ngày=24 giờ = 24*60 phút = 24*60*60 giây

cứ thế mà đổi là ra tất

 

[597335]

Nhờ mọi người giải đáp dùm em công thức:

 =Lookup(max(A1:E1)+1, A1:E1)

 

[ndu96081631]

Nhờ mọi người giải đáp dùm em công thức:

 =Lookup(max(A1:E1)+1, A1:E1)

Đối với hàm LOOKUP, nếu giá trị tìm là cực lớn thì nó sẽ lấy giá trị cuối cùng có dữ liệu trong mảng
Theo công thức trên, max(A1:E1)+1 là giá trị lớn hơn mọi giá trị có trong A1:E1 (vì có cộng thêm 1) nên nó sẽ tìm cell cuối cùng có dữ liệu trong vùng A1:E1
Vậy thôi

 

[HONGTBM]

=if(or(left(c9,3)="p20",left(c9,3)="618"),(if(len(d9)=11,(left(d9,3)+3)&"*"&(mid(d9,5,3)+3),(if(len(d9)=10,(left(d9,3)+3)&"*"&(mid(d9,5,3)+3),(if(len(d9)=9,(left(d9,3)+3)&"*"&(mid(d9,5,2)+3),(if(len(d9)=8,(left(d9,2)+3)&"*"&(mid(d9,4,2)+3)))))))))&"*"&'618'!b9,"")
kq sao bi mat 02 kyù tu cuoi cung???lam on giup em voi anh chi oi!huhu

nghiaphuc: Lần sau nhớ gõ tiếng Việt có dấu nha bạn. Nếu không, bài sẽ bị xóa đấy.

 

[Dauthivan]

Nhờ sửa dùm công thức tính tổng A1 của tất cả các Sheet

Em muốn làm ví dụ đơn giản, tính tổng tất cả các ô A1 của các sheet, cụ thể trong bài này của em là 3 Sheet, công thức em dự kiến làm là

=SUMPRODUCT(INDIRECT("Sheet"&ROW(1:3)&"!A1"))

không biết phải sửa thế nào cho đúng? Xin hãy giúp em với

 

[ndu96081631]

Em muốn làm ví dụ đơn giản, tính tổng tất cả các ô A1 của các sheet, cụ thể trong bài này của em là 3 Sheet, công thức em dự kiến làm là

=SUMPRODUCT(INDIRECT("Sheet"&ROW(1:3)&"!A1"))

không biết phải sửa thế nào cho đúng? Xin hãy giúp em với

Gần đúng rồi đấy... chỉ sửa lại tí thôi:

=SUMPRODUCT(N(INDIRECT("Sheet"&ROW(1:3)&"!A1")))

Cứ thuộc lòng cái này: Cộng 1 ô trong tất cả các sheet phải luôn có hàm N()
Ẹc... Ẹc...

 

[tvxdgt]

Em muốn làm ví dụ đơn giản, tính tổng tất cả các ô A1 của các sheet, cụ thể trong bài này của em là 3 Sheet, công thức em dự kiến làm là

=SUMPRODUCT(INDIRECT("Sheet"&ROW(1:3)&"!A1"))

không biết phải sửa thế nào cho đúng? Xin hãy giúp em với

Sao bạn không dùng công thức đơn giản này nhỉ:

=SUM(Sheet1:Sheet3!A1)

 

[Dauthivan]

Vì mình đang muốn học thêm cái Indirect xem nó như thế nào ấy mà?

 

[ndu96081631]

Sao bạn không dùng công thức đơn giản này nhỉ:

=SUM(Sheet1:Sheet3!A1)

Đó chỉ là 1 ví dụ để tìm hiểu thôi!
Đương nhiên sẽ có những trường hợp đặc biệt cần xài đến