Bảng excel đánh giá năng suất để tính thưởng??

[Forever Lover]

Staythesame, sure, mình đang nghiên cứu bài của bạn nè, thiệt tình là hàm IF mình dễ hiểu hơn, hihi

Thanks nhiều lắm

 

[Forever Lover]

Staythesame ơi, mình thử các trường hợp đều OK (điểm >20, <20) theo đúng ý mình muốn, riêng trường hợp CHUẨN tức tất cả các cột điểm đều đạt 4, tức điểm = 20, thì lại không ra, vậy là công thức thiếu trường hợp điểm = 20 phải không bạn?

Cũng nhờ bạn giải thích bằng lời cho mình hiểu nếu ...thì ....theo thứ tự trong công thức sau của bạn, cho mình hiểu rõ với nhe :


=IF(AND(I8>20,MIN(D8,E8,F8,G8,H8)>=4),120%,IF(AND(I8>20,MIN(D8,E8,F8,G8,H8)<4),100%,""))

và

=MAX(L8,M8)*IF(C8=1,N$5,IF(C8=0,N$4,""))

Cao Mạnh Sơn, mình thử các trường hợp theo công thức của bạn, đều OK, nhưng thú thiệt, mình không hiểu lắm về cái công thức này, nhờ bạn giải thích bằng lời cụ thể ra, nếu gì thì ...gì theo thứ tự công thức dưới của bạn, cho mình hiểu với được không ?

=IF(AND(COUNTIF(D8:H8,"<4")<>0,J8<0),VLOOKUP(C8,CV,2,0),VLOOKUP(J8,HS,2,1)*VLOOKUP(C8,CV,2,0))

Các bạn thông cảm, mình không thể trình ra 1 khi chưa hiểu rõ chi tiết. Cảm ơn các bạn

 

[Cao Mạnh Sơn]

, nhờ bạn giải thích bằng lời cụ thể ra, nếu gì thì ...gì theo thứ tự công thức dưới của bạn, cho mình hiểu với được không ?

=IF(AND(COUNTIF(D8:H8,"<4")<>0,J8<0),VLOOKUP(C8,CV,2,0),VLOOKUP(J8,HS,2,1)*VLOOKUP(C8,CV,2,0))

Này nhé hàm Countif : Đếm các cell từ D8 đến H8 nếu có cell nào nhỏ hơn 4(có nghĩa là 1 trong các tiêu chí đã bị trừ điểm) và cell J8<0 (có nghĩa là tổng điểm các tiêu chí >20),Thỏa mãn 2 điều kiện trên(2 đối số của hàm And) thì tìm trong vùng CV giá trị của cell c8,nếu thấy sẽ trả về giá trị của cột thứ 2 trong vùng CV,số 0 trong hàm Vookup sẽ trả về giá trị chính xác tương ứng với C8(tức là nếu C8 là nhân viên sẽ cho giá trị 500.000,là QL sẽ cho giá trị 700.000).Nếu không thỏa mã 2 điều kiện trên thì sẽ thực hiện phép tính:VLOOKUP(J8,HS,2,1)*VLOOKUP(C8,CV,2,0)
1-Tìm theo J8 trong vùng HS giá trị tương đối của J8,nếu thỏa mãn trả về giá trị tương ứng ở cột thứ 2(kết quả sẽ là 120%,100%,90% tùy theo J8,nếu J8=0.5(0<J8<1 trong bảng HS) sẽ cho giá trị 100%
2-Tìm chính xác theo giá trị của C8(nhân viên,quản lý) trong vùng CV,nếu thỏa mãn trả về giá trị tương ứng ở cột thứ 2(Kết quả sẽ là 500.000 hoặc 700.000)
3-thực hiện nốt phép tính nhân
Hy vọng bạn hiểu.Hàm Vlookup hay lắm đó.

 

[BNTT]

Không hiểu sao có bạn lại không thể mở cái file của tôi post lên. Và cũng nhân tiện có bạn PM cho tôi nhờ giải thích công thức, nên tôi xin trình bày luôn ở đây:

Dựa vào file và yêu cầu của Forever Lover, tôi tạo một bảng tính như vầy:

Ở góc dưới, bên trái, có hai cái bảng để tra dữ liệu. Sở dĩ tôi làm hai cái bảng này, để tránh phải dùng IF quá nhiều trong công thức tính thưởng, dễ bị sai, mà cũng khó đọc. Trong đó:

- Dãy A19:B20 tôi đặt tên là THUONG
- Dãy A2324, tôi đặt tên là DIEMTRU​

Công thức để tính tổng điểm thì dễ rồi (cột I), dùng hàm SUM.

Công thức để tính số điểm trừ, tôi dùng COUNTIF để đếm tất cả những ô nào có số điểm nhỏ hơn 4, rồi nhân kết quả này cho 4, rồi trừ đi tổng của những ô có số điểm nhỏ hơn 4 (dùng SUMIF). Đây là công thức (tại J5) :

(J5) = COUNTIF(D5:H5,"<4")*4 - SUMIF(D5:H5,"<4")​

Công thức này hơi lắc léo, nhưng nó tính được chính xác số điểm trừ của những người có tổng điểm > 20.

Và đây là công thức tại cột L, tính điểm thưởng:

(L5) = HLOOKUP(C5,THUONG,2,0) * IF(AND(I5>=20,J5=0),120%, IF(AND(I5>=20,J5>0),100%, HLOOKUP(J5,DIEMTRU,2)))​

Dùng hàm HLOOKUP, đem mã số (1 hay là 0, phân biệt giữa Supervisor và NV) đi dò với bảng THUONG, để lấy số tiền thưởng chuẩn ở hàng thứ 2, với cách dò chính xác.
Rồi lấy kết quả này nhân với:

IF(AND(I5>=20,J5=0),120% : Nếu tổng điểm lớn hơn hoặc bằng 20, và không có điểm trừ, nhân với 120%

IF(AND(I5>=20,J5>0),100% : Nếu tổng điểm lớn hơn hoặc bằng 20, và có điểm trừ, nhân với 100%

HLOOKUP(J5,DIEMTRU,2) : Còn không (nghĩa là không rơi vào 2 trường hợp trên, thì đem số điểm trừ đi dò với bảng DIEMTRU, và nhân với con số tương ứng ở hàng thứ 2 (từ 0.5 đến 1.5 là 90%, từ 2 đến 2.5 là 80%, từ 3 đến 4 là 90%, hơn 4 thì không thưởng)​

Ở hàm HLOOKUP trên đây, tôi dùng cách dò là không chính xác (không có tham số thứ tư), nghĩa là, nếu như không tìm thấy giá trị muốn dò, thì lấy giá trị nhỏ nhất mà lớn hơn giá trị muốn dò. Cách dò này chuyên để trị kiểu "dò trong một khoảng nào đó". Ở bảng DIEMTRU, bạn thấy có con số 4.1, đó là vì, theo đề bài, cho đến 4 điểm trừ vẫn được thưởng 60%, chỉ khi nào trên 4 điểm trừ (> 4) mới không thưởng, nên tôi phải dùng cái mánh là nhích con số 4 lên một tí, bằng 4.1. Nếu ở đó mà tôi để số 4, thì có nghĩa là từ 4 điểm trừ trở lên (>= 4) sẽ không được thưởng, sai mất.

Hy vọng bài của tôi được tác giả cho điểm 9.9 (/10)...

 

[Forever Lover]

cảm ơn các bạn đã giúp và giải thích, giờ mình đã hiểu rõ hơn rồi

BNTT, mình đang ở nhà, sáng nay vào công ty mình sẽ thử down file của bạn về xem sao , hy vọng là mình sẽ down được, càng nhiều cách làm khác nhau mình càng học tốt hơn

Phen này chắc phải đi mò các sách dạy về hàm excel học thêm cho bớt.....mù chữ quá (xấu hổ)

cảm ơn

P/S: mình vừa thử mở bài BNTT down về được đó BNTT à

 

[Forever Lover]

BNTT ƠI

Mình đã thử bài của bạn giúp, có mấy chỗ này nhờ bạn xem lại

1/ STT 4: NGUYEN VAN D : 20 Điểm, nhưng có 1 điểm trừ, nó vẫn ra kết quả thưởng 100% (không trừ, có lẽ do có số điểm =20), nhưng như vậy là chưa tínht tới anh này bị 1 điểm trừ ???

2/ Stt 8: NGUYEN VAN H: Tổng điểm là 19.5, có số điểm trừ là 0,5, theo nội quy chỉ nhắc nhở, không trừ tiền thưởng, nhưng kết quả lại ra 90% thưởng thôi

3/ STT 9: 20 điểm đúng, ko có điểm trừ, nhưng kết quả lại thưởng có 600,000 đ

Nhờ bạn xem lại giúp xem sai chỗ nào nhé, có phải chưa có công thức cho trường hợp đúng 20 điểm và trường hợp điểm trừ 0,5 thì không bị trừ thưởng, chỉ nhắc nhở không ?

cảm ơn bạn

 

[BNTT]

BNTT ƠI

Mình đã thử bài của bạn giúp, có mấy chỗ này nhờ bạn xem lại

1/ STT 4: NGUYEN VAN D : 20 Điểm, nhưng có 1 điểm trừ, nó vẫn ra kết quả thưởng 100% (không trừ, có lẽ do có số điểm =20), nhưng như vậy là chưa tínht tới anh này bị 1 điểm trừ ???

2/ Stt 8: NGUYEN VAN H: Tổng điểm là 19.5, có số điểm trừ là 0,5, theo nội quy chỉ nhắc nhở, không trừ tiền thưởng, nhưng kết quả lại ra 90% thưởng thôi

3/ STT 9: 20 điểm đúng, ko có điểm trừ, nhưng kết quả lại thưởng có 600,000 đ

Nhờ bạn xem lại giúp xem sai chỗ nào nhé, có phải chưa có công thức cho trường hợp đúng 20 điểm và trường hợp điểm trừ 0,5 thì không bị trừ thưởng, chỉ nhắc nhở không ?

cảm ơn bạn

1/ OK. Tôi đọc nhầm, phải lớn hơn 20 chứ không phải là lớn hơn hoặc bằng 20.

2/ OK. Tôi đọc nhầm nốt, quên mất bạn đã nói chỉ trừ khi điểm trừ bằng 1.

3/ Cũng OK. Giống câu 1. Phải lớn hơn 20 mới được thưởng.

Phương án sửa:

1. Sửa lại bảng điểm trừ. Thêm một cột nữa, cho giống như hình sau đây:

2. Sửa lại công thức ở cột L:

(L5) = HLOOKUP(C5,THUONG,2,0) * IF(AND(I5>20,J5=0),120%, IF(AND(I5>20,J5>0),100%, HLOOKUP(J5,DIEMTRU,2)))​

Gửi lại file đã sửa:

 

[Forever Lover]

cảm ơn bạn BNTT nhiều nhé . Mọi người ở đây nhiệt tình giúp đỡ quá, mình là thành viên mới vào đã cảm thấy rất thích gắn bó với diễn đàn này

Nếu mình còn thắc mắc gì xin được hỏi thêm sau nhé

Cảm ơn tất cả.

 

[Forever Lover]

Xin vui lòng cho mình hỏi thêm, bây giờ trong tình huống mới, ngoài 2 cấp độ 1 là Manager, 0 là nhân viên như bảng cũ trước đây, giờ phát sinh ra thêm 1 cấp độ là 2: Shift leader: mức thưởng sẻ cao hơn nhân viên và thấp hơn cấp quản lý Manager

Vậy mình nên sửa công thức trong file đính kèm như thế nào ? Xin xem giúp mình

Xin giải thích giúp mình là định nghĩa 2 vùng THƯỞNG và ĐIỂM TRỪ như thế nào? Trong công thức mình có thấy THUONG va DIEMTRU nhưng mình không tìm thấy định nghĩa cell nào tới cell nào là THƯỞNG, cell nào tới Cell nào là ĐIỂM TRỪ để trong trường hợp cần thay đổi mình có thể tự thay đổi.

=HLOOKUP(C8,THUONG,2,0)*IF(AND(I8>20,J8=0),150%,IF(AND(I8>20,J8>0),100%,HLOOKUP(J8,DIEMTRU,2)))


Cảm ơn nhiều và mong được hướng dẫn

 

[sealand]

THUONG, DIEMTRU là tên vùng, bạn nhấn mũi tên trong ô bên trái thanh Công thức chọn tên nào thì nó sẽ hiện nên cho bạn (Hoặc bạn view nhỏ hơn 40% cũng được). Để sửa được công thức tham chiếu đến tên vùng thì bạn phải sửa lại tên vùng. Bạn chọn Insert-->Name-->define chọn tên THUONG sửa lại Refer to ở dưới (Mở rộng thêm cột Shift Leader)

 

[Forever Lover]

Cảm ơn Sealand, mình đã thấy rồi và đã điều chỉnh được theo ý muốn

Cảm ơn nhiều