Hỏi về cách dùng hàm if lồng nhau.

[tohongdieu]

Các anh/chị xem dùm em cách dùng hàm if bên cột "Ghi chú" của em có vấn đề gì không sao nó lại chỉ hiển thị được 2 kết quả mà sai ben bét hết. Em xin cám ơn

 

[mhung12005]

Các anh/chị xem dùm em cách dùng hàm if bên cột "Ghi chú" của em có vấn đề gì không sao nó lại chỉ hiển thị được 2 kết quả mà sai ben bét hết. Em xin cám ơn

Như vầy mới đúng chứ bạn:

Z12=IF(V12>100,"Quá tải",IF(AND(V12>=80,V12<=100),"Đầy tải",IF(AND(V12>=50,V12<80),"Vừa tải","Non tải")))

 

[tohongdieu]

Cám ơn bạn mhung12005! Mình làm được rồi, nhưng cho mình hỏi, điều kiện của nó không thể cho: 50<=V12<80 được ah?

 

[vanle33]

Cám ơn bạn mhung12005! Mình làm được rồi, nhưng cho mình hỏi, điều kiện của nó không thể cho: 50<=V12<80 được ah?

Tất, lẽ, dĩ ngẫu nhiên rồi bạn!
Bạn thử đặt điều kiện 50<=V12<80 vào hàm AND xem có bị báo lỗi ko?

 

[tohongdieu]

Bạn cho mình hỏi thêm, nếu mỗi kết quả trả về mình sẽ cho hiển thị 1 màu khác nhau thì làm thế nào bạn ah, search trên mạng thây dùng conditional formatting, nhưng trong excel 2013 mình không biết dùng. cám ơn bạn

 

[vanle33]

Bạn cho mình hỏi thêm, nếu mỗi kết quả trả về mình sẽ cho hiển thị 1 màu khác nhau thì làm thế nào bạn ah, search trên mạng thây dùng conditional formatting, nhưng trong excel 2013 mình không biết dùng. cám ơn bạn

Mình nghĩ giao diện các menu của excel 2013 cũng tương tự excel 2010 chứ?
Để vào CF bạn nhấn Home/Conditional Formatting/Manager Rules...

 

[concogia]

Như vầy mới đúng chứ bạn:
Z12=IF(V12>100,"Quá tải",IF(AND(V12>=80,V12<=100),"Đầy tải",IF(AND(V12>=50,V12<80),"Vừa tải","Non tải")))

Hình như công thức này dư mấy em AND hay sao í
Thân

 

[VetMini]

Cám ơn bạn mhung12005! Mình làm được rồi, nhưng cho mình hỏi, điều kiện của nó không thể cho: 50<=V12<80 được ah?

50<=V12<80 chỉ là ký hiệu toán học để diễn tả một khoảng. Trên thực tế, ít có ngôn ngữ lập trình nào hiểu được ký hiệu này.
Chúng chỉ hiểu được rằng để định một khoảng, người ta cần giời hạn đầu và giới hạn đuôi.
Giới hạn đầu được diễn tả là 50<=V12; giới hạn đuôi V12<80; còn lại chữ "và", nó phải được diễn tả bằng hàm AND()

Hình như công thức này dư mấy em AND hay sao í
Thân

Đúng vậy, đây là bài toán có những khoảng liên tục. Ví vậy chỉ cần lọt ra khoảng này là vào khoảng kế tiếp, không cần xác định giới hạn đầu.

 

[mhung12005]

Hình như công thức này dư mấy em AND hay sao í
Thân

Đúng là do sơ xuất, chỉ nghĩ sửa công thức của chủ Topic, nên em không để ý bác ạ. Lẽ ra chỉ cần thế này thôi:

=IF(V12>100,"Quá tải",IF(V12>=80,"Đầy tải",IF(V12>=50,"Vừa tải","Non tải")))

 

[hngiatuong]

công thức này dư mấy em AND hay sao í
Thân

Mình thấy đúng đấy chứ.
Tô màu thì đây, xem có đúng ko?

 

[Let'GâuGâu]

Các anh/chị xem dùm em cách dùng hàm if bên cột "Ghi chú" của em có vấn đề gì không sao nó lại chỉ hiển thị được 2 kết quả mà sai ben bét hết. Em xin cám ơn

góp thêm một cthức cho có tụ.....ihihiih

Z12=LOOKUP(V12,{0,50,80,100},{"Non Tải","Vừa Tải","Đầy Tải","Quá Tải"})

 

[VetMini]

Hình như loại bài toán này dùng choose và match trông đẹp mắt hơn. (hoặc index/match, lookup gì đó)

=CHOOSE(MATCH(V12,{0,50,80,100},1),"non","vua","day","qua")

Bàn chơi cho vui thôi, chứ chưa xem kỹ. Vả lại "đẹp mắt" là vấn đề đầy tính cách chủ quan!

 

[tohongdieu]

Cảm ơn mọi người. Định dạng màu mình làm được rồi, rất đơn giản.

 

[tohongdieu]

Bạn letgaugau với Vietmini có thể giải thích hộ mình 2 cách sử dụng hàm trên ý nghĩa như thế nào không vậy?

 

[tohongdieu]

Nếu điều kiện của em có thêm: nếu V12=0,"Chưa đo" thì làm sao

 

[hngiatuong]

Nếu điều kiện của em có thêm: nếu V12=0,"Chưa đo" thì làm sao

Thì thế này:
=IF(V13>100,"Quá tải",IF(AND(V13>=80,V13<=100),"Đầy tải",IF(AND(V13>=50,V13<80),"Vừa tải",IF(AND(V13>=1,V13<50),"Non tải","Chưa đo"))))

 

[Let'GâuGâu]

Nếu điều kiện của em có thêm: nếu V12=0,"Chưa đo" thì làm sao

thì bạn thêm bẫy lổi vào

if(v12="","",bạn thích hàm nào thì cho vô đây)

 

[VetMini]

Bạn letgaugau với Vietmini có thể giải thích hộ mình 2 cách sử dụng hàm trên ý nghĩa như thế nào không vậy?

=CHOOSE(MATCH(V12,{0,50,80,100},1),"non","vua","day","qua")

MATCH(V12,{0,50,80,100},1)
Phần này xét vị trí của V12 trong mảng [0, 50, 80, 100], con số 1 đứng sau cùng có nghĩa là: nếu không gặp đúng số ấy thì tụ về số nhỏ hơn nó và gần nó nhất. Như vây các trị lớn hơn 100 (và kể cả 100) sẽ tụ về 100, tức là vị trí thứ 4. Tương tự, các trị nhỏ hơn 100, nhưng lớn hơn 80 sẽ tụ về 80, tức là vị trí thứ 3.
=CHOOSE(SốGìĐó,"non","vua","day","qua")
Phần này dùng trị của SốGìĐó để chọn một trong danh sách đi kế tiếp SốGìĐó; tức là "non","vừa","đầy", hay "quá"
Như vậy nếu V12 là 110 thì hàm match ở trên cho ra 4, và hàm choose sẽ dùng 4 để chọn được "quá"

Hàm LOOKUP cũng đại khái theo nguyên tắc như vậy

Nếu điều kiện của em có thêm: nếu V12=0,"Chưa đo" thì làm sao

Nhét thêm một trị rất nhỏ, gần 0, để cho những trị <50 tụ hội về đó, và riêng 0 thì có chỗ của nó.

=CHOOSE(MATCH(V12,{0,0.001,50,80,100},1),"chưa đo","non","vừa","đầy","quá")

Nếu dùng LOOKUP thì cũng tương tự vậy

 

[tohongdieu]

Thì thế này:
=IF(V13>100,"Quá tải",IF(AND(V13>=80,V13<=100),"Đầy tải",IF(AND(V13>=50,V13<80),"Vừa tải",IF(AND(V13>=1,V13<50),"Non tải","Chưa đo"))))

Cảm ơn bạn. Cái này mình biết rồi, mình đang hỏi bạn dùng hàm choose(match(....)) kia.

 

[tohongdieu]

=CHOOSE(MATCH(V12,{0,50,80,100},1),"non","vua","day","qua")

MATCH(V12,{0,50,80,100},1)
Phần này xét vị trí của V12 trong mảng [0, 50, 80, 100], con số 1 đứng sau cùng có nghĩa là: nếu không gặp đúng số ấy thì tụ về số nhỏ hơn nó và gần nó nhất. Như vây các trị lớn hơn 100 (và kể cả 100) sẽ tụ về 100, tức là vị trí thứ 4. Tương tự, các trị nhỏ hơn 100, nhưng lớn hơn 80 sẽ tụ về 80, tức là vị trí thứ 3.
=CHOOSE(SốGìĐó,"non","vua","day","qua")
Phần này dùng trị của SốGìĐó để chọn một trong danh sách đi kế tiếp SốGìĐó; tức là "non","vừa","đầy", hay "quá"
Như vậy nếu V12 là 110 thì hàm match ở trên cho ra 4, và hàm choose sẽ dùng 4 để chọn được "quá"

Hàm LOOKUP cũng đại khái theo nguyên tắc như vậy



Nhét thêm một trị rất nhỏ, gần 0, để cho những trị <50 tụ hội về đó, và riêng 0 thì có chỗ của nó.

=CHOOSE(MATCH(V12,{0,0.001,50,80,100},1),"chưa đo","non","vừa","đầy","quá")

Nếu dùng LOOKUP thì cũng tương tự vậy

Cám ơn bạn VietMini rất nhiều. Rất rõ ràng và dễ hiểu.