Tham chiều với nhiều điều kiện áp dụng trong công ty may mặc

[syberia2_tb]

Tham chiều với nhiều điều kiện áp dụng khác nhau

Em đang phải đánh giá lại nguyên vật liệu đang sử dụng đối với sản phẩm dở dang trong công ty may mặc. Mỗi sản phẩm hoàn thiện đều có bảng định mức, tuy nhiên phần mã sản phẩm dở dang trên dây chuyền có thể nằm ở 1 trong 3 khâu: khâu cắt, may, đóng gói và mỗi khâu đó sẽ sử dụng lượng nguyên vật liệu khác nhau, ví dụ khâu cắt thì sử dụng: vải , nhãn. Khâu may thì sử dụng thêm vật liệu khác như: dây viền, móc khóa, khoen, chỉ. Tại khâu đóng gói thì có thêm thùng carton và túi ni long (đã bao gồm VNL từ khâu trước chuyển sang). Điều này có nghĩa là tại khâu đóng gói là sẽ sử dụng toàn bộ VNL vào sản phẩm
Em muốn tham chiếu. Em gửi phẩn bảng định mức và sản phẩm dở dang để mọi người giúp em xem cách làm thế nào , em chân thành cảm ơn.

 

[quocgiacan]

Em đang phải đánh giá lại nguyên vật liệu đang sử dụng đối với sản phẩm dở dang trong công ty may mặc. Mỗi sản phẩm hoàn thiện đều có bảng định mức, tuy nhiên phần mã sản phẩm dở dang trên dây chuyền có thể nằm ở 1 trong 3 khâu: khâu cắt, may, đóng gói và mỗi khâu đó sẽ sử dụng lượng nguyên vật liệu khác nhau, ví dụ khâu cắt thì sử dụng: vải , nhãn. Khâu may thì sử dụng thêm vật liệu khác như: dây viền, móc khóa, khoen, chỉ. Tại khâu đóng gói thì có thêm thùng carton và túi ni long (đã bao gồm VNL từ khâu trước chuyển sang). Điều này có nghĩa là tại khâu đóng gói là sẽ sử dụng toàn bộ VNL vào sản phẩm
Em muốn tham chiếu. Em gửi phẩn bảng định mức và sản phẩm dở dang để mọi người giúp em xem cách làm thế nào , em chân thành cảm ơn.

Chào syberia2_tb,

Bạn tạo thêm từ G3 đến P3 các mã NVL sau:
[TABLE="width: 682"]
[TR]
[TD="class: xl72, width: 74"]SW04,[/TD]
[TD="class: xl72, width: 67"]SW14,[/TD]
[TD="class: xl72, width: 56"]SW16,[/TD]
[TD="class: xl72, width: 74"]SW18,[/TD]
[TD="class: xl72, width: 74"]SW19,[/TD]
[TD="class: xl72, width: 61"]SW21,[/TD]
[TD="class: xl72, width: 61"]SW22,[/TD]
[TD="class: xl72, width: 67"]SW222,[/TD]
[TD="class: xl72, width: 74"]SW233,[/TD]
[TD="class: xl72, width: 74"]SW25[/TD]
[/TR]
[/TABLE]

ô G2 dùng công thức:

=INDEX('bang dinh muc va khau su dung'!$F$2:$F$1000,MATCH(G$3,'bang dinh muc va khau su dung'!$C$2:$C$1000),1)

ô G4 dùng công thức: (sau khi nhập xong, nhấn Ctrl+Shift+Enter, rồi copy sang các ô kế tiếp và xuống dưới)

=SUMIFS('bang dinh muc va khau su dung'!$E$2:$E$1000,'bang dinh muc va khau su dung'!$F$2:$F$1000,INDEX({"Cắt","<>Đóng gói","*"},1,MAX(IF($C4:$E4>0,COLUMN($C4:$E4)-2))),'bang dinh muc va khau su dung'!$A$2:$A$1000,$A4,'bang dinh muc va khau su dung'!$C$2:$C$1000,G$3)*SUM(OFFSET($C4,,MATCH(G$2,{"Cắt","May","Đóng gói"},0)-1,,MAX((G$2=({"Cắt","May","Đóng gói"}))*{3,2,1})))

Chúc bạn cuối tuần vui

PS: bạn có thể load về file tôi đã chỉnh theo link sau: https://drive.google.com/file/d/0B4LHoUy1L9LGdmJFRTNpckhSdEE/view?usp=sharing

 

[chuson071094]

Mình không hiểu phần này lắm

 

[quocgiacan]

Mình không hiểu phần này lắm

Chào chuson071094,

Bạn có thể nói rõ hơn, bạn không hiểu về phần nào, như:
1. Về đề bài?
2. Về công thức?
3. Hay cách thiết lập bảng, để tạo kết quả?

Có như vậy thì GPE mới giúp được bạn.

Chúc bạn ngày vui.

 

[syberia2_tb]

trong sheet 1 là cái bảng thể hiện mã sản phẩm còn đang dở dang trên dây chuyền. mục đích là mình phải tính được số nguyên vật liệu đang sử dụng trên từng khâu đó: cắt, may, đóng gói. Để tính được thì mình phải dựa vào bảng định mức tiêu hao VNl cho từng mã sản phẩm, cái này thì chỉ bằng số lượng x định mức là ra. Điều cần chú ý ở đây là mỗi khâu dở dang đều sẽ sử dụng lượng VNL khác nhau, ví dụ như ở khâu cắt sử dụng vải, nhãn chính, nhãn phụ...thì ở khâu may sẽ sử dụng thêm lượng VNL khác, điều cần chú ý là nếu ở khâu cắt rồi thì vải, nhãn chính, nhãn phụ cũng sẽ được chuyển sang khâu này, nghĩa là đã sử dụng. Ở khâu đóng gói thì cũng thế (khâu này sử dụng thêm túi nilong và thùng carton thôi) phần NVL ở các khâu kia cũng đã được chuyển sang. có nghĩa là bỏ vào từ đầu 1 lần duy nhất. Phần NVL muốn tính thì tính ở sheet "bang dinh muc va khau su dung"
Em đã kiểm tra lại phần bác "quocgiacan" trả lời và kiểm tra lại thấy như thế là đúng rồi, mỗi tội hàm em đọc hơi khó hiểu quả, chắc phải mất công mầy mò

 

[quocgiacan]

......
Em đã kiểm tra lại phần bác "quocgiacan" trả lời và kiểm tra lại thấy như thế là đúng rồi, mỗi tội hàm em đọc hơi khó hiểu quả, chắc phải mất công mầy mò

Chào syberia2_tb,

Để tiện cho bạn tham khảo và tự tin khi thức hiện công thức vào công việc của mình, xin giải thích sơ như sau:

=SUMIFS('bang dinh muc va khau su dung'!$E$2:$E$1000,'bang dinh muc va khau su dung'!$F$2:$F$1000,INDEX({"Cắt","<>Đóng gói","*"},1,MAX(IF($C4:$E4>0,COLUMN($C4:$E4)-2))),'bang dinh muc va khau su dung'!$A$2:$A$1000,$A4,'bang dinh muc va khau su dung'!$C$2:$C$1000,G$3)

Câu này yêu cầu Excel truy dùm bạn theo: mã sản phẩm, đồng thời theo mã NVL mà các NVL này chỉ được thể hiện nếu thỏa điều kiện nằm tại khâu kiểm kê nào, ví dụ: nếu số lượng tại khâu May>0, tức là chỉ các mã NVL : Cắt và May bên bảng định mức mới được đem qua sử dụng tính toán(tiêu chí so: "<>Đóng gói"), giả sử thêm nếu kiểm kê khâu đóng gói có SL>0 thì toàn bộ vật tư tương thích mã sản phẩm sẽ được đem qua tính toán (tiêu chí so: "*").

Do nó có sử dụng công thức mảng nên phải nhấn Ctrl+Shift+Enter.

=SUM(OFFSET($C4,,MATCH(G$2,{"Cắt","May","Đóng gói"},0)-1,,MAX((G$2=({"Cắt","May","Đóng gói"}))*{3,2,1})))

Câu này yêu cầu tính toán số lượng NVL tại các khâu, ví dụ: kiểm kê tại khâu cắt và may đều có số tồn, vậy: các NVL tại khâu cắt sẽ bằng tổng hai khâu: cắt + may, riêng NVL khâu may thì bằng đúng số kiểm kê. Tôi có làm tại ô R1 để kiểm tra việc này, bạn có thể xem thêm.

Chúc bạn ngày vui.