Làm sao để thay đổi một cách đồng loạt kích cỡ của nhiều comment trong excel?

[vungoc]

Hỏi các cao thủ 1 vấn đề như sau:

Vui lòng mở xem file đính kèm

Hiện tại thì kích thước các comment tại các ô trong cột B này nhỏ xíu, k xem được nội dung hình ảnh trong comment đó


Làm sao để thay đổi một cách đồng loạt kích cỡ của tất cả các comment (giả sử thay đổi size của comment là bằng 3cm x 4cm) mà không phải click vào từng ô comment để edit kích thước từng cái một bằng cách thủ công các bác nhỉ?


Tks cả nhả!


Ghi chú: 1 File có cả hàng ngàn cái comment như thế, đây là mình trích mẫu là minh họa cho dễ hiểu thôi

 

[be_09]

Insert > Module cho code vào, sau đó chọn cột B rồi thử chạy Code này.

Sub Side_Comments()
        Dim Cell As Range
        For Each Cell In Selection
        If Not Cell.Comment Is Nothing Then
        With Cell.Comment.Shape.TextFrame.Characters.Font
        .Size = 12
        End With
        End If
        Next Cell
End Sub

Muốn cỡ chữ bao nhiêu thì thay
.Size = 10
.Size = 12
.Size = 14

 

[Quang_Hải]

Insert > Module cho code vào, sau đó chọn cột B rồi thử chạy Code này.

Sub Side_Comments()
        Dim Cell As Range
        For Each Cell In Selection
        If Not Cell.Comment Is Nothing Then
        With Cell.Comment.Shape.TextFrame.Characters.Font
        .Size = 12
        End With
        End If
        Next Cell
End Sub

Muốn cỡ chữ bao nhiêu thì thay
.Size = 10
.Size = 12
.Size = 14

Hình như là tác giả cần chỉnh cái khung chứ không phải font chữ ạ.

To VuNgoc
Thử vầy xem. Nếu muốn thay hàng loạt thì dùng vòng lặp chạy cái vèo.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Column = 2 Then
   With Selection.Comment.Shape
      .Width = 80
      .Height = 120
   End With
End If
End Sub

 

[vungoc]

Anh quanghai1969 hiểu đúng ý em đó, tuy nhiên em vẫn ""muốn thay hàng loạt thì dùng vòng lặp chạy cái vèo.""
Anh giúp em phát, cảm ơn anh nhiều!

 

[nmhung49]

Anh quanghai1969 hiểu đúng ý em đó, tuy nhiên em vẫn ""muốn thay hàng loạt thì dùng vòng lặp chạy cái vèo.""
Anh giúp em phát, cảm ơn anh nhiều!

Thử code này xem sao
[GPECODE=vb]
Sub Test()
Dim x As Range
Dim a As Range
Set x = Cells.SpecialCells(xlCellTypeComments)
For Each a In x.Areas
With a.Comment.Shape
.Width = 80
.Height = 120
End With
Next
End Sub
[/GPECODE]

 

[vungoc]

Chạy không được, báo lỗi!

 

[tungnguyen_kt]

Chạy không được, báo lỗi!

Sub vungoc()
        Dim Cell As Range
        For Each Cell In Selection
        If Not Cell.Comment Is Nothing Then
        With Cell.Comment.Shape
       .Width = 150
       .Height = 180
        End With
        End If
        Next Cell
End Sub

Chẳng hiểu gì hết, nhưng sửa thế này thì nó chạy, anh ngọc copy vào "mô đun" sau đó chọn cột B rồi chạy "cốt" thử xem sao.

 

[ndu96081631]

Chạy không được, báo lỗi!

Thử vầy:

Sub Test()
  Dim comm As Comment
  Dim lCount As Long
  lCount = ActiveSheet.Comments.Count
  If lCount Then
    For Each comm In ActiveSheet.Comments
      With comm.Shape
        .Width = 60
        .Height = 80
      End With
    Next
    MsgBox "Da thay doi kich thuoc cho " & lCount & " comments"
  Else
    MsgBox "Không tìm thay comments nào ca!"
  End If
End Sub

 

[Quang_Hải]

Thêm 1 cách viết để tham khảo

Sub ResizeCommentBox()
Dim i As Long
For i = 1 To [B65536].End(3).Row
   With Cells(i, 2)
      If Not .Comment Is Nothing Then
         .Comment.Shape.Width = 90
         .Comment.Shape.Height = 120
      End If
   End With
Next
End Sub

 

[vungoc]

Tuyệt, đã ngon...
Xin cảm ơn các anh và các bạn!