Các bác giúp hàm sắp xếp này với

[quocphu67]

Như file em gửi ở sheet CD: hàng 1 là giá trị X, Cột A là giá trị Y... bên trong là giá trị đo được... em muốn xắp xếp thành bảng giống sheet CMap thì làm như thế nào?
http://www.mediafire.com/view/?9zo571d50h7dqem

 

[quocphu67]

ko có bác nào giúp à???

 

[SA_DQ]

Macro ốc sên

[thongbao]ko có bác nào giúp à???[/Thongbao]

Kiểm số liệu theo macro tạm này thử coi.

 

[ndu96081631]

ko có bác nào giúp à???

Bài này tôi nghĩ nếu dùng code VBA sẽ khỏe thân hơn
1> Viết 1 hàm chuyển đổi vị trí của các phần tử trong Table

Function TransferTable(ByVal rngData As Range)
  Dim tmpArr, Arr()
  Dim lR As Long, lC As Long, n As Long
  With rngData
    If .Count >= 4 Then
      tmpArr = .Value
      ReDim Arr(1 To .Rows.Count * .Columns.Count, 1 To 3)
      For lC = 2 To UBound(tmpArr, 2)
        For lR = 2 To UBound(tmpArr, 1)
          n = n + 1
          Arr(n, 1) = tmpArr(1, lC)
          Arr(n, 2) = tmpArr(lR, 1)
          Arr(n, 3) = tmpArr(lR, lC)
        Next
      Next
    End If
  End With
  If n Then TransferTable = Arr
End Function

2> Code chính:

Sub Main()
  Dim Arr
  Arr = TransferTable(Sheets("CD").Range("A1").CurrentRegion)
  If IsArray(Arr) Then Sheets("CMap").Range("A2").Resize(UBound(Arr, 1), UBound(Arr, 2)).Value = Arr
End Sub