Bài tập xét thành tích học sinh

[chickencake1]

- Em có 1 bài tập exel đại khái như vầy:
1+ học sinh có tất cả các môn >=5 " đạt"
2+học sinh có 1 mộn chuyên <5 hay có trên 1 môn <5 thi 2" hỏng"
3+học sinh có 1 môn <5 " thi lại"........
......nói chung em viết cũng gần xong nhưng đến cái thứ 2 ( phần.... 2 môn < 5 "hỏng" ) nếu dùng if thì thật dài dòng..Mong các pro chỉ dẫn ....xin cám ơn

---đây là file bài tập :

 

[hoangminhtien]

Tại O5 bạn nhập công thức sau

O5=IF(MIN(D5:M5)>=5,"Đạt",IF(OR(SMALL(D5:M5,2)<5,OFFSET(C5,,MATCH(C5,$D$4:$M$4,0))<5),"Hỏng","Thi lại"))

 

[solomon2211]

Ô O5 bạn nhập = IF(COUNTIF(D5:M5,"<5")=0,"Đạt",IF(AND(COUNTIF(D5:M5,"<5")=1,SUMIF($D$4:$M$4,$C5,$D5:$M5)>5),"Thi lại","Hỏng"))

 

[BNTT]

Vài công thức đề nghị với bạn:

Điểm trung bình

[N5]: =AVERAGE(OFFSET(C5,, MATCH(C5, $D$4:$M$4, 0)), D5:M5)​

Ghi chú (công thức của HoangMinhTien):

[O5]: =IF(MIN(B5:K5)>=5, "Đạt", IF(OR(SMALL(B5:K5, 2)< 5, OFFSET($C$5,, MATCH($C$5, $D$4:$M$4, 0))<5), "Hỏng", "Thi lại"))
​

Môn thi lại:

[P5]: =IF(O5="Thi lại", OFFSET($D$4,, MATCH(MIN(D5:M5), D5:M5, 0)-1), "")​

Xếp loại:

[Q5]: =IF(O5="Đạt", IF(N5<7, "TB", IF(N5<9, "Khá", "Giỏi")), "")​

Học bổng:

[R5]: =IF(Q5="Giỏi", 100000, IF(Q5="Khá", 50000, 0))​

 

[chickencake1]

-Rất cám ơn các bạn.....
-Nhưng xin lỗi bạn BNTT hàm :IF(OR(SMALL(B5:K5, 2)< 5, OFFSET($C$5,, MATCH($C$5, $D$4:$M$4, 0))<5)... Mình hoàn toàn mù tịt về hàm này, Bạn vui lòng nói rõ chức năng của hàm ( Small và offset) này dùm mình.( cám ơn bạn)

 

[chickencake1]

Ờ mình cũng mún hỏi bạn Solomon về chỗ hàm sumif ....Bạn nói rõ về nó xíu nha ( cám ơn)

àh mình hiểu cái sùmi rồi

 

[solomon2211]

Ờ mình cũng mún hỏi bạn Solomon về chỗ hàm sumif ....Bạn nói rõ về nó xíu nha ( cám ơn)

= IF(COUNTIF(D5:M5,"<5")=0,"Đạt",IF(AND(COUNTIF(D 5:M5,"<5")=1,SUMIF($D$4:$M$4,$C5,$D5:$M5)>5),"Thi lại","Hỏng"))

• COUNTIF(D5:M5,"<5") Đếm số môn mà điểm số nhỏ hơn 5. Bằng 0 nghĩa là không có điểm nào dưới 5
• SUMIF($D$4:$M$4,$C5,$D5:$M5) Tính tổng số điểm mà Tên Môn học bằng với Môn chuyên (dĩ nhiên 1 môn chuyên, nên công thức này cho ra số điểm của môn chuyên)

 

[BNTT]

-Rất cám ơn các bạn.....
-Nhưng xin lỗi bạn BNTT hàm :IF(OR(SMALL(B5:K5, 2)< 5, OFFSET($C$5,, MATCH($C$5, $D$4:$M$4, 0))<5)... Mình hoàn toàn mù tịt về hàm này, Bạn vui lòng nói rõ chức năng của hàm ( Small và offset) này dùm mình.( cám ơn bạn)

Bạn xem ở đây: Hàm SMALL, Hàm OFFSET

SMALL(B5:K5, 2)<5:

Tìm số nhỏ thứ hai trong dãy B5:K5 (dãy ô chứa điểm), xem nó có nhỏ hơn 5 không. Nếu như con số nhỏ thứ hai này mà nhỏ hơn 5, có nghĩa là có 2 con số nhỏ hơn 5, hay nói cách khác, có 2 môn thi có điểm nhỏ hơn 5 --> "Hỏng"
​

OFFSET($C$5,, MATCH($C$5, $D$4:$M$4, 0))<5 (hay là: OFFSET($C$5, 0, MATCH($C$5, $D$4:$M$4, 0))<5)

Đứng từ ô C5 (chứa tên môn chuyên), dời ngang sang (lẽ ra có con số 0 ở giữa 2 dấu phẩy trong công thức, nhưng không cần thiết, con số 0 này có nghĩa là dời xuống 0 hàng), ngang sang mấy ô, thì do hàm MATCH tìm ra. Hàm MATCH lấy giá trị trong ô C5 đi dò với dãy D4:M4, là dãy chứa tên các môn học, và báo cho biết môn học giống như ở ô C5 đang nằm ở ô thứ mấy. Ví dụ môn Toán nằm ở ô thứ 2 (trong dãy D4:M4) thì OFFSET sẽ dời ngang sang 2 ô. Và nó xét xem cái điểm đang nằm ở ô này có nhỏ hơn 5 không, nếu có thì xếp loại Hỏng (vì theo điều kiện, học môn chuyên nào mà điểm thi môn đó < 5 thì xếp loại Hỏng).​

P/S: Bí hàm nào, bạn cứ tìm trong mục Tra cứu Hàm Excel ở dưới chữ ký của tôi. Có đủ hết, không thiếu hàm nào cả.

 

[chickencake1]

ờ Bạn BTNT ơi , giải thích dùm mình cái hàm ở môn thi lại dc ko?
----offset mình đã đọc rùi nhưng mình ko hiểu ..., ( mình xài exel 2003 nha bạn)

 

[ntthanh87]

anh chị giúp minh làm phần còn lại vơi!
"học bổng"
"?"

 

[khoavu87]

anh chị giúp minh làm phần còn lại vơi!
"học bổng"
"?"

Tại ô N4 bạn đặt công thức đơn giản này

N4 =IF(AND(M4>=9,J4="Đạt"),245000,IF(AND(M4>=8,J4="Đạt"),200000,IF(AND(M4>=7,J4="Đạt"),125000,0)))

sau đó bạn fill xuống các ô còn lại

 

[diemquynhnhomai]

Nếu như đó là 1 lớp không chuyên thì công thức ở tất cả các cột sẽ thay đổi như thế nào?

 

[Ba Tê]

anh chị giúp minh làm phần còn lại vơi!
"học bổng"
"?"

Làm đại bằng các công thức Excel không được gọn lắm, các ô tô màu xanh:

 

[diemquynhnhomai]

Có thể cho hiển thị tất cả tên các môn học dưới 5 điểm không?

 

[hoangcuong_0525]

P5==IF(O5="thi lại";CONCATENATE(IF(D5<5;"Toán";IF(E5<5;"Lý";IF(F5<5;"Hóa";IF(G5<5;"Văn";IF(H5<5;"Sử";IF(I5<5;"Địa";""))))));IF(J5<5;"Anh";IF(K5<5;"Pháp";IF(L5<5;"Trung";IF(M5<5;"Sinh";"")))));"")
O5==IF(COUNTIF(D5:M5;">=5")=COUNT(D5:M5);"Đạt";IF(OR(COUNTIF(D5:M5;"<5")>=2;VLOOKUP(C5;$C$4:$M$17;MATCH(C5;$C$4:$M$4;0);0)<5);"Hỏng";IF(COUNTIF(D5:M5;"<5")=1;"Thi lại";"")))