Những vấn đề về hàm IF

[Jenhcv]

mình hok biết tải file lên làm sao hết á, đơn giản là mình dùng hàm này để lấy Mã Hàng từ 1 bảng khác qua. Có ai giúp mình được mình cám ơn nhìu

 

[Hoàng Trọng Nghĩa]

mình hok biết tải file lên làm sao hết á

Bạn theo đường dẫn này nhé:
http://www.giaiphapexcel.com/forum/showthread.php?t=250
Sau khi xem xong, bạn sẽ biết nhiều thủ thuật trong GPE.

đơn giản là mình dùng hàm này để lấy Mã Hàng từ 1 bảng khác qua. Có ai giúp mình được mình cám ơn nhìu

Bạn cứ làm như bạn Mig17 là được rồi:

Vì hàm if chỉ lồng được 8 hàm nên theo tôi, bạn nên dùng 2 ô trung gian, mỗi ô gom công thức lồng 4 hàm if. Sau đó gom tiếp kết quả của 2 ô trung gian đó.

 

[Jenhcv]

http://www.mediafire.com/download.php?lmgqwzwmgmy

Đây là File của mình xin nhờ mọi người giúp dùm, nó nằm ở SCT cột Mã Hàng. Bảng tính mình làm không tốt, công thức hơi lung tung, nhờ mọi người sửa giùm.

Cám ơn mọi người ^__^

À yêu cầu của mình là làm sao cho Sheet SCT tự chạy được từ bản gốc là SBH

 

[duongdv]

Bạn xem công thức của mình nhé. Chẳng cần dùng đến hàm IF() nào.
=INDEX(SBH!$I$4:$R$4,,MAX(COLUMN(SBH!I5:R5)*(SBH!I5:R5<>0))-8)

 

[Jenhcv]

Cám ơn bạn Duongdv rất nhìu, bạn có thể giải thích dùm mình công thức của bạn không?

 

[duongdv]

Việc giải thích một công thức về mảng là rất khó trong cách diễn đạt vì nó hơi trìu tượng một chút.
Trước tiên bạn cần tìm hiểu về lý thuyết và cấu trúc của một số hàm có trong công thức. Các hàm này có tài liệu CÔNG THỨC & HÀM EXCEL được ban quản trị biên soạn công phu chi tiết cùng các ví dụ sinh động rễ hiểu. Bạn có thể vào diễn đàn tìm hoặc download tại đây.
http://www.4shared.com/file/53407070/61f57ae4/_2__Excel_Function_and_Formulas.html?err=no-sess
Sau khi bạn tìm hiểu lý thuyết về các hàm bạn có mở phần bài tập của bạn trong đó có công thức mình làm
=INDEX(SBH!$I$4:$R$4,,MAX(COLUMN(SBH!I5:R5)*(SBH!I5:R5<>0))-8)
Bạn copy riêng từng hàm một ra để xem kết quả trả về của hàm đó trên cơ sở đó bạn sẽ hiểu được toàn bộ công thức.

 

[huuthang_bd]

http://www.mediafire.com/download.php?lmgqwzwmgmy

Đây là File của mình xin nhờ mọi người giúp dùm, nó nằm ở SCT cột Mã Hàng. Bảng tính mình làm không tốt, công thức hơi lung tung, nhờ mọi người sửa giùm.

Cám ơn mọi người ^__^

À yêu cầu của mình là làm sao cho Sheet SCT tự chạy được từ bản gốc là SBH

Trường hợp này không cần đến công thức mảng đâu. Dùng LOOKUP() là được rồi.

=LOOKUP(10^10,SBH!$I5:$Q5,SBH!$I$4:$Q$4)

 

[duongdv]

Trường hợp này không cần đến công thức mảng đâu. Dùng LOOKUP() là được rồi.

=LOOKUP(10^10,SBH!$I5:$Q5,SBH!$I$4:$Q$4)

To huuthang_bd trong công thức của bạn cái 10^10 có ý nghĩa gì vậy?

 

[huuthang_bd]

To huuthang_bd trong công thức của bạn cái 10^10 có ý nghĩa gì vậy?

10^10 là 10 mũ 10. Tôi muốn lấy một giá trị thật lớn, lớn hơn các giá trị có thể có của dữ liệu để dò vì hàm Lookup() sẽ trả về vị trí của số cuối cùng nhỏ hơn hoặc bằng số được dò tìm.
Bạn thử các công thức này để hiểu thêm về hàm Lookup()

=LOOKUP(3,{1,2,3,4,5},{"a","b","c","d","e","f"})

=LOOKUP(6,{1,2,3,4,5},{"a","b","c","d","e","f"})

=LOOKUP(-2,{1,2,3,4,5},{"a","b","c","d","e","f"})

 

[Jenhcv]

cám ơn mọi người rất nhìu ^__^

 

[daikatung]

Tớ muốn lập 1 bảng tính: Nếu A1=1 thì B1=C1; nếu A1=2 thì B1=C2, nếu A1=3 thì B1=C3; ... ; nếu A1=50 thì B1=C50. Ai biết chỉ giùm tớ với, loay hoay cả tuần mà tớ không làm được. Thank nhiều. Gởi vào mail daikatung@gmail.com giùm tớ với nhé!

 

[hoangminhtien]

Tớ muốn lập 1 bảng tính: Nếu A1=1 thì B1=C1; nếu A1=2 thì B1=C2, nếu A1=3 thì B1=C3; ... ; nếu A1=50 thì B1=C50. Ai biết chỉ giùm tớ với, loay hoay cả tuần mà tớ không làm được. Thank nhiều. Gởi vào mail daikatung@gmail.com giùm tớ với nhé!

Bạn thử dùng công thức sau xem có được không nhé!

B1=IF(AND(INT(A1)=A1,A1>0),INDIRECT(ADDRESS(A1,3)),"")

hoặc

B1=IF(AND(INT(A1)=A1,A1>0),OFFSET($C$1,A1-1,0),"")

 

[daikatung]

Bảng tính của bạn thì đúng rồi, nhưng mình không ứng dụng được, giúp thêm mình cái này nữa nhé.
Nếu B2=1 thì C2=Sheet2!A1, Nếu B2=2 thì C2=Sheet2!A2, ... , Nếu B2=50 thì C2=Sheet2!A50.
Giúp mình 1 lần nữa nhé! Thank!!

 

[hoangminhtien]

Bảng tính của bạn thì đúng rồi, nhưng mình không ứng dụng được, giúp thêm mình cái này nữa nhé.
Nếu B2=1 thì C2=Sheet2!A1, Nếu B2=2 thì C2=Sheet2!A2, ... , Nếu B2=50 thì C2=Sheet2!A50.
Giúp mình 1 lần nữa nhé! Thank!!

Bạn xem có đúng ý bạn không nhé!

 

[daikatung]

ok? rồi, thank hoangminhtien, cách 1 &3 thì tốt, nhưng cách 2 bị giới hạn.

 

[Hoàng Trọng Nghĩa]

ok? rồi, thank hoangminhtien, cách 1 &3 thì tốt, nhưng cách 2 bị giới hạn.

CÁCH NÀO CŨNG TỐT bạn à, vấn đề là bạn biết vận dụng thêm tí xíu thôi, ý bạn nói nếu ngoài những số dữ liệu thì CÁCH 2 sẽ cho ra giá trị #REF! phải không? OK bạn thêm một tí vào thôi mà!

=IF(ISERROR(IF(AND(INT(B2)=B2,B2>0),INDEX(Sheet2!$A$1:$A$9,Sheet1!B2,0),"")),0,IF(AND(INT(B2)=B2,B2>0),INDEX(Sheet2!$A$1:$A$9,Sheet1!B2,0),""))

 

[hvman_126]

giúp em về hàm if với

lâu lắm rồi mới dùng lại excel....
giúp em cái bài này đi.
lấy kí tự đầu tiên của mã sãn phẫm; nếu là s thì xuất chữ sony
nếu h thì xuất chử hitachi, nếu t thì xuất chữ toshiba, nếu a thì xuất 4tech, nếu l thì xuất chữ loghitec.
giúp em nhé xin đa tạ

 

[duongdv]

Bạn làm như sau nhé
=IF(LEFT(A1,1)="S",Sony,IF(LEFT(A1,1)="H","Hitachi",IF(LEFT(A1,1)="T","Tosiba",IF(LEFT(A1,1)="A","4tech","loghitec"))))

 

[BNTT]

Bạn làm như sau nhé
=IF(LEFT(A1,1)="S","Sony",IF(LEFT(A1,1)="H","Hitachi",IF(LEFT(A1,1)="T","Tosiba",IF(LEFT(A1,1)="A","4tech","loghitec"))))

Có thể ngắn hơn tí:

=IF(LEFT(A1)="S","Sony",IF(LEFT(A1)="H","Hitachi",IF(LEFT(A1)="T","Tosiba",IF(LEFT(A1)="A","4tech","loghitec"))))​

 

[thanh_tks]

Có thể ngắn hơn tí:

=IF(LEFT(A1)="S","Sony",IF(LEFT(A1)="H","Hitachi",IF(LEFT(A1)="T","Tosiba",IF(LEFT(A1)="A","4tech","loghitec"))))​

Bác toàn làm tắt,sumif cũng tắt, left cũng tắt .còn cái gì tắt nữa bác cho em xem để học hỏi tí xíu.