Đổi Code Name bằng VBA ?

[Blad01]

Chào các anh chị trong diễn đàn. Em tham khảo đoạn code để thay đổi CodeName trong VBA nhưng có một hộp thông báo hiện lên và phải ấn Continue thì sub mới tiếp tục chạy. Xin hỏi có cách nào thay đổi CodeName mà không có thông báo như vậy không ?
Code:

Sub bieuTK1()
Sheets.Add after:=Sheets(Sheets.Count)
Sheets(Sheets.Count).Name = "B1"
ThisWorkbook.VBProject.VBComponents(ThisWorkbook.Worksheets(Sheets.Count).CodeName).Name = "TK1"
End Sub

 

[Blad01]

Anh , chị, thầy cô giúp em với được không ?

 

[ndu96081631]

Sao lại lỗi "Can't enter break mode at this time" được ta?

 

[Blad01]

Thầy ndu có cách nào giúp em ko ạ

 

[SA_DQ]

Bạn thử chạy macro này xem sẽ ra sao:

Sub bieuTK1()
 On Error GoTo LoiCT
 ThisWorkbook.Worksheets.Add after:=Sheets(Sheets.Count)
 Sheets(Sheets.Count).Name = "B1"
 ThisWorkbook.VBProject.VBComponents(ThisWorkbook.Worksheets(Sheets.Count).CodeName).Name = "TK1"
Err_:           Exit Sub
LoiCT:
 If Err = 1004 Then
    Resume Next
 Else
    MsgBox Error(), , Err
    Resume Err_
 End If
End Sub

 

[ndu96081631]

Anh , chị, thầy cô giúp em với được không ?

Thử sửa code thành vầy xem:

Sub bieuTK1()
  Dim wks As Worksheet, lCount As Long
  With ThisWorkbook
    Set wks = .Sheets.Add(after:=.Sheets(.Sheets.Count))
    wks.Name = "B1"
    lCount = .VBProject.VBComponents.Count   '<-- tưởng không có tác dụng nhưng phải có
    .VBProject.VBComponents(wks.CodeName).Name = "TK1"
  End With
End Sub

Nói chung vừa add sheet vừa đổi sheet code name thì phải vậy, riêng thông báo lỗi của bạn thì tôi không biết đâu
--------------------------------------------
Nói thêm:
1> Để code trên có thể chạy thì phải thêm yêu cầu nữa, đó là phải vào Excel Options --> Trust Center --> Trust Center Settings... --> Macro Settings và check vào mục "Trust access to the VBA project object model"
2> Code này chỉ chạy được một lần, lần thứ hai sẽ bị lỗi do tên sheet đã tồn tại. Bạn lưu ý nhé