Tính tổng 10 số cuối cùng trong dãy (1 người xem)

[bebo021999]

Mình đang bí cái này, ACE nào biết giúp giùm (bằng công thức nhé)
Đếm ngược từ dưới lên đủ 10 số thì tính tổng

 

[QuocPhong]

Bạn dùng thử công thức mảng sau:

=SUM(LARGE(A:A,ROW(1:10)))

 

[vu_tuan_manh_linh]

Mình đang bí cái này, ACE nào biết giúp giùm (bằng công thức nhé)
Đếm ngược từ dưới lên đủ 10 số thì tính tổng

Làm thế này là dễ nhất!

 

[bebo021999]

Làm thế này là dễ nhất!

Mình đang cần 1 công thức đặt ở bất kỳ ô nào , VD tại ô B18, tính ra kết quả luôn, chứ không dùng cột phụ B.

Bạn dùng thử công thức mảng sau:

=SUM(LARGE(A:A,ROW(1:10)))

Công thức này là tính tổng 10 số lớn nhất rồi, không phải như yêu cầu mình cần. Bạn có cách nào khác không?

 

[kimloan96.414]

Bạn dùng thử công thức mảng sau:

=SUM(LARGE(A:A,ROW(1:10)))

Dạ công thức này dùng để tính tổng 10 số lớn nhất trong mảng mà!

 

[bebo021999]

Dạ công thức này dùng để tính tổng 10 số lớn nhất trong mảng mà!

Mình cần đếm ngược cột từ dưới lên, đủ 10 số thì cộng. Cột có thể có ô trống

 

[QuocPhong]

Mình cần đếm ngược cột từ dưới lên, đủ 10 số thì cộng. Cột có thể có ô trống

Bạn thử công thức sau:

=SUM(A1000:INDEX(A:A,LARGE(IF(A1:A1000<>"",ROW(A1:A1000)),10)))

{Ctrl-Shift-Enter}

 

[kimloan96.414]

Mình cần đếm ngược cột từ dưới lên, đủ 10 số thì cộng. Cột có thể có ô trống

Dạ chị thử cái này đúng không?
{=SUM(IF(ROW($A$1:$A$17)>ROW($A$17)-10,$A$1:$A$17,0))}

 

[VMH0307]

Bạn đặt các Name sau cho tiện dùng:

Data=Sheet1!$A$1:$A$1000

Ma=(ROW(Data)/ROW(Data)*TRANSPOSE(ROW(Data))<=ROW(Data))*1

Tại ô cần cho kết quả bạn sử dụng công thức sau:

=SUMPRODUCT((MMULT(Ma,ISNUMBER(Data)*1)>(COUNT(Data)-10))*1,Data)

Bạn xem trong file đính kèm

 

[Ba Tê]

Mình cần đếm ngược cột từ dưới lên, đủ 10 số thì cộng. Cột có thể có ô trống

Đủ 10 số có kể số 0 hông?
Nếu số 0 cũng hổng kể thì thử công thức "vỏ sầu riêng" này xem, Cột A có số liệu đến dòng 20

=SUM(INDIRECT("A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");10) &":A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");1)))

Công thức mảng. Nếu tính luôn số 0 thì thay >0 thành <>""

 

[kimloan96.414]

Đủ 10 số có kể số 0 hông?
Nếu số 0 cũng hổng kể thì thử công thức "vỏ sầu riêng" này xem, Cột A có số liệu đến dòng 20

=SUM(INDIRECT("A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");10) &":A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");1)))

Công thức mảng. Nếu tính luôn số 0 thì thay >0 thành <>""

Dạ thưa thầy ! Thầy cho em hỏi ở bài #8 của topic này em làm có đúng không ? Em cảm ơn!

 

[hoangminhtien]

Đủ 10 số có kể số 0 hông?
Nếu số 0 cũng hổng kể thì thử công thức "vỏ sầu riêng" này xem, Cột A có số liệu đến dòng 20

=SUM(INDIRECT("A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");10) &":A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");1)))

Công thức mảng. Nếu tính luôn số 0 thì thay >0 thành <>""

Công thức của bác có thể rút gọn hơn 1 chút

=SUM(INDIRECT("A"&LARGE(IF(A1:A20>0,ROW(A1:A20),""),10)&":A"&ROWS(A1:A20)))

 

[ndu96081631]

Dạ thưa thầy ! Thầy cho em hỏi ở bài #8 của topic này em làm có đúng không ? Em cảm ơn!

Đương nhiên là sai rồi
10 số đếm ngược từ dưới lên chứ không phải 10 dòng từ dưới lên
Tức cell nào rổng sẽ không tính
Theo như trong file thì 10 số cuối cùng sẽ kết thúc ở số 2 (tại cell A17) và bắt đầu từ số 6 (tại cell A4) ---> Kết quả đúng cho phép SUM này là = 33

 

[Ba Tê]

Công thức của bác có thể rút gọn hơn 1 chút

Hi hi... Lo copy cái trước ra phía sau.
Nhìn lại công thức này thì chỉ cần vầy cũng đủ.

=SUM(INDIRECT("A" & LARGE(IF(A1:A20>0;ROW(A1:A20);"");10) &":A20"))

Híc!

 

[dhn46]

Anh dùng công thức này:

=SUM(OFFSET(A20,,,-20+LARGE(ISNUMBER(A1:A20)*ROW(A1:A20),11)))

 

[bebo021999]

Cảm ơn các ACE đã nhiệt tình đóng góp. Sáng giờ bận quá chưa thử được, sẽ kiểm tra lại nhé.

 

[bebo021999]

Kết quả đúng rồi. Cám ơn các bạn nhé. Phương pháp dùng LARGE để lấy số dòng rất hay. Cách dùng MMUL tuy dài nhưng cũng hỏi thêm nhiều điều mới.