Tìm kiếm bằng Match và Index bị lỗi khi giá trị tìm kiếm lớn hơn 255 ký tự.

[TuAnAnh94]

Thân gửi các bác trên diễn đàn GPE.
Em đang sử dụng match và index để tìm kiếm dữ liệu trong công việc, ví dụ như trong file.
Vấn đề là ô giá trị tìm kiếm quá dài nên kết quả cứ báo #value! miết.
Các bác có giải pháp gì không chỉ em với./

 

[HieuCD]

Thân gửi các bác trên diễn đàn GPE.
Em đang sử dụng match và index để tìm kiếm dữ liệu trong công việc, ví dụ như trong file.
Vấn đề là ô giá trị tìm kiếm quá dài nên kết quả cứ báo #value! miết.
Các bác có giải pháp gì không chỉ em với./

Bạn nên đặt mã hành trình và tìm theo mã

 

[TuAnAnh94]

Cảm ơn bác đã trả lời. Việc đặt theo Mã Hành Trình em cũng đã nghĩ tới nhưng khi sử dụng để cập nhật vào bảng rất khó khăn vì số lượng hành trình là rất nhiều, khi không nhớ mã sẽ phải quay lại bảng nguồn để xem.

 

[HieuCD]

Cảm ơn bác đã trả lời. Việc đặt theo Mã Hành Trình em cũng đã nghĩ tới nhưng khi sử dụng để cập nhật vào bảng rất khó khăn vì số lượng hành trình là rất nhiều, khi không nhớ mã sẽ phải quay lại bảng nguồn để xem.

F6 =IF(D6="","",INDEX($B$3:$C$6,INDEX(MATCH(TRUE,$A$3:$A$6=D6,0),0),MATCH(E6,$B$2:$C$2,0)))

Chuẩn hơn

=IFERROR(INDEX($B$3:$C$6,INDEX(MATCH(TRUE,$A$3:$A$6=D6,0),0),MATCH(E6,$B$2:$C$2,0)),"")

 

[TuAnAnh94]

F6 =IF(D6="","",INDEX($B$3:$C$6,INDEX(MATCH(TRUE,$A$3:$A$6=D6,0),0),MATCH(E6,$B$2:$C$2,0)))

Chuẩn hơn

=IFERROR(INDEX($B$3:$C$6,INDEX(MATCH(TRUE,$A$3:$A$6=D6,0),0),MATCH(E6,$B$2:$C$2,0)),"")

Mọi thứ đã trơn tru. Xin cảm ơn Mr HieuCD rất nhiều.

 

[Phuocam]

Góp vui:

=IFERROR(LOOKUP(2,1/($A$3:$A$4=D6),INDEX($A$3:$C$4,0,MATCH(E6,$A$2:$C$2,0))),"")

 

[Phan Thế Hiệp]

Cũng góp vui:
=IFERROR(HLOOKUP(E6,$B$2:$C$4,LOOKUP(4,{1;2;3}/(D6=$A$2:$A$4)),),"")
Hoặc:
=IFERROR(HLOOKUP(E6,$B$2:$C$4,LOOKUP(,0/(D6=$A$2:$A$4),ROW($1:$100)),),"")
Cả 2 chỉ Enter.

Thân

 

[dazkangel]

Thử:

=SUMPRODUCT((A$3:A$4=D6)*(B$2:C$2=E$6),B$3:C$4)