thử làm bảng tính cho cửa hàng game

[hoailinh_191]

Mình có thằng bạn mở của hàng games nó thu 9000/h. và nhờ mình làm bảng excel tính tiền giúp. mình kém excel nên không làm marco được mình làm đại khái thế này mọi người xem và tư vấn thêm cho dễ quản lý.
Minh chỉ mới làm ra vào giờ ra tổng thời gian chơi quy ra phút rồi * 150đ (9000/60=150đ/phút) rồi làm tròn số tiền để để trả và tính tồn cuối ngày. mọi người tư vấn thêm làm sao cho khoa học nhé. có 4 máy tất cả.

 

[phuong1604]

Có 4 máy bạn làm thế là khoa học rồi ! Chẳng phải dòng cuối bạn đã để là "đúng rồi" rồi sao ? Có điều 9k/h hơi đắt thì phải ? Gần nhà tui có 5k/h thui !!!

 

[BNTT]

Mình có thằng bạn mở của hàng games nó thu 9000/h. và nhờ mình làm bảng excel tính tiền giúp. mình kém excel nên không làm marco được mình làm đại khái thế này mọi người xem và tư vấn thêm cho dễ quản lý.
Minh chỉ mới làm ra vào giờ ra tổng thời gian chơi quy ra phút rồi * 150đ (9000/60=150đ/phút) rồi làm tròn số tiền để để trả và tính tồn cuối ngày. mọi người tư vấn thêm làm sao cho khoa học nhé. có 4 máy tất cả.

Xin có một vài góp ý:

Trước hết là chuyện "Kinh doanh":

• Nên có số tiền tối thiểu, giống như mỗi khi lên taxi, là phải trả 10.000, bất kể anh đi xa hay gần, nếu xa thì tính thêm, còn nếu quá gần thì cũng phải mất 10.000. Kinh doanh dịch vụ Internet cũng vậy, anh đã ngồi vào máy là anh phải mất một số tiền tối thiểu nào đó...
  
  
• Đã kinh doanh, là không có chuyện "bớt". Ở đây tôi nói đến việc làm tròn của bạn. Nên "làm tròn lên" mà thôi. Ví dụ, chưa đến 500 đồng thì làm tròn đến 500 đồng, còn hơn 500 đến dưới 1000 thì làm tròn đến 1000. Tôi đã thử làm theo kiểu này vào bảng tính của bạn, kết quả, tôi kiếm thêm được 5.000 đồng! Cũng được ly cafe đá ngồi trông máy chứ!

Bây giờ là góp ý cho các công thức: (tôi làm ví dụ cho hàng số 5, sau khi thấy được, và sửa lại, bạn copy xuống các hàng dưới nghe)

• Tính tổng thời gian (E5):
  
  Công thức của bạn: =IF(D5<C5, (D5+12)-C5, D5-C5)
  
  Có thể sửa lại là: =(D5<C5)+D5-C5
  
  Giải thích: (D5<C5) là một biểu thức, nếu sai, thì nó = 0, nếu đúng, thì nó = 1. Con số 1 ở đây có thể hiểu là 1 ngày, là 24 tiếng.
  
  Ví dụ, có một máy chạy từ 9 giờ tối (=21 giờ) đến 2 giờ sáng. Khi đó, 2<21 là đúng, biểu thức (2<21) sẽ trả về 1, nghĩa là 24 giờ, vậy, công thức trên sẽ trở thành = 24+2-21 = 5 (tiếng).
  
  Để hiểu thêm về cách mà Excel tính toán thời gian, bạn xem ở đây: Các hàm ngày tháng và thời gian
  
  
  
• Tính thành tiền (F5):
  
  Công thức của bạn: =(HOUR(E5)*60+MINUTE(E5))*150
  
  Có thể sửa lại là: =E5*24*9000
  
  Có phải bạn tính giá cho 1 phút là 150 đồng? Nghĩa là 1 tiếng = 9.000 đồng? Con số thời gian bạn đã tính ra ở E5, Excel sẽ xem đó là "một phần" của một ngày (ví dụ, 6 tiếng = 1/4 ngày), do đó, để quy ra "tiếng đồng hồ", ta sẽ nhân nó với 24, rồi nhân tiếp với giá tiền của 1 giờ.
  
  Trong file của bạn, tôi đặt thêm một ô tính Giá tiền một giờ ở C2. Sở dĩ nên làm vậy, để nếu bạn muốn tăng giá, hay hạ giá tiền một giờ, bạn chỉ cần thay đổi con số ở C2, là cả bảng tính sẽ được cập nhật, không cần phải sửa công thức ở cột F.
  
  Khi đó, công thức ở F5 có thể viết lại là: =E5*24*$C$2
  
  Và như trên tôi đã nói, nếu như bạn đồng ý với chuyện là phải có một số tiền tối thiểu (tạm gọi là tiền mở máy...), ví dụ như 5.000, tôi làm thêm một ô nữa, ở F2, để ghi giá tiền tối thiểu này. Và công thức ở F5 sẽ như sau:
  
  =MAX(E5*24*$C$2, $F$2) ​
  
  Nghĩa là, nếu E5 nhỏ hơn F2 thì lấy F2.
  
  
  
• Việc làm tròn (G5):
  
  Công thức này của bạn: =IF((1000-RIGHT(F5,3))>500, F5-RIGHT(F5,3), IF((1000-RIGHT(F5,3))=500, F5, F5+(1000-RIGHT(F5,3))))
  
  Không sai, nhưng dài quá. Bởi vì bạn xài đơn vị tính là đồng. Ngày nay đâu có ai xài đồng đâu bạn, do đó, bạn nên dùng đơn vị tính là ngàn đồng, thì việc làm tròn rất dễ, và công thức ngắn bớt. Chỉ có một lưu ý, là bạn nhớ định dạng cho những ô chứa số tiền có 3 số lẻ thập phân.
  
  =IF(MOD(F5,INT(F5))<0.5, INT(F5), IF(MOD(F5,INT(F5))=0.5, F5, INT(F5)+1))​
  
  Hàm MOD là hàm tính số dư của một phép chia, còn hàm INT là hàm lấy phần nguyên của một con số.
  
  Tuy nhiên, nếu như đổi đơn vị tính sang ngàn đồng, thì bạn phải nhớ chia hết số tiền khách đã trả cho 1000 (dùng Paste Special với tùy chọn Divide cho lẹ), rồi ở ô C2 (đơn giá 1 giờ) và ô F2 (số tiền tối thiểu, nếu có), bạn cũng phải nhập lại, 1 con số thôi (9 và 5 chẳng hạn), và cũng định dạng cho nó có 3 số 0 ở phần thập phân, cho giống như tiền ngàn vậy (Excel sẽ hiển thị là 5.000 và 9.000).
  
  Đó là làm theo cách bạn muốn: Nếu số lẻ không tới 500 đồng, thì không tính, nếu số lẻ bằng 500 đồng, thì tính nguyên, và nếu số lẻ hơn 500 mà chưa tới 1000, thì làm tròn lên ngàn đồng tiếp theo. Còn nếu làm theo kiểu của tui: chưa đến 500 đồng thì làm tròn đến 500 đồng, đúng 500 đồng thì tính đúng giá, còn hơn 500 đến dưới 1000 thì làm tròn đến ngàn tiếp theo, công thức ở G5 sẽ ngắn ngủn như sau:
  
  =CEILING(E5, 0.5)​
  Ceiling, theo tiếng Anh, có nghĩa là cái trần nhà, còn trong Excel, nó dùng làm tròn lên đến một bội số nào đó đã được xác định. Ở đây, tôi cho làm tròn lên đến 500 đồng (0.5 của 1 ngàn đồng).
  
  
  
• Tồn cuối ngày (J5):
  
  Cái này làm như bạn cũng được, nhưng phải có 2 công thức, một cho J5 và một cho những ô bên dưới. Đề nghị với bạn một công thức thôi, nhập cho cả cột J:
  
  =$J$2+SUM($G$5:G5)​
  Ô J2 là ô chứa con số 1 triệu đồng đầu ngày của bạn.

Gửi bạn cái file tôi làm theo những gì đã nói ở trên đây. Nếu thích, bạn có thể dùng.

 

[hoailinh_191]

Cám ơn bạn rất hữu ích. có ai có thêm ý kiến nữa không ví dụ cửa hàng còn có khác khoản thu thêm từ bán bim bim, bánh kẹo, thuốc lá mỳ tôm. làm sao quan lý tiền thu đc từ các nguồn này luôn.

 

[BNTT]

Cám ơn bạn rất hữu ích. có ai có thêm ý kiến nữa không ví dụ cửa hàng còn có khác khoản thu thêm từ bán bim bim, bánh kẹo, thuốc lá mỳ tôm. làm sao quan lý tiền thu đc từ các nguồn này luôn.

Bạn cứ tạo ra một file mẫu, cụ thể, theo ý bạn, rồi gửi lên. Chứ chẳng lẽ chúng tôi phải giả lập dùm bạn sao? Tốt hơn nữa là giống như file trước, bạn cứ tự làm, rồi chúng tôi sẽ góp ý, như vậy sẽ vừa tốt hơn cho bạn, sẽ giúp bạn học mau hơn, mà cũng khỏe hơn cho chúng tôi...
Bạn đồng ý chứ?