Nhờ giúp đỡ về công thức dò tìm.

[tictactictac]

Em cũng học kế toán nhưng từ ngày ra trường không làm gì tới kế toán nên giờ quên hết công thức, nên nhờ các bác giúp e tạo 1 công thức dò tìm như file ví dụ ở bên dưới ạ. Như e có dữ liệu có đơn hàng và số lượng, giờ e muốn tạo công thức xem số lượng của đơn hàng đó nằm trong dòng nào của phần số luơng đơn hàng từ đó lấy kết quả tương ứng ở cột lấy mẫu bên cạnh.
Em xin chân thành cảm ơn !

 

[huonglien1901]

Em cũng học kế toán nhưng từ ngày ra trường không làm gì tới kế toán nên giờ quên hết công thức, nên nhờ các bác giúp e tạo 1 công thức dò tìm như file ví dụ ở bên dưới ạ. Như e có dữ liệu có đơn hàng và số lượng, giờ e muốn tạo công thức xem số lượng của đơn hàng đó nằm trong dòng nào của phần số luơng đơn hàng từ đó lấy kết quả tương ứng ở cột lấy mẫu bên cạnh.
Em xin chân thành cảm ơn !

=INDEX($M$2:$M$16,MATCH(C2,{2;9;16;26;51;91;151;281;501;1201;3201;10001;35001;150001;500001},1),)

=OFFSET($M$1,MATCH(C2,{2;9;16;26;51;91;151;281;501;1201;3201;10001;35001;150001;500001},1),)

 

[HieuCD]

Em cũng học kế toán nhưng từ ngày ra trường không làm gì tới kế toán nên giờ quên hết công thức, nên nhờ các bác giúp e tạo 1 công thức dò tìm như file ví dụ ở bên dưới ạ. Như e có dữ liệu có đơn hàng và số lượng, giờ e muốn tạo công thức xem số lượng của đơn hàng đó nằm trong dòng nào của phần số luơng đơn hàng từ đó lấy kết quả tương ứng ở cột lấy mẫu bên cạnh.
Em xin chân thành cảm ơn !

Dùng công thức mảng

=INDEX($M$2:$M$16,MATCH(C2,--(LEFT(SUBSTITUTE($L$2:$L$16,"-",REPT(" ",6)),6)),1),)

nhấn Ctrl+Shift+Enter

 

[batman1]

Hãy thay 500001以上 bằng 500001-以上
Công thức cho E2, kết thúc bằng Ctrl+Shift+Enter

=INDEX($M$2:$M$16,MATCH(C2,--(REPLACE($L$2:$L$16,FIND("-",$L$2:$L$16),7,""))))

Cũng không cần thay thì công thức là, kết thúc bằng Ctrl+Shift+Enter

=INDEX($M$2:$M$16,MATCH(C2,--(REPLACE($L$2:$L$16,IFERROR(FIND("-",$L$2:$L$16),7),7,""))))

Nhưng chả lý gì làm khó mình khi sự thay đổi 500001-以上 chả ảnh hưởng gì cả, không làm tối nghĩa câu. Thậm chí tôi nghĩ nếu viết chuẩn phải có dấu cách, tức "500001 以上", chứ ai đời số dính với chữ. Như vậy ta chỉ thay dấu cách bằng dấu gạch ngang thôi.
-------------
Nhưng tại sao lại làm khó mình và làm nặng bảng tính? Tôi nghĩ là nếu bạn sửa L1 thành "Số lượng lô hàng (từ)" và nhập trong cột L các giá trị số 2, 9, 16, 26, ..., 500001 thì tôi tin rằng các đồng nghiệp và mỗi người làm chuyên môn của bạn chắc chắn hiểu.

Lúc đó công thức chỉ là, kết thúc bằng Enter

=VLOOKUP(C2,$L$2:$M$16,2)

 

[dazkangel]

Thử:

=LOOKUP(C2,--LEFT(SUBSTITUTE(L$2:L$16,"-",REPT(" ",6)),6),M$2:M$16)

 

[tictactictac]

cám ơn mọi người rất nhiều ạ !