hàm vlookup nhiều điều kiện

[queluatb]

em có tài liệu đính kèm xin nhờ mọi nguời giúp đỡ, em muốn lấy số dư đầu kỳ của mã vật tư theo từng phân xưởng mà không biết sử dụng công thức như thế nào cả, em đã thử dùng hàm vlookup nhưng chỉ cho phép dùng cho 1 phân xưởng khi có sự thay đổi phân xưởng thì không được
xin moi người giúp đỡ

 

[nghiaphuc]

em có tài liệu đính kèm xin nhờ mọi nguời giúp đỡ, em muốn lấy số dư đầu kỳ của mã vật tư theo từng phân xưởng mà không biết sử dụng công thức như thế nào cả, em đã thử dùng hàm vlookup nhưng chỉ cho phép dùng cho 1 phân xưởng khi có sự thay đổi phân xưởng thì không được
xin moi người giúp đỡ

1. Tạo 2 name động:

MaPX=OFFSET(DMKH!$D$5,,,COUNTA(DMKH!$D:$D)-1)
MaVT=OFFSET('Ton DK'!$B$2,,,COUNTA('Ton DK'!$B:$B)-1)

2. Lấy name MaPX để tạo Validation list cho ô C3 trên sheet BCPX (chọn Mã phân xưởng) cho thuận tiện.
3. Sử dụng công thức sau chô ô C7 trên sheet BCPX và fill cho phần còn lại:

=OFFSET('Ton DK'!$E$1,MATCH(A7,MaVT,0),MATCH($C$3,MaPX,0))

 

[khunglongcodon]

Bạn nên tạo thêm 1 dòng phụ chứa mã phân xưởng thì dễ dàng xử lý hơn.
Bạn xem cách làm của mình nhé.

 

[queluatb]

tính tồn đầu kỳ điều kiện theo ngày tháng

1. Tạo 2 name động:

MaPX=OFFSET(DMKH!$D$5,,,COUNTA(DMKH!$D:$D)-1)
MaVT=OFFSET('Ton DK'!$B$2,,,COUNTA('Ton DK'!$B:$B)-1)

2. Lấy name MaPX để tạo Validation list cho ô C3 trên sheet BCPX (chọn Mã phân xưởng) cho thuận tiện.
3. Sử dụng công thức sau chô ô C7 trên sheet BCPX và fill cho phần còn lại:

=OFFSET('Ton DK'!$E$1,MATCH(A7,MaVT,0),MATCH($C$3,MaPX,0))

giúp cho em cách tính số dư đầu kỳ phụ thuộc ngày tháng đầu kỳ, ngày tháng phát sinh trong kỳ, ngày tháng phát sinh lập biểu

 

[nghiaphuc]

giúp cho em cách tính số dư đầu kỳ phụ thuộc ngày tháng đầu kỳ, ngày tháng phát sinh trong kỳ, ngày tháng phát sinh lập biểu

Cách giải quyết hơi phức tạp một chút:
1. Tạo thêm các name:

Ngay=OFFSET(PSNX!$A$6,,,COUNT(PSNX!$A:$A))
PXNX=OFFSET(Ngay,,1)
VTNX=OFFSET(Ngay,,3)
Nhap=OFFSET(Ngay,,6)
Xuat=OFFSET(Ngay,,7)

2. Fill đầy đủ Mã phân xưởng tại cột B, sheet PSNX.
3. Lập công thức cho hàng 8 trên sheet BCPX và fill cho các hàng còn lại:

C8=OFFSET('Ton DK'!$E$2,MATCH(A8,MaVT,0),MATCH($C$3,MaPX,0))+SUMPRODUCT((Ngay<$C$5)*(PXNX=$C$3)*(VTNX=A8)*Nhap)-SUMPRODUCT((Ngay<$C$5)*(PXNX=$C$3)*(VTNX=A8)*Xuat)
D8=SUMPRODUCT((Ngay>=$C$5)*(Ngay<=$C$6)*(PXNX=$C$3)*(VTNX=A8)*Nhap)
E8=SUMPRODUCT((Ngay>=$C$5)*(Ngay<=$C$6)*(PXNX=$C$3)*(VTNX=A8)*Xuat)
F8=C8+D8-E8