Tính giá combo theo sản phẩm được chọn

[castanea]

Hi mọi người. Mình đang cần tính giá của các combo gồm nhiều sản phẩm khác nhau
data đầu vào có giá của các sản phẩm và combo sẽ gồm nhiều sp ghép lại với nhau
mình cần tính tổng giá trị của combo
Mình cần công thức tại ô Tổng tiền nhè
Cám ơn mọi người

 

[Phuocam]

Hi mọi người. Mình đang cần tính giá của các combo gồm nhiều sản phẩm khác nhau
data đầu vào có giá của các sản phẩm và combo sẽ gồm nhiều sp ghép lại với nhau
mình cần tính tổng giá trị của combo
Mình cần công thức tại ô Tổng tiền nhè
Cám ơn mọi người

Trong lúc đợi, xài tạm công thức mảng này:

=SUM(SUMIF($L$1:$L$6,IF(B2:G2="x",$B$1:$G$1,""),$M$1:$M$6))

Kết thúc bằng Ctrl+Shift+Enter.

Nếu chèn thêm dòng 2 và ghi giá sản phẩm dưới nó, công thức sẽ là:

=SUMPRODUCT(SUMIF(B3:G3,"x",$B$2:$G$2))

Chỉ Enter.

 

[xuongrongdat]

Nếu chèn thêm dòng 2 và ghi giá sản phẩm dưới nó, công thức sẽ là:

=SUMPRODUCT(SUMIF(B3:G3,"x",$B$2:$G$2))

Sao làm như này không được vậy anh?

 

[hocexcel_1991]

Sao làm như này không được vậy anh?
View attachment 269285

Bạn phải dùng thêm hàm TRANSPOSE

 

[castanea]

Trong lúc đợi, xài tạm công thức mảng này:

=SUM(SUMIF($L$1:$L$6,IF(B2:G2="x",$B$1:$G$1,""),$M$1:$M$6))

Kết thúc bằng Ctrl+Shift+Enter.

Nếu chèn thêm dòng 2 và ghi giá sản phẩm dưới nó, công thức sẽ là:

=SUMPRODUCT(SUMIF(B3:G3,"x",$B$2:$G$2))

Chỉ Enter.

Mình thấy công thức đầu tiên ko cần dùng mảng nó vẫn trả về kết quả đúng
Nếu thêm dòng vlookup giá qua thì chỉ cần sumif là dc mà mình ko muốn có thêm dòng đó nên mình làm cách 1 của bạn.
cám ơn bạn nhiều

 

[xuongrongdat]

Bạn phải dùng thêm hàm TRANSPOSE

Như thế nào bạn?
Mình tưởng Sumproduct nhân mảng 2 chiều được luôn chứ.

 

[Phuocam]

Nếu dùng 365, chỉ cần Enter.

Trường hợp vị trí sản phẩm giống nhau như trong file, chỉ khác ngang và dọc, có thể dùng:

=MMULT(--(B2:G2="x"),$M$1:$M$6)

.

 

[echo07]

Thêm nữa cho nhiều nè.

=SUM(IF(($B$1:$G$1=$L$1:$L$6)*($B2:$G2="x"),$M$1:$M$6,))

Ctr+Shift+Enter

Ps: số bạn đưa ra trong ví dụ là sai so với công thức nhé.

 

[castanea]

Thêm nữa cho nhiều nè.

=SUM(IF(($B$1:$G$1=$L$1:$L$6)*($B2:$G2="x"),$M$1:$M$6,))

Ctr+Shift+Enter

Ps: số bạn đưa ra trong ví dụ là sai so với công thức nhé.

View attachment 269286

Thanks bạn.
cộng vội vd nên sai vậy mới tháy nguy hiểm nếu ko dùng công thức để tự tính

 

[hocexcel_1991]

Như thế nào bạn?
Mình tưởng Sumproduct nhân mảng 2 chiều được luôn chứ.

SUMPRODUCT((B3:G3="x")*TRANSPOSE($B$2:$G$2))

 

[longtay1111]

Tại I3=SUMIFS($B$2:$G$2,B3:G3,"x") kéo xuống là xong