Bỏ bớt ký tự có điều kiện

[leolas]

Mình đang có một cột chứa các chuổi ký tự như sau:
190419HF190401631
260319260319DUSA05696
260319DUSA04627
30042019SAG332165
....
Mình muốn xóa các số đứng trước chữ cái đi chỉ còn như vầy:
HF190401631
DUSA05696
DUSA04627
SAG332165
....
Mình không biết dùng công thức thế nào để xóa. Các bác trên diễn đàn giúp mình với. Cám ơn

 

[Phuocam]

Thử công thức này:

=REPLACE(A1,1,MATCH(TRUE,INDEX(ISERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)),0),0)-1,"")

 

[huuthang_bd]

Mình đang có một cột chứa các chuổi ký tự như sau:
190419HF190401631
260319260319DUSA05696
260319DUSA04627
30042019SAG332165
....
Mình muốn xóa các số đứng trước chữ cái đi chỉ còn như vầy:
HF190401631
DUSA05696
DUSA04627
SAG332165
....
Mình không biết dùng công thức thế nào để xóa. Các bác trên diễn đàn giúp mình với. Cám ơn

Bạn dùng công thức mảng này:

=MID(A1,MIN(IFERROR(SEARCH(CHAR(ROW($A$65:$A$90)),A1),FALSE)),99)

 

[Phan Thế Hiệp]

Cho chơi với!

Thêm một cách nữa để chủ thớt tham khảo:
A1="190419HF190401631"

B1=SUBSTITUTE(A1,LOOKUP(10^35,--LEFT(A1,ROW($1:$15))),"")
Hoặc:
B1=MID(A1,LEN(LOOKUP(10^35,--LEFT(A1,ROW($1:$15))))+1,100)

Enter, fill xuống.

Thân

 

[Phuocam]

Cho chơi với!

Gặp trường hợp có số 0 đầu thì tèo, như:

00190419HF190419031

 

[Phan Thế Hiệp]

Gặp trường hợp có số 0 đầu thì tèo, như:

00190419HF190419031

Ừ hén!
Dzậy chơi vầy:

=MID(A1,MATCH(,ISNUMBER(--MID(A1,ROW($1:$100),1))+0,),100)

Ctrl+Shift+Enter

=MID(A1,MATCH(,INDEX(ISNUMBER(--MID(A1,ROW($1:$100),1))+0,),),100)
Hoặc:
=MID(A1,MATCH(1,INDEX(ISERR(--MID(A1,ROW($1:$100),1))+0,),),100)
Hoặc:
=MID(A1,MATCH(10^35,INDEX(--LEFT(A1,ROW($1:$100)),))+1,100)

Chỉ Enter.

Chúc anh em ngày vui.

 

[leolas]

Chân thành cám ơn các bác đã tận tình giúp đỡ. Rất mong được học hỏi thêm từ các bác.

 

[Nguyễn Hồng Quang]

Kể từ hôm được thưởng thức đặc sản cây nhà lá vườn , bình mới (sách mới ra) của GPE , em lại đâm ra thích áp dụng. Góp vui với các anh và bạn leolas 2 cái ma cờ rô nho nhỏ. Chúc cả nhà ngày vui