Tìm 5 doanh thu bán hàng lớn nhất và 5 doanh thu bán hàng nhỏ nhất- KHÔNG TÍNH TRÙNG

[longtay1111]

Em chào các Anh/ Chị/ em trong nhóm Giaiphapexcel

Em có 1 bảng doanh thu bán hàng của các nhân viên trong nhóm theo ngày bán hàng.
Em được yêu cầu thống kê Top 5 doanh số bán hàng cao nhất và 5 doanh thu bán hàng thấp nhất của từng nhân viên theo ngày.

Em dùng lệnh Small và Large để tìm Top 5 giá trị doanh thu lớn nhất và nhỏ nhất

Max={IFERROR(LARGE(IF($B$6:$B$116=$G6,IF($D$6:$D$116=$H6,$E$6:$E$116)),I$5),"")}

Min={IFERROR(SMALL(IF($B$6:$B$116=$G30,IF($D$6:$D$116=$H30,$E$6:$E$116)),I$29),"")}

( em dùng công thức mảng ạ )

Nhưng kết quả Top 5 toàn cho ra giá trị trùng nhau, ví dụ Nhân viên Nguyễn Minh Anh ngày 01/01/2021 có doanh thu bán hàng lần lượt là 200.000,100.000,200.000, nhưng khi tìm Top 5 doanh thu cao nhất thì số công thức trên cho ra kết quả số 1( xếp đầu tiên -cao nhất ) là 200.000, số 2( xếp cao thứ 2) cũng là 200.000 và số 3( xếp cao thứ 3 ) là 100.000.

Mong muốn của em là nhờ các anh chị em trong nhóm hỗ trợ em lọc trùng những giá trị này, cụ thể em mong muốn là số 1( doanh thu cao nhất ) có giá trị là 200.000, số 2(doanh thu cao thứ 2) là 100.000, số 3,4,5( doanh thu cao thứ 3,4,5) không có.....

Tương tự với Top 5 doanh thu nhỏ nhất cũng vậy, xếp hạng KHÔNG BỊ TRÙNG DOANH THU.

Em cảm ơn anh chị em trong nhóm rất nhiều, chi tiết anh chị em tham khảo file đính kèm giúp em với ạ.

 

[Phan Thế Hiệp]

Em chào các Anh/ Chị/ em trong nhóm Giaiphapexcel

Em có 1 bảng doanh thu bán hàng của các nhân viên trong nhóm theo ngày bán hàng.
Em được yêu cầu thống kê Top 5 doanh số bán hàng cao nhất và 5 doanh thu bán hàng thấp nhất của từng nhân viên theo ngày.

Em dùng lệnh Small và Large để tìm Top 5 giá trị doanh thu lớn nhất và nhỏ nhất

Max={IFERROR(LARGE(IF($B$6:$B$116=$G6,IF($D$6:$D$116=$H6,$E$6:$E$116)),I$5),"")}

Min={IFERROR(SMALL(IF($B$6:$B$116=$G30,IF($D$6:$D$116=$H30,$E$6:$E$116)),I$29),"")}

( em dùng công thức mảng ạ )

Nhưng kết quả Top 5 toàn cho ra giá trị trùng nhau, ví dụ Nhân viên Nguyễn Minh Anh ngày 01/01/2021 có doanh thu bán hàng lần lượt là 200.000,100.000,200.000, nhưng khi tìm Top 5 doanh thu cao nhất thì số công thức trên cho ra kết quả số 1( xếp đầu tiên -cao nhất ) là 200.000, số 2( xếp cao thứ 2) cũng là 200.000 và số 3( xếp cao thứ 3 ) là 100.000.

Mong muốn của em là nhờ các anh chị em trong nhóm hỗ trợ em lọc trùng những giá trị này, cụ thể em mong muốn là số 1( doanh thu cao nhất ) có giá trị là 200.000, số 2(doanh thu cao thứ 2) là 100.000, số 3,4,5( doanh thu cao thứ 3,4,5) không có.....

Tương tự với Top 5 doanh thu nhỏ nhất cũng vậy, xếp hạng KHÔNG BỊ TRÙNG DOANH THU.

Em cảm ơn anh chị em trong nhóm rất nhiều, chi tiết anh chị em tham khảo file đính kèm giúp em với ạ.

Thử:
1/ Từ Doanh thu cao đến thấp:

I6=IFERROR(AGGREGATE(14,6,$E$6:$E$200/(MATCH($E$6:$E$200,IF(($G6=$B$6:$B$200)*($H6=$D$6:$D$200),$E$6:$E$200),)=ROW($1:$300)),I$5),)

Kết thúc bằng Ctrl+Shift+Enter. Fill qua phải rồi xuống.

2/ Từ Doanh thu thấp đến cao:

I30=IFERROR(AGGREGATE(15,6,$E$6:$E$200/(MATCH($E$6:$E$200,IF(($G30=$B$6:$B$200)*($H30=$D$6:$D$200),$E$6:$E$200),)=ROW($1:$300)),I$29),)

Kết thúc bằng Ctrl+Shift+Enter. Fill qua phải rồi xuống.

Thân

 

[longtay1111]

Thử:
1/ Từ Doanh thu cao đến thấp:

I6=IFERROR(AGGREGATE(14,6,$E$6:$E$200/(MATCH($E$6:$E$200,IF(($G6=$B$6:$B$200)*($H6=$D$6:$D$200),$E$6:$E$200),)=ROW($1:$300)),I$5),)

Kết thúc bằng Ctrl+Shift+Enter. Fill qua phải rồi xuống.

2/ Từ Doanh thu thấp đến cao:

I30=IFERROR(AGGREGATE(15,6,$E$6:$E$200/(MATCH($E$6:$E$200,IF(($G30=$B$6:$B$200)*($H30=$D$6:$D$200),$E$6:$E$200),)=ROW($1:$300)),I$29),)

Kết thúc bằng Ctrl+Shift+Enter. Fill qua phải rồi xuống.

Thân

Dạ em cảm ơn anh rất rất nhiều ạ, em đã làm được rồi. Em chân thành cảm ơn anh và chúc anh 1 ngày mơi tốt lành ạ.

 

[Binbo2020]

Ctrl+Shift+Enter

Như này thôi đỡ phải Ctrl+Shift+Enter anh
Lớn, nhỏ:

I6=IFERROR(AGGREGATE(14;6;(($E$6:$E$116)*($E$6:$E$116<IF(I$5=1;10^9;H6)))/(($B$6:$B$116=$G6)*($D$6:$D$116=$H6));1);"")
I30=IFERROR(AGGREGATE(15;6;(($E$6:$E$116)/($E$6:$E$116>IF(I$29=1;0;H30)))/(($B$6:$B$116=$G30)*($D$6:$D$116=$H30));1);"")

 

[hocexcel_1991]

Excel365

I6=IFERROR(LARGE(UNIQUE(FILTER($E$6:$E$116,($B$6:$B$116=$G6)*($D$6:$D$116=$H6))),I$5),0)
I30=IFERROR(SMALL(UNIQUE(FILTER($E$6:$E$116,($B$6:$B$116=$G30)*($D$6:$D$116=$H30))),I$29),0)

 

[longtay1111]

Như này thôi đỡ phải Ctrl+Shift+Enter anh
Lớn, nhỏ:

I6=IFERROR(AGGREGATE(14;6;(($E$6:$E$116)*($E$6:$E$116<IF(I$5=1;10^9;H6)))/(($B$6:$B$116=$G6)*($D$6:$D$116=$H6));1);"")
I30=IFERROR(AGGREGATE(15;6;(($E$6:$E$116)/($E$6:$E$116>IF(I$29=1;0;H30)))/(($B$6:$B$116=$G30)*($D$6:$D$116=$H30));1);"")

Dạ, em cảm ơn bác rất nhiều ạ, em đã làm thành công rồi ạ. Chân thành cảm ơn sự giúp đỡ của bác rất nhiều.

Bài đã được tự động gộp: 11/11/21

Excel365

I6=IFERROR(LARGE(UNIQUE(FILTER($E$6:$E$116,($B$6:$B$116=$G6)*($D$6:$D$116=$H6))),I$5),0)
I30=IFERROR(SMALL(UNIQUE(FILTER($E$6:$E$116,($B$6:$B$116=$G30)*($D$6:$D$116=$H30))),I$29),0)

Dạ, em cảm ơn bác nhiều nhiều ạ, máy em rất tiếc chưa dùng 365, nhưng em vẫn được học hỏi thêm được cách làm mơi qua công thức của bác ạ.

 

[Phan Thế Hiệp]

Như này thôi đỡ phải Ctrl+Shift+Enter anh
Lớn, nhỏ:

I6=IFERROR(AGGREGATE(14;6;(($E$6:$E$116)*($E$6:$E$116<IF(I$5=1;10^9;H6)))/(($B$6:$B$116=$G6)*($D$6:$D$116=$H6));1);"")
I30=IFERROR(AGGREGATE(15;6;(($E$6:$E$116)/($E$6:$E$116>IF(I$29=1;0;H30)))/(($B$6:$B$116=$G30)*($D$6:$D$116=$H30));1);"")

($E$6:$E$116<IF(I$5=1;10^9;H6))
Sáng ý, rất hay!

Thay toàn bộ dấu * bằng / cũng được.

Thân

 

[leonguyenz]

Như này thôi đỡ phải Ctrl+Shift+Enter anh
Lớn, nhỏ:

I6=IFERROR(AGGREGATE(14;6;(($E$6:$E$116)*($E$6:$E$116<IF(I$5=1;10^9;H6)))/(($B$6:$B$116=$G6)*($D$6:$D$116=$H6));1);"")
I30=IFERROR(AGGREGATE(15;6;(($E$6:$E$116)/($E$6:$E$116>IF(I$29=1;0;H30)))/(($B$6:$B$116=$G30)*($D$6:$D$116=$H30));1);"")

Bỏ IFERROR vẫn ổn nhỉ.
Ngoài lề chút: số đẹp quá, nếu tham gia GPE sau một ngày nữa thì lục quý luôn!

 

[longtay1111]

Bỏ IFERROR vẫn ổn nhỉ.
Ngoài lề chút: số đẹp quá, nếu tham gia GPE sau một ngày nữa thì lục quý luôn!
View attachment 269265

Tuyệt vời, cảm ơn bạn nhiều nhé

 

[HieuCD]

Bỏ IFERROR vẫn ổn nhỉ.
Ngoài lề chút: số đẹp quá, nếu tham gia GPE sau một ngày nữa thì lục quý luôn!
View attachment 269265

Không có gì hoàn hảo 100%, sau 1 ngày thời sinh viên gọi là 6 cây gậy (điểm 1)