Tính tổng của một số ô liên tiếp trong dãy các ô

[tuanvd]

Xin chào mọi người, tôi có 1 vấn đề mong mọi người giúp, yêu cầu như trong file đính kèm.
Trân trọng

 

[phihndhsp]

Xin chào mọi người, tôi có 1 vấn đề mong mọi người giúp, yêu cầu như trong file đính kèm.
Trân trọng

Bạn thử ô N2=SUM(INDIRECT(ADDRESS(ROW(),2)&":"&ADDRESS(ROW(),12+COUNTBLANK(B2:M2)-6)))

 

[thanhsangnguyen1982]

Đếm tổng

Bạn xem thử file ko biết đúng ý bạn ko?

 

[thanhsangnguyen1982]

Bạn dùng công thức này: tại ô N2, vì là công thức mãng nên khi kết thúc công thức nhấn tổ hợp phím Ctrl + Shift +Enter
=SUMPRODUCT(IF($B$1:$M$1<=5+COUNTBLANK($B2:$M2),1,0)*($B2:$M2))

 

[tuanvd]

Bạn dùng công thức này: tại ô N2, vì là công thức mãng nên khi kết thúc công thức nhấn tổ hợp phím Ctrl + Shift +Enter
=SUMPRODUCT(IF($B$1:$M$1<=5+COUNTBLANK($B2:$M2),1,0)*($B2:$M2))

Sao công thức của bạn báo lỗi vậy, mình không rõ lắm nếu bạn sửa giúp mình thì tốt quá, excel mình kém lắm
Trân trọng

 

[thanhsangnguyen1982]

Tổng số liệu

Bạn xem file mình đính kèm

 

[ndu96081631]

Xin chào mọi người, tôi có 1 vấn đề mong mọi người giúp, yêu cầu như trong file đính kèm.
Trân trọng

Dùng công thức này:

=SUM(N(OFFSET($A2,,SMALL(IF($B2:$M2="","",$B$1:$M$1),{1,2,3,4,5}))))

- Không cần bất cứ cột phụ nào
- Công thức này luôn lấy 5 cell đầu tiên có dữ liệu, ngay cả trường hợp 5 cell ấy không nằm liền kề nhau
- Công thức mảng, phải kết thức bằng tổ hợp phím Ctrl + Shift + Enter

 

[MonaLisa7775]

Công thức thường nà, không cần ctrl Shift Enter gì hết nà:
=SUM(OFFSET(A2;;COUNTBLANK(B2:M2)+1;1;5))

Cơ mà sau vùng trống là phải liên tục há!

 

[bebo021999]

Dùng cái này này tại N2 cũng được:

=sum(offset($a2,,min(if($b2:$m2="","",match($b2:$m2,$b2:$m2,0))),,5))

Kết thúc bằng Ctrl_shift-enter

 

[ptm0412]

Ngoại trừ công thức của ndu là có xét đến dữ liệu không liên tục, còn các công thức khác thì của Monalisa là ngắn nhất, và không phải công thức mảng.

 

[phihndhsp]

Ngoại trừ công thức của ndu là có xét đến dữ liệu không liên tục, còn các công thức khác thì của Monalisa là ngắn nhất, và không phải công thức mảng.

Thưa thầy em thấy công thức này cũng liên tục mà

=SUM(INDIRECT(ADDRESS(ROW(),2)&":"&ADDRESS(ROW(),6+COUNTBLANK(B2:M2))))

{=SUMPRODUCT(IF($B$1:$M$1<=5+COUNTBLANK($B2:$M2),1, 0)*($B2:$M2))}

 

[ptm0412]

Thưa thầy em thấy công thức này cũng liên tục mà

Dạ thưa anh, tôi nói rằng: trong tất cả các công thức tính tổng 5 ô liên tục, công thức của Monalisa ngắn nhất và không phải công thức mảng.

 

[ndu96081631]

Thưa thầy em thấy công thức này cũng liên tục mà

=SUM(INDIRECT(ADDRESS(ROW(),2)&":"&ADDRESS(ROW(),6+COUNTBLANK(B2:M2))))

{=SUMPRODUCT(IF($B$1:$M$1<=5+COUNTBLANK($B2:$M2),1, 0)*($B2:$M2))}

Thử xóa 1 cell tại cột M xem công thức của bạn còn đúng không nha
Nói chung, nếu là giá trị không liên tục mà dùng COUNTBLANK gì gì đó thì.. THUA

 

[MonaLisa7775]

Hic hic, lại còn vụ trống ô cuối nữa mình ơi! Mình mới iu cầu dữ liệu liên tục thôi mà quên vụ "ngày kết thúc có thể khác nhau" (dù tác giả hong nói)

Có thể countBlank lùi lại 5 ngày, hong bít tác giả chịu hong ta? M - 5 = H hé?

=SUM(OFFSET(A2;;COUNTBLANK(B2:H2)+1;1;5))

Í mà hổng được, nếu tác giả chừa sẵn mấy chục cột trống sau đuôi thì cũng chít á!

 

[tuanvd]

Cám ơn các bác đã giúp, em đã sang tên đổi chủ xong công thức của các bác, còn 1 vấn đề nữa em muốn nhờ các bác như trong file đính kèm.
Trân trọng

 

[ndu96081631]

Cám ơn các bác đã giúp, em đã sang tên đổi chủ xong công thức của các bác, còn 1 vấn đề nữa em muốn nhờ các bác như trong file đính kèm.
Trân trọng

Gõ công thức này vào N2:

=MIN(IF($B2:$M2="","",$B$1:$M$1))

Bấm Ctrl + Shift + Enter để kết thúc

 

[thanhsangnguyen1982]

Công thức ô N2:
=SMALL($B$1:$M$1,1+COUNTBLANK($B2:$M2))
vì là công thức mảng nên kết thúc bằng Ctrl+Shift+Enter

 

[MonaLisa7775]

Nếu các ô trống của các cột cuối đều là 0 như file, thì công thức này hong cần Ctrl + Shift + Enter nà:
N2 =OFFSET($B$1;;COUNTBLANK(B2:M2))

 

[tuanvd]

Gõ công thức này vào N2:

=MIN(IF($B2:$M2="","",$B$1:$M$1))

Bấm Ctrl + Shift + Enter để kết thúc

Cám ơn bác ndu96081631