Hàm tìm 5 giá trị liên tiếp thỏa một điều kiên

[hitokiri239]

Anh/chị giúp thể chỉ hàm tìm ra khách hàng không trả tiền liên tiếp trong 5 kỳ liên tiếp(Period) như trong file đính kèm được không ạ. Cảm ơn anh/chị ạ

 

[HieuCD]

Anh/chị giúp thể chỉ hàm tìm ra khách hàng không trả tiền liên tiếp trong 5 kỳ liên tiếp(Period) như trong file đính kèm được không ạ. Cảm ơn anh/chị ạ

 O3 =IF(ISNA(MATCH("00000",INDEX(A3:J3&B3:K3&C3:L3&D3:M3&E3:N3,0),0)),"","Nợ dây dưa")

 

[ndu96081631]

Anh/chị giúp thể chỉ hàm tìm ra khách hàng không trả tiền liên tiếp trong 5 kỳ liên tiếp(Period) như trong file đính kèm được không ạ. Cảm ơn anh/chị ạ

Gõ công thức này vào O3:

=COUNT(1/(SUBTOTAL(9,OFFSET(E3:I3,,COLUMN($A1:$E1)))=0))

Bấm Ctrl + Shift + Enter để kết thúc
Ô nào cho kết quả = 1 là hàng đó có nợ 5 kỳ liên tiếp

 

[eke_rula]

Anh/chị giúp thể chỉ hàm tìm ra khách hàng không trả tiền liên tiếp trong 5 kỳ liên tiếp(Period) như trong file đính kèm được không ạ. Cảm ơn anh/chị ạ

Bạn dùng CT mảng này thử xem:

O3=IF(OR(SUMIF(OFFSET(D3,,ROW($1:$6),,5),"<>")=0),"No day dua","")

Ctrl+Shift+Enter rồi fill xuống!!!

 

[bebo021999]

Dùng hàm này để tìm số tháng liên tiếp =0 nhiều nhất, sau đó tùy quyết định nhé:

=MAX(FREQUENCY(COLUMN(E3:N3)-COLUMNS(E3)+1,IF(E3:N3>0,COLUMN(E3:N3),"")))-1

Ctrl-shift-enter

 

[eke_rula]

---------------------------------------------------------

 

[quocgiacan]

Công thức này không đúng với trường hợp =0 5 giai đoạn cuối, bài này dùng FREQUENCY không phù hợp lắm vì phải tạo ra 1 cột cuối và phải >0!!

Vậy nếu dùng FREQUENCY() như vầy thì sao em?

P3=COUNT(1/(FREQUENCY(ROW($1:$11),TRANSPOSE((E3:O3>0)*1)*ROW($1:$11))>=6))

Ctrl+Shift+Enter.

Có tội nó hơi "dzài", nên ngậm bồ hòn vậy. khà khà khà

 

[eke_rula]

Dùng hàm này để tìm số tháng liên tiếp =0 nhiều nhất, sau đó tùy quyết định nhé:

=MAX(FREQUENCY(COLUMN(E3:N3)-COLUMNS(E3)+1,IF(E3:N3>0,COLUMN(E3:N3),"")))-1

Ctrl-shift-enter

CT này không đúng với trường hợp =0 5 giai đoạn cuối, dùng FREQUENCY phải kéo dư 1 cột, trong bài này thì cột cuối phải <>0!!!

 

[eke_rula]

-----------------------------------------

 

[Phuocam]

Anh/chị giúp thể chỉ hàm tìm ra khách hàng không trả tiền liên tiếp trong 5 kỳ liên tiếp(Period)

Bạn có thể dùng hàm COUNTIFS.

 

[hitokiri239]

Đây mới là 9 kỳ. Giả sử em cần dò trong 36 kỳ thì s ạ. Anh có thể giải thích giúp em cụ thể cách làm hàm này được không ạ

Gõ công thức này vào O3:

=COUNT(1/(SUBTOTAL(9,OFFSET(E3:I3,,COLUMN($A1:$E1)))=0))

Bấm Ctrl + Shift + Enter để kết thúc
Ô nào cho kết quả = 1 là hàng đó có nợ 5 kỳ liên tiếp

 

[hitokiri239]

Nếu em muốn dò trong 36 kỳ thì sao ạ. Em sẽ thay công thức ntn ạ

 O3 =IF(ISNA(MATCH("00000",INDEX(A3:J3&B3:K3&C3:L3&D3:M3&E3:N3,0),0)),"","Nợ dây dưa")

 

[HieuCD]

Nếu em muốn dò trong 36 kỳ thì sao ạ. Em sẽ thay công thức ntn ạ

trong công thức , thay J3,K3,L3,M3 VÀ N3 BẰNG CỘT TƯƠNG ỨNG

 

[hitokiri239]

Quy luật thay J3,K3,L3,M3 VÀ N3 là gì ạ. Có phải là thay bằng các colum cuối cùng từ bên phải qua không ạ

trong công thức , thay J3,K3,L3,M3 VÀ N3 BẰNG CỘT TƯƠNG ỨNG

 

[Gió Đông]

Dùng thử công thức này cho O3

=IF(MAX(INDEX(COUNTIF(OFFSET(F3:J3,,COLUMN(A3:E3)-1),0),0))=5,"Nợ >=5 kỳ","")

Trường hợp tăng lên 36 kỳ thì chỉ thay
A3:E3
thành
A3:AF3
Vì
A3:E3 là 5 cột = 9 (số periods)-5 +1
khi tăng lên 36 periods thì cần 36-5+1=32 ==> chính là A3:AF3

nên công thức trên thành

=IF(MAX(INDEX(COUNTIF(OFFSET(F3:J3,,COLUMN(A3:AF3)-1),0),0))=5,"Nợ >=5 kỳ","")

 

[HieuCD]

Quy luật thay J3,K3,L3,M3 VÀ N3 là gì ạ. Có phải là thay bằng các colum cuối cùng từ bên phải qua không ạ

N3 là cột cuối các ô trước tính lùi dần lại

 

[hitokiri239]

CHo em hỏi thêm làm thế nào insert cột vào nó sẽ tự nhảy giá trị của hàm ạ

N3 là cột cuối các ô trước tính lùi dần lại

 

[HieuCD]

CHo em hỏi thêm làm thế nào insert cột vào nó sẽ tự nhảy giá trị của hàm ạ

trường hợp nầy khó thực hiện

 

[hitokiri239]

Vậy là phải chỉnh bằng tay đúng ko anh

trường hợp nầy khó thực hiện

 

[HieuCD]

Vậy là phải chỉnh bằng tay đúng ko anh

bạn chọn lần đầu đúng 5 cột cuối cùng và insert, lần 2 có thể là 5 hoặc tăng lên 6... hoặc 5*2 cột và insert, các lần sau làm tương tự nhưng nhớ tối thiểu là 5 cột cuối, nói chung rất dể nhầm, nếu công thức chưa như ý thì chỉnh tay lại