Định dạng có điều kiện

[chohom]

Chào anh chị nhờ anh chị giúp định dạng có điều kiện. Trong cột K2:K1000 là ngày tháng của nhiều năm nhưng không liên tục mà bất kỳ. Em cần tô mầu các ngày là thứ Sáu đầu tiên của một tháng nào đó. Ví dụ tô mầu ngày 2/1/2015 và 4/11/2016 vì là ngày thứ Sáu đầu tiên trong tháng.

 

[befaint]

Công thức trong CF:

=$K2=CEILING(EOMONTH($K2,-1)-5,7)+6

Vùng áp dụng: =$K$2:$K$1000

 

[hoangminhtien]

Bạn cũng có thể dùng CF với công thức

=EOMONTH($K2,-1)-WEEKDAY($K2,1)+7

 

[chohom]

Bạn cũng có thể dùng CF với công thức

Hình như bạn hiểu sai ý thì phải

 

[hoangminhtien]

Hình như bạn hiểu sai ý thì phải

Có phải ý bạn là tô mầu thứ 6 đầu tiên của tháng không?

 

[chohom]

Có phải ý bạn là tô mầu thứ 6 đầu tiên của tháng không?

Tôi viết rõ bạn ơi.

Bạn ơi bạn có kiểm tra không, tôi đính kèm ảnh. Bạn nhìn ảnh sẽ thấy ngày 03/02/2016 và 06/03/2016 được tô mầu. Nhưng 03/02/2016 là thứ Tư còn 06/03/2016 là Chủ Nhật.
Nếu kiểm tra tiếp thì bạn thấy là trong tháng 5 không có ngày nào được tô mầu còn ngày 02/06/2016 được tô mầu thì lại là thứ Năm. Tôi không kiểm tra tiếp nữa.

Cám ơn bạn befaint nhé, công thức đơn giản

 

[hoangminhtien]

Mình nhầm, bạn có thể chỉnh lại công thức CF như sau

=$K2=EOMONTH($K2,-1)-WEEKDAY(EOMONTH($K2,-1),16)+7

 

[NguyenNgocThuHien]

Tớ nghĩ công thức chỉ đơn giản như thế này thôi: =AND(WEEKDAY(K2)=6,DAY(K2)<=10)

Chỉ tô màu vào ngày thứ 6, chắc chắn là ngày thứ sau đầu tiên của mỗi tháng sẽ nằm trong 10 ngày đầu tiên của mỗi tháng.

 

[doveandrose]

Tớ nghĩ công thức chỉ đơn giản như thế này thôi: =AND(WEEKDAY(K2)=6,DAY(K2)<=10)

Chỉ tô màu vào ngày thứ 6, chắc chắn là ngày thứ sau đầu tiên của mỗi tháng sẽ nằm trong 10 ngày đầu tiên của mỗi tháng.

ôi ôi , thần tượng của Doveandrose tìm kiếm lâu nay đây rồi
Bạn cho mình hỏi :
Nếu thứ sáu đầu tiên của tháng nhằm ngày 1 thì ngày mùng 8 gọi là gì bạn ?

 

[chohom]

Tớ nghĩ công thức chỉ đơn giản như thế này thôi: =AND(WEEKDAY(K2)=6,DAY(K2)<=10)

Chỉ tô màu vào ngày thứ 6, chắc chắn là ngày thứ sau đầu tiên của mỗi tháng sẽ nằm trong 10 ngày đầu tiên của mỗi tháng.

Cám ơn nhiều. Tôi sửa thành

=AND(WEEKDAY(K2)=6,DAY(K2)<=7)

vì trong 7 ngày đầu thì luôn có CN, 2, 3, 4, 5, 6, 7, mỗi ngày xuất hiện đúng một lần và cũng là lần đầu tiên
Và nếu muốn CN, thứ 2, 3, 4, 5, 6, 7 thì chỉnh 6 thành 1, 2, 3, 4, 5, 6, 7

 

[quocgiacan]

Công thức trong CF:

=$K2=CEILING(EOMONTH($K2,-1)-5,7)+6

Vùng áp dụng: =$K$2:$K$1000

Góp vui với em hàm workday.intl (excel>=2010)

=K2=WORKDAY.INTL(EOMONTH($K2,-1),1,"1111011")

Chúc em ngày vui.

 

[quocgiacan]

(gặp sự cố gửi hai lần, thông cảm!................)

 

[NguyenNgocThuHien]

Cám ơn nhiều. Tôi sửa thành

=AND(WEEKDAY(K2)=6,DAY(K2)<=7)
[/
vì trong 7 ngày đầu thì luôn có CN, 2, 3, 4, 5, 6, 7, mỗi ngày xuất hiện đúng một lần và cũng là lần đầu tiên
Và nếu muốn CN, thứ 2, 3, 4, 5, 6, 7 thì chỉnh 6 thành 1, 2, 3, 4, 5, 6, 7[/QUOTE]

thanks you. tối qua em viết vội. chưa nghĩ ký, sáng nay mở mắt ra là biết ko ổn.
ngày thứ sau đầu tiên chắc chắn nằm trơng 7ngày đầu tiên của tháng. theo ý tưởng trên thì có thể áp dụng cho ngày thứ 6 thứ 2 thứ 4 của tháng.

 

[chohom]

Mình nhầm, bạn có thể chỉnh lại công thức CF như sau

7/10/2016, 7/4/2017, 7/7/2017 và 7/9/2018 đều là những thứ Sáu đầu tiên nhưng công thức của bạn không trả về không cho là những thứ Sáu đầu tiên.
Không cần nữa đâu bạn ơi vì đã có những công thức ngắn gọn rồi.