Xin hỏi về cách cộng 1 dãy số theo công thức pascal

[tra777]

em có ô A1 chứa dãy số 12345 và muốn cộng pascal theo kiểu từng cặp:
1+2 =3;
2+3=5,
3+4=7,
4+5=9
Ô A2 sẽ ra kết quả 3579. mong mọi người giúp đỡ. cảm ơn

 

[phihndhsp]

em có ô A1 chứa dãy số 12345 và muốn cộng pascal theo kiểu từng cặp:

Sory nhầm tưởng dãy Fibonacci
Nếu dãy số như trên thì ta có thể làm theo ý tưởng này
chuoi = chuoi & 2 * i + 1 ( với i là số chạy từ 1 đến 4)

 

[ndu96081631]

em có ô A1 chứa dãy số 12345 và muốn cộng pascal theo kiểu từng cặp:
1+2 =3;
2+3=5,
3+4=7,
4+5=9
Ô A2 sẽ ra kết quả 3579. mong mọi người giúp đỡ. cảm ơn

Nếu dãy số là 56789 thì bạn muốn kết quả sẽ là gì?

 

[Phuocam]

em có ô A1 chứa dãy số 12345
Ô A2 sẽ ra kết quả 3579. mong mọi người giúp đỡ. cảm ơn

Trường hợp A1 có 56789, A2 kết quả như thế nào?
...
Haha, chậm rồi!

 

[huuthang_bd]

Nhìn đơn giản vậy thôi chứ phải mấy chục bài mới giải quyết được vấn đề

 

[tra777]

Trường hợp A1 có 56789, A2 kết quả như thế nào?
...
Haha, chậm rồi!

A2 sẽ có kết quả là : 1357

Bài đã được tự động gộp: 30/7/18

mong mọi người giúp đỡ ạ

Bài đã được tự động gộp: 30/7/18

Sory nhầm tưởng dãy Fibonacci
Nếu dãy số như trên thì ta có thể làm theo ý tưởng này
chuoi = chuoi & 2 * i + 1 ( với i là số chạy từ 1 đến 4)

em làm theo công thức trên nhưng khôg ra kết quả a ơi

 

[Phuocam]

Thử:

=SUMPRODUCT(MOD(MID(A1,ROW(INDIRECT("1:"&LEN(A1)-1)),1)
+MID(A1,ROW(INDIRECT("2:"&LEN(A1))),1),10)*10^(LEN(A1)-1-ROW(INDIRECT("1:"&LEN(A1)-1))))

 

[huuthang_bd]

Lỡ làm rồi thì đăng lên luôn.

=SUMPRODUCT(MOD(MMULT(--MID(A1,({1,2}+LEN(A1)-ROW(INDIRECT("2:"&LEN(A1)))),1),{1;1}),10)*10^(ROW(INDIRECT("2:"&LEN(A1)))-2))

 

[tra777]

Lỡ làm rồi thì đăng lên luôn.

=SUMPRODUCT(MOD(MMULT(--MID(A1,({1,2}+LEN(A1)-ROW(INDIRECT("2:"&LEN(A1)))),1),{1;1}),10)*10^(ROW(INDIRECT("2:"&LEN(A1)))-2))

haha, chuẩn luôn, quá hay, cảm ơn anh nha, à anh có thể cho em hỏi thêm 1 xíu về hàm này được không ạ, em đọc nhưng không hiểu nó cho lắm, anh có thể giải thíc cách hàm này làm việc được không ạ, cảm ơn anh nhiều

 

[huuthang_bd]

haha, chuẩn luôn, quá hay, cảm ơn anh nha, à anh có thể cho em hỏi thêm 1 xíu về hàm này được không ạ, em đọc nhưng không hiểu nó cho lắm, anh có thể giải thíc cách hàm này làm việc được không ạ, cảm ơn anh nhiều

Chuẩn chắc phải vầy:

=TEXT(SUMPRODUCT(MOD(MMULT(--MID(A1,({1,2}+LEN(A1)-ROW(INDIRECT("2:"&LEN(A1)))),1),{1;1}),10)*10^(ROW(INDIRECT("2:"&LEN(A1)))-2)),REPT(0,LEN(A1)-1))

MMULT(...): Tạo một 1 mảng n-1 phần tử với phần tử i là tổng chữ số thứ n-i và thứ n-i+1 (n là chiều dài chuỗi ban đầu)
MOD(...): Chỉ lấy số đơn vị
...*10^(...): Chuyển dãy 1, 2, 3, 4 thành 1000, 200, 30, 4
SUMPRODUCT(...): Cộng dãy 1000, 200, 30, 4 được 1234
TEXT(...): Định dạng kết quả với số chữ số là n-1 để đề phòng kết quả bắt đầu bằng số 0.

Chỉ giải thích được vậy, muốn chi tiết hơn thì tôi chịu

 

[tra777]

Chuẩn chắc phải vầy:

=TEXT(SUMPRODUCT(MOD(MMULT(--MID(A1,({1,2}+LEN(A1)-ROW(INDIRECT("2:"&LEN(A1)))),1),{1;1}),10)*10^(ROW(INDIRECT("2:"&LEN(A1)))-2)),REPT(0,LEN(A1)-1))

MMULT(...): Tạo một 1 mảng n-1 phần tử với phần tử i là tổng chữ số thứ n-i và thứ n-i+1 (n là chiều dài chuỗi ban đầu)
MOD(...): Chỉ lấy số đơn vị
...*10^(...): Chuyển dãy 1, 2, 3, 4 thành 1000, 200, 30, 4
SUMPRODUCT(...): Cộng dãy 1000, 200, 30, 4 được 1234
TEXT(...): Định dạng kết quả với số chữ số là n-1 để đề phòng kết quả bắt đầu bằng số 0.

Chỉ giải thích được vậy, muốn chi tiết hơn thì tôi chịu

e cũng vừa định hỏi cách để số 0 nếu xuất hiện ở đầu vẫn còn chứ

Bài đã được tự động gộp: 30/7/18

TEXT(...): Định dạng kết quả với số chữ số là n-1 để đề phòng kết quả bắt đầu bằng số 0.

text vào thì hàm bị lỗi anh ơi, giúp e với

Bài đã được tự động gộp: 30/7/18

e cũng vừa định hỏi cách để số 0 nếu xuất hiện ở đầu vẫn còn chứ

Bài đã được tự động gộp: 30/7/18

TEXT(...): Định dạng kết quả với số chữ số là n-1 để đề phòng kết quả bắt đầu bằng số 0.

text vào thì hàm bị lỗi anh ơi, giúp e với

à, e đã sửa đc rồi ạ, chân thành cảm ơn a rất nhiều