Hàm IF trong excel (1 người xem)

Excel365 · 16/10/12

Em có hàm như thế này mong các anh chị giúp em.
Nếu >0 đến 1 thì lấy 300.000
Nếu > 1 đến 3 thì lấy 500.000
Nếu > 3 đến 5 thì lấy 700.000
Nếu > 5 đến 7 thì lấy 900.000
Nếu > 7 đến 9 thì lấy 1.100.000
Nếu > 9 đến 11 thì lấy 1.300.000
Nếu > 11 đến 15 thì lấy 1.600.000
Nếu > 15 đến 19 thì lấy 2.000.000
Nếu > 19 thì lấy 2.200.000.
Nhờ các anh chị giúp em. Thank!>

hungpecc1 · 16/10/12

cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^

ndu96081631 · 16/10/12

hungpecc1 đã viết:
cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^

Nếu làm được theo kiểu cu nhu vay cho den het thì bạn hãy làm thử vào 1 file Excel rồi đưa lên đây cho tôi học hỏi với

vanle33 · 16/10/12

hungpecc1 đã viết:
cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^

If lồng được 7 điều kiện phải không các bạn?
Ở đây bạn huu duy cần 9 điều kiện mà

dongducnhiem · 16/10/12

huuduy.duy đã viết:
Em có hàm như thế này mong các anh chị giúp em.
Nếu >0 đến 1 thì lấy 300.000
Nếu > 1 đến 3 thì lấy 500.000
Nếu > 3 đến 5 thì lấy 700.000
Nếu > 5 đến 7 thì lấy 900.000
Nếu > 7 đến 9 thì lấy 1.100.000
Nếu > 9 đến 11 thì lấy 1.100.000
Nếu > 11 đến 15 thì lấy 1.600.000
Nếu > 15 đến 19 thì lấy 2.000.000
Nếu > 19 thì lấy 2.200.000.
Nhờ các anh chị giúp em. Thank!>

1/ ĐK của bạn:
Nếu > 7 đến 9 thì lấy 1.100.000
Nếu > 9 đến 11 thì lấy 1.100.000
hai thằng này trùng nhau nên tôi sửa lại Nếu > 9 đến 11 thì lấy 1.300.000
2/ Chỉ có Excel 2003 chỉ cho 7 điều kiện IF
3/ Nếu muốn dùng hàm IF tôi làm cthức này cho Excel 2007-2010

PHP:

=IF(A1<=0;0;IF(AND(A1>0;A1<=1);300000;IF(AND(A1>1;A1<=3);500000;IF(AND(A1>3;A1<=5);700000;IF(AND(A1>5;A1<=7);900000;IF(AND(A1>7;A1<=9);1100000;IF(AND(A1>9;A1<=11);1300000;IF(AND(A1>11;A1<=15);1600000;IF(AND(A1>15;A1<=19);2000000;2200000)))))))))

Với A1 là cell điều kiện

nhat chi mai · 16/10/12

dongducnhiem Bác gửi kèm luôn file đi, em xem với.thanks

ndu96081631 · 16/10/12

dongducnhiem đã viết:
1/ ĐK của bạn:
Nếu > 7 đến 9 thì lấy 1.100.000
Nếu > 9 đến 11 thì lấy 1.100.000
hai thằng này trùng nhau nên tôi sửa lại Nếu > 9 đến 11 thì lấy 1.300.000
2/ Chỉ có Excel 2003 chỉ cho 7 điều kiện IF
3/ Nếu muốn dùng hàm IF tôi làm cthức này cho Excel 2007-2010

PHP:

=IF(A1<=0;0;IF(AND(A1>0;A1<=1);300000;IF(AND(A1>1;A1<=3);500000;IF(AND(A1>3;A1<=5);700000;IF(AND(A1>5;A1<=7);900000;IF(AND(A1>7;A1<=9);1100000;IF(AND(A1>9;A1<=11);1300000;IF(AND(A1>11;A1<=15);1600000;IF(AND(A1>15;A1<=19);2000000;2200000)))))))))

Với A1 là cell điều kiện

Hàm IF có tính loại trừ, vậy đâu cần phải AND chi cho cực:

Mã:

=IF(A1<=0,0,IF(A1<=1,300000,IF(A1<=3,500000,IF(A1<=5,700000,IF(A1<=7,900000,IF(A1<=9,1100000,IF(A1<=11,1300000,IF(A1<=15,1600000,IF(A1<=19,2000000,2200000)))))))))

dongducnhiem · 16/10/12

nguyencanh160890 đã viết:
dongducnhiem Bác gửi kèm luôn file đi, em xem với.thanks

Bạn xem File....................

nhat chi mai · 16/10/12

Cảm ơn BÁC dongducnhiem nhiều nhé, 9 hàm IF và 8 hàm AND.... !$@!!

em cũng thử nhưng thực sự trình chưa tới có cố cũng về zezo $-\\/.$

dongducnhiem · 16/10/12

ndu96081631 đã viết:
Hàm IF có tính loại trừ, vậy đâu cần phải AND chi cho cực:

Mã:

=IF(A1<=0,0,IF(A1<=1,300000,IF(A1<=3,500000,IF(A1<=5,700000,IF(A1<=7,900000,IF(A1<=9,1100000,IF(A1<=11,1300000,IF(A1<=15,1600000,IF(A1<=19,2000000,2200000)))))))))

Anh cho tôi hỏi, ngoài cách dùng hàm IF, còn cách nào dùng hàm khác nũa kg?
Trước đây hình như tôi có đọc một bài dạng tư tự, hình như dùng VLOOKUP thì fải!
Cảm ơn!

bebo021999 · 16/10/12

Không phải VLOOKUP mà là LOOKUP.
Tận dụng tính chất tìm kiếm gần đúng của hàm LOOKUP cho dãy số tăng (giảm) dần
Nếu ô A1 chứa điều kiện:

Mã:

=LOOKUP(A1,{0,1,3,5,7,9,11,15,19}+0.1,{3,5,7,9,11,13,16,20,22}*100000)

Lưu ý rút thừa số chung ra ngoài (100.000) cho gọn công thức.

ndu96081631 · 16/10/12

dongducnhiem đã viết:
Anh cho tôi hỏi, ngoài cách dùng hàm IF, còn cách nào dùng hàm khác nũa kg?
Trước đây hình như tôi có đọc một bài dạng tư tự, hình như dùng VLOOKUP thì fải!
Cảm ơn!

Tôi nghĩ vầy chắc được:

Mã:

=IF(A1<=0,0,10^5*IF(A1>19,22,INDEX({20,16,13,11,9,7,5,3},,MATCH(A1,{19,15,11,9,7,5,3,1},-1))))

Excel365 · 16/10/12

Đúng là em có làm hàm If như vậy cho đến hết như mà nó báo lỗi (do nhiều hàm if quá)

Excel365 · 16/10/12

Cám ơn tất cả các anh / chị rất nhiều

hoamattroicoi · 16/10/12

dongducnhiem đã viết:
Anh cho tôi hỏi, ngoài cách dùng hàm IF, còn cách nào dùng hàm khác nũa kg?
Trước đây hình như tôi có đọc một bài dạng tư tự, hình như dùng VLOOKUP thì fải!
Cảm ơn!

Dùng Vlookup thì thế này bác ạ :

PHP:

=VLOOKUP(A1,{0,300000;1,500000;3,700000;5,900000;7,1100000;9,1300000;11,1600000;15,2000000;19,2200000},2)

ndu96081631 · 16/10/12

hoamattroicoi đã viết:
Dùng Vlookup thì thế này bác ạ :

PHP:

=VLOOKUP(A1,{0,300000;1,500000;3,700000;5,900000;7,1100000;9,1300000;11,1600000;15,2000000;19,2200000},2)

Xem lại, công thức này sai à nghen ---> Nếu A1 = 1 thì kết quả = 300000 chứ không phải 500000 đâu

hoamattroicoi · 16/10/12

ndu96081631 đã viết:
Xem lại, công thức này sai à nghen ---> Nếu A1 = 1 thì kết quả = 300000 chứ không phải 500000 đâu

Hix, em không để ý cái chỗ "ĐẾN" mà tác giả viết.
Nếu vẫn muốn dùng Vlookup thì phải tịnh tiến giá trị dò tìm trong bang tham chiếu lên nhưng như thế thì cũng quá tội.

bebo021999 · 16/10/12

hoamattroicoi đã viết:
Hix, em không để ý cái chỗ "ĐẾN" mà tác giả viết.
Nếu vẫn muốn dùng Vlookup chắc vẫn phải tịnh tiến giá trị dò tìm trong bang tham chiếu lên nhưng như thế thì cũng quá tội.

Đơn giản là cộng thêm 1 sai số (<1) vào lookup range thôi: 1.1; 3.1; ....
Nhưng làm LOOKUP là chuẩn, ngắn gọn (có thể rút gọn thừa số) và dễ hiểu nhất

hoamattroicoi · 16/10/12

bebo021999 đã viết:
Đơn giản là cộng thêm 1 sai số (<1) vào lookup range thôi: 1.1; 3.1; ....
Nhưng làm LOOKUP là chuẩn, ngắn gọn (có thể rút gọn thừa số) và dễ hiểu nhất

Ý em đang nói là bắt buộc phải dùng Vlookup cũng có thể tịnh tiến được giá trị dò tìm trong bảng tham chiếu đó.
Còn cái vụ dùng Lookup dễ hiểu hơn Vlookup thì chưa chắc đâu anh ạ. Có thể chỉ là dễ hiểu nhất với anh thôi, không phải đại đa số. hiiiiiiiiii

bebo021999 · 16/10/12

hoamattroicoi đã viết:
Ý em đang nói là bắt buộc phải dùng Vlookup cũng có thể tịnh tiến được giá trị dò tìm trong bảng tham chiếu đó.
Còn cái vụ dùng Lookup dễ hiểu hơn Vlookup thì chưa chắc đâu anh ạ. Có thể chỉ là dễ hiểu nhất với anh thôi, không phải đại đa số. hiiiiiiiiii

Đúng là VLOOKUP thân thiện và quen thuộc với đại đa số người dùng. Nhưng trường hợp này Range không phải là một vùng cụ thể trên bảng tính, đưa vào VLOOKUP quả là khối người ... tẩu hỏa nhập ma.
Ặc ặc...

ndu96081631 · 16/10/12

bebo021999 đã viết:
Đơn giản là cộng thêm 1 sai số (<1) vào lookup range thôi: 1.1; 3.1; ....
Nhưng làm LOOKUP là chuẩn, ngắn gọn (có thể rút gọn thừa số) và dễ hiểu nhất

MATCH với kiểu dò -1 mới là chuẩn nhất
Ai mà biết trị dò có phải luôn là số nguyên hay không? Và nếu trị dò là số lẻ thì cũng chẳng biết nó lẻ đến mức nào để mà cộng thêm cho đúng
Nếu A1= 1.0001 thì tính sao đây?
Ẹc... Ẹc...

bebo021999 · 16/10/12

ndu96081631 đã viết:
MATCH với kiểu dò -1 mới là chuẩn nhất
Ai mà biết trị dò có phải luôn là số nguyên hay không? Và nếu trị dò là số lẻ thì cũng chẳng biết nó lẻ đến mức nào để mà cộng thêm cho đúng
Nếu A1= 1.0001 thì tính sao đây?
Ẹc... Ẹc...

Hic, đúng là như thế. Nhưng đời cũng có lúc phải bỏ qua những "chuẩn mực gò bó phi thực tế" chứ nhỉ sư phụ? Hay là A1=1+10^-10 cho chắc ăn?
Ặc ... ặc...

ndu96081631 · 16/10/12

bebo021999 đã viết:
Hic, đúng là như thế. Nhưng đời cũng có lúc phải bỏ qua những "chuẩn mực gò bó phi thực tế" chứ nhỉ sư phụ? Hay là A1=1+10^-10 cho chắc ăn?
Ặc ... ặc...

Uh.. thì thà là vậy đi cho chắc!
Tôi đang nghĩ: Tại sao LOOKUP không có chiêu dò tìm giống MATCH nhỉ? Tức dò trên bảng sắp xếp giảm dần ---> Nếu được vậy thì đúng là HỔ MỌC THÊM CÁNH
Ẹc... Ẹc...

tan10ckn · 16/10/12

bebo021999 đã viết:
Đơn giản là cộng thêm 1 sai số (<1) vào lookup range thôi: 1.1; 3.1; ....
Nhưng làm LOOKUP là chuẩn, ngắn gọn (có thể rút gọn thừa số) và dễ hiểu nhất

Em thấy hàm vlookup đơn giản hơn(vì em chưa học hàm lookup ^^), nhưng đó là trường hợp trị dò là số nguyên, nếu lẻ thì em bó tay

Với lại e nhớ có 1 lần xem bài giảng trên mạng là excel chỉ cho 8 hàm if trong 1 cell, 2003 và 2007 đều vậy phải không các anh chị?

bebo021999 · 16/10/12

ndu96081631 đã viết:
Uh.. thì thà là vậy đi cho chắc!
Tôi đang nghĩ: Tại sao LOOKUP không có chiêu dò tìm giống MATCH nhỉ? Tức dò trên bảng sắp xếp giảm dần ---> Nếu được vậy thì đúng là HỔ MỌC THÊM CÁNH
Ẹc... Ẹc...

Không cho thì mình chế thêm: LOOKUP(N-A1, N-RANGE1, RANGE2)
Với N đủ lớn hơn các phần tử của RANGE, đảo lại thành tăng dần.
Ặc...Ặc...

hoamattroicoi · 16/10/12

bebo021999 đã viết:
Đúng là VLOOKUP thân thiện và quen thuộc với đại đa số người dùng. Nhưng trường hợp này Range không phải là một vùng cụ thể trên bảng tính, đưa vào VLOOKUP quả là khối người ... tẩu hỏa nhập ma.
Ặc ặc...

Thế chắc cái chỗ tạo mảng trong công thức đó cô giáo trong trường không dạy, hihi!

Với lại e nhớ có 1 lần xem bài giảng trên mạng là excel chỉ cho 8 hàm if trong 1 cell, 2003 và 2007 đều vậy phải không các anh chị?

Excel 2007 cho phép tồn tại 64 hàm IF trong công thức bạn ạ!

ndu96081631 · 16/10/12

bebo021999 đã viết:
Không cho thì mình chế thêm: LOOKUP(N-A1, N-RANGE1, RANGE2)
Với N đủ lớn hơn các phần tử của RANGE, đảo lại thành tăng dần.
Ặc...Ặc...

Nghĩ lại thấy mình.. ngu thật ---> Giới hạn cận trên, cận dưới theo kiểu gì cũng LOOKUP được tuốt. Nếu dùng LOOKUP(2, 1/(....)...) thì cũng cóc cần phải cộng trừ thêm bớt gì luôn
Ví dụ

PHP:

=LOOKUP(2,1/({0,1,3,5,7,9,11,15,19}<A1),{3,5,7,9,11,13,16,20,22}*10^5)

Hoặc cẩn thận hơn:

PHP:

=IF(A1<=0,0,LOOKUP(2,1/({0,1,3,5,7,9,11,15,19}<A1),{3,5,7,9,11,13,16,20,22}*10^5))

Ẹc... Ẹc...

nhockon0689 · 21/11/12

Mình đang dùng 2003 ở đây anh em viết cho 2007 nên chưa gặm được +-+-+-+

.

hoamattroicoi · 21/11/12

nhockon0689 đã viết:
Mình đang dùng 2003 ở đây anh em viết cho 2007 nên chưa gặm được .

Excel 2003 "gặm" tốt bạn ạ, bạn đã cho nó "gặm" thử chưa mà kêu um thế???

HoaHuongDuong113_kt · 27/1/13

Cho em hoi , cai cong thuc dung ham If lai co ky hieu : '''', dể lam gi em khong hieu, cu the la trong bang xuat kho de tinh gia von và thanh tien nghia la sao ah

HoaHuongDuong113_kt · 27/1/13

=IF($F8="","",VLOOKUP(F8,'BCNXT 156'!$A$8:$H$32,8,0)), ky hieu " la sao

vanle33 · 27/1/13

HoaHuongDuong113_kt đã viết:
=IF($F8="","",VLOOKUP(F8,'BCNXT 156'!$A$8:$H$32,8,0)), ky hieu " la sao

"" nghĩa là để trống đó bạn
hoặc giữa 2 dấu " là text đó bạn
Theo mình biết là dấu " có chức năng đó.

macaopark · 13/4/13

dongducnhiem đã viết:
Bạn xem File....................

bác cho em hỏi.
>2.35 đến 2.65 thì lấy 0 rồi từ 0 lấy ra kq 1 bên là 1.86
>2 đến 2.35 thi lay 0.25 rồi từ 0.25 lấy ra kq 1 bên là 2
>1.53 đến 2 thi lấy 0.5 rồi từ 0.5 lấy ra kq 1 bên là 2.03

vst1986 · 13/4/13

huuduy.duy đã viết:
Em có hàm như thế này mong các anh chị giúp em.
Nếu >0 đến 1 thì lấy 300.000
Nếu > 1 đến 3 thì lấy 500.000
Nếu > 3 đến 5 thì lấy 700.000
Nếu > 5 đến 7 thì lấy 900.000
Nếu > 7 đến 9 thì lấy 1.100.000
Nếu > 9 đến 11 thì lấy 1.300.000
Nếu > 11 đến 15 thì lấy 1.600.000
Nếu > 15 đến 19 thì lấy 2.000.000
Nếu > 19 thì lấy 2.200.000.
Nhờ các anh chị giúp em. Thank!>

Cho ô A1 là ô chứa giá trị ta có thể viết theo cách sau:

=IF(A1<=0,"",IF(A1<=1,"300.000",IF(A1<=3,"500.000",IF(A1<=5,"700.000",IF(A1<=7,"900.000",IF(A1<=9,"1.100.000",IF(A1<=15,"1.600.000","")))))))&IF(AND(A1>15,A1<=19),"2.000.000",IF(A1>19,"2.200.000",""))

Nếu sau khi lồng hàm IF 7 lần rồi trả về giá trị "" (NULL) rồi & thêm các hàm IF lồng nữa thì bạn sẽ sử dụng được với nhiều điều kiện hơn nữa.Sau mỗi dấu & sẽ là các hàm IF lồng.

thienkimtieuthu · 15/4/13

ndu96081631 đã viết:
Nếu làm được theo kiểu cu nhu vay cho den het thì bạn hãy làm thử vào 1 file Excel rồi đưa lên đây cho tôi học hỏi với

Mình làm theo yêu cầu của bạn , bạn xem đúng y/c ko nhé.
Chúc bạn thành công !

nhat chi mai · 15/4/13

thienkimtieuthu đã viết:
Mình làm theo yêu cầu của bạn , bạn xem đúng y/c ko nhé.
Chúc bạn thành công !

ý Thầy ndu trả lời là câu này bạn nhé, hiiiiiiiiii, bạn có vẻ như đang trả lời nhầm gì đó hen

Nguyên văn bởi hungpecc1

cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^
Nếu làm được theo kiểu cu nhu vay cho den het thì bạn hãy làm thử vào 1 file Excel rồi đưa lên đây cho tôi học hỏi với.

Good-Luck · 15/4/13

NHẤT CHI MAI đã viết:
ý Thầy ndu trả lời là câu này bạn nhé, hiiiiiiiiii, bạn có vẻ như đang trả lời nhầm gì đó hen

Nguyên văn bởi hungpecc1
cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^
Nếu làm được theo kiểu cu nhu vay cho den het thì bạn hãy làm thử vào 1 file Excel rồi đưa lên đây cho tôi học hỏi với.

Cô này thăng cấp rồi, nói năng cũng.....
nếu nhiều vấn đề quá thì dùng hàm dò đi, thiết lập cái bảng các điều kiện, sau dó dùng hàm dò truy xuất dự liệu

hngiatuong · 15/4/13

.. .

thienkimtieuthu · 16/4/13

NHẤT CHI MAI đã viết:
ý Thầy ndu trả lời là câu này bạn nhé, hiiiiiiiiii, bạn có vẻ như đang trả lời nhầm gì đó hen

Nguyên văn bởi hungpecc1
cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^
Nếu làm được theo kiểu cu nhu vay cho den het thì bạn hãy làm thử vào 1 file Excel rồi đưa lên đây cho tôi học hỏi với.

ý này nghĩa là sao nhỉ mình thấy bài của mình cũng phù hợp yêu cầu của bạn đó mà !

minhhhuanth · 16/4/13

=if(A10>19,2200000,if(A10>15,2000000,if(A10>11,1600000....................................,if(A10>0,300000,0))))))))))))...
nhớ đóng cho đủ dấu ngoặc nha !

nhocdaudat · 14/5/13

các bác cho e hỏi chút
e có cột Á là ngày/tháng/năm vay, cột B1 là ngày/tháng/năm phải trả lãi (đã gõ công thức để cộng thêm 3 tháng), cột C1 là ngày/tháng/năm thực tế KH trả lãi. Nay e muốn các bác giúp e công thức để nếu ngày thực tế trả mà lớn hơn ngày phải trả thì xếp loại B, mà nhỏ hơn thì xếp loại A.
Hoặc các bác có cách nào nhanh hơn nữa không có nghĩa là e muốn phân loại KH nếu khách hàng đó trả lãi trước 3 tháng là loại A sau đó là loại B.

leonguyenz · 14/5/13

Công thức tại cột D là lấy cột C trừ cột B:
=if(c1<=b1,"A","B")

bebo021999 · 14/5/13

Tính trực tiếp luôn: A1 là ngày vay, C1 là ngày trả:
=IF(C1<=EDATE(A1,3),"A","B")

duongnhi8812 · 11/6/13

đúng rồi. bạn dongducnhiem tính như vậy là đúng mà lại dễ và nhanh hơn
Thanks nhìu nhé! /-*+/

phudentist · 14/7/13

bác nào giải pháp giúp em cái hàm này đau dầu quá:
nếu A1= CB thì là 200, nếu A1= AD thì =300 , nếu A1= Ac thì bằng 400 ....
trong đó ô A1 mình chỉ nhập dạng text CB hoặc AD, AC. Viết hàm cho cái ô đang chọn bằng cách nào ai biết giúp với !

Cám ơn nhiều

thanhsangnguyen1982 · 15/7/13

Dùng hàm if nha bạn và cái chỗ .... còn bao nhiêu điều kiện nữa. Tốt nhất bạn gửi fiel của bạn lên đi

angiaminh · 20/8/13

Anh chị xem giúp em cái này nữa với ạ, điều kiện đúng mà sao nó cứ bảo "false" là sạo ạ, em cảm ơn anh chị nhiều ạ./.

leonguyenz · 21/8/13

angiaminh đã viết:
Anh chị xem giúp em cái này nữa với ạ, điều kiện đúng mà sao nó cứ bảo "false" là sạo ạ, em cảm ơn anh chị nhiều ạ./.

Công thức của bạn sai cấu trúc, bạn phải sử dụng hàm AND(logical1,logical2...)
Công thức kiểm tra tính logic của bạn chỉ cần: =AND(A1>0,A1<=10000)

nhat chi mai · 21/8/13

angiaminh đã viết:
Anh chị xem giúp em cái này nữa với ạ, điều kiện đúng mà sao nó cứ bảo "false" là sạo ạ, em cảm ơn anh chị nhiều ạ./.

Hôm qua tối định trả lời, nhưng do mất mạng hôm nay gửi lại file, lỗi của bạn là điều kiện if không đúng.

dvh.hy.9902 · 27/11/13

Trong file đính kèm mình có sử dụng công thức hàm if nhưng báo lỗi #NAME?
Rất mong được mọi người xem giúp. Rất cảm ơn mọi người!.

SA_DQ · 27/11/13

!!!!

=if(left(b6,2)= "mh", round((d6/15),1), round((e6+g6)/15+(f6/40),1))

Đình Phán · 28/11/13

dvh.hy.9902 đã viết:
Trong file đính kèm mình có sử dụng công thức hàm if nhưng báo lỗi #NAME?
Rất mong được mọi người xem giúp. Rất cảm ơn mọi người!.

Phần này của bạn chỉ gõ thiếu dấu "" của MH, thay vì để MH trong "" ("MH") thì bạn lại đang để (_MH) do đó không tìm được giá trị
=IF(LEFT(B6;2)=" MH"; ROUND((D6/15);1); ROUND((E6+G6)/15+(F6/40);1))

ChanhTQ@ · 28/11/13

thì bạn lại đang để (_MH) do đó không tìm được giá trị
=IF(LEFT(B6;2)=" MH"; ROUND((D6/15);1); ROUND((E6+G6)/15+(F6/40);1))

Nói vậy chắc chưa chính xác cho lắm!

Fải nói là:
Bạn không để chuỗi đó trong ngoặt kép, nên nó tưởng đó là vùng ô được gán tên; Nên nó đi tìm vùng có tên đó;
May mà nó không tìm ra nên báo lỗi
Nếu nó tìm ra được tên đó, chắc còn lộn xộn hơn!

dvh.hy.9902 · 28/11/13

ChanhTQ@ đã viết:
Nói vậy chắc chưa chính xác cho lắm!

Fải nói là:
Bạn không để chuỗi đó trong ngoặt kép, nên nó tưởng đó là vùng ô được gán tên; Nên nó đi tìm vùng có tên đó;
May mà nó không tìm ra nên báo lỗi
Nếu nó tìm ra được tên đó, chắc còn lộn xộn hơn!

Nói vậy chắc chưa chính xác cho lắm!

May mà nó không tìm ra nên báo lỗi

Đúng như bạn nói, mình nhập

=IF(LEFT(B6,2)= "MH", ROUND((D6/15),1), ROUND((E6+G6)/15+(F6/40),1))

vào thì lỗi không được mong các bạn xem giúp hoặc nếu có cách nào khác cũng xin chỉ giùm mình. Cảm ơn các bạn!.

dvh.hy.9902 · 28/11/13

dvh.hy.9902 đã viết:
Đúng như bạn nói, mình nhập vào thì lỗi không được mong các bạn xem giúp hoặc nếu có cách nào khác cũng xin chỉ giùm mình. Cảm ơn các bạn!.

Đã sửa được!. Cảm ơn các bạn rất nhiều

Đầu đất · 4/12/13

pass, fail, pass tôi muốn dùng hàm if để 3 trường hợp này nếu có một trường fail thì sẽ ra kết quả là fail

có ai giúp tôi với

xin gửi về địa chỉ : mail: luumaihuong85@gmail.com. nhé

cảm ơn nhiều. càng sớm càng tốt

Đầu đất · 4/12/13

[TABLE="width: 256"]
[TR]
[TD="class: xl63, width: 64"]A[/TD]
[TD="class: xl63, width: 64"]B[/TD]
[TD="class: xl63, width: 64"]C[/TD]
[TD="class: xl63, width: 64"]KET QUA[/TD]
[/TR]
[TR]
[TD="class: xl64"]PASS[/TD]
[TD="class: xl64"]FAIL [/TD]
[TD="class: xl64"]PASS [/TD]
[TD="class: xl64"]FAIL[/TD]
[/TR]
[/TABLE]

giúp mình nhe

hungpecc1 · 4/12/13

đầu đất đã viết:
pass, fail, pass tôi muốn dùng hàm if để 3 trường hợp này nếu có một trường fail thì sẽ ra kết quả là fail

có ai giúp tôi với

xin gửi về địa chỉ : mail: luumaihuong85@gmail.com. nhé

cảm ơn nhiều. càng sớm càng tốt

=IF(Or(điều kiệnh 1,điều kiện 2,...),Fail,"")

bibonht · 11/12/13

9 điều kiện, mình chưa gặp vụ này, học hỏi mới đc.

ngocpham1988 · 28/3/14

hungpecc1 đã viết:
cái này chỉ cần lồng hàm IF thôi mà
vi du :

I F ( a > 19, 2200000,I F (19>a>15, 2000,I F(15>a>11,1600,I F(.....................
cu nhu vay cho den het ^^

Cho mình hỏi, dạng hàm if lồng vào nhau như thế này mình sử dụng được bao nhiêu lần lồng ghép. Mình tiến hành cho 12 lần lồng ghép nhưng excel không cho phép, trong khi các bạn mình làm thì vẫn được. Vậy có phải do phiên bản excel của mình có vấn đề?

Nhờ các bạn giúp giùm

leonguyenz · 28/3/14

ngocpham1988 đã viết:
Cho mình hỏi, dạng hàm if lồng vào nhau như thế này mình sử dụng được bao nhiêu lần lồng ghép. Mình tiến hành cho 12 lần lồng ghép nhưng excel không cho phép, trong khi các bạn mình làm thì vẫn được. Vậy có phải do phiên bản excel của mình có vấn đề?

Nhờ các bạn giúp giùm

Excel 2003 cho phép 7 IF lồng vào nhau, còn phiên bản cao hơn cho nhiều IF lồng vào nhau hơn.
Có nhiều giải pháp thay cho IF, ví dụ dùng tham chiếu trên bảng điều kiện chẳng hạn. Nói chung là có file thì có giải pháp cụ thể hơn.

kimgiang_2008 · 21/6/14

Em không thạo về Excel, em có 1 bảng tính trong file đính kèm muốn nhờ các bác giúp đỡ lập hộ công thức, em xin trân thành cảm ơn.

leonguyenz · 21/6/14

kimgiang_2008 đã viết:
Em không thạo về Excel, em có 1 bảng tính trong file đính kèm muốn nhờ các bác giúp đỡ lập hộ công thức, em xin trân thành cảm ơn.

Nếu không có ký tự khác (ngoài a,p,v) thì bạn có thể dùng công thức sau:

Mã:

=IF(A1="",0,IF(A1="a",85*B1,IF(A1="p",B1*220,IF(B1<=6,B1*70,B1*65))))

kimgiang_2008 · 21/6/14

leonguyenz đã viết:
Nếu không có ký tự khác (ngoài a,p,v) thì bạn có thể dùng công thức sau:

Mã:

=IF(A1="",0,IF(A1="a",85*B1,IF(A1="p",B1*220,IF(B1<=6,B1*70,B1*65))))

Rât cảm ơn bác. Em loay hoay mãi cũng làm thành công nhưng không đơn giản được như của bác. Tối đây em phải học thêm Excel mới được.

Mã:

=IF(C3="a",D3*85000,IF(C3="p",D3*220000,IF(AND(C3="v",D3<=6),D3*70000,IF(AND(C3="v",D3>6),D3*65000,"0"))))

vo huu tuyen · 11/12/14

xin nhờ các bạn trên diễn đàn giúp đỡ : tôi muốn đặt hàm if với ĐK sau : = if((and(C9="NAM",D9=14)),(E9<=5'20,"T"),IF(AND(C9="NỮ",D9=14,E9<6'20,"T",Đ)
nếu là "nam " ở tuổi 14 thì ,< 5,20 là T còn <= 6,20 là Đ . còn nếu là nữ ở tuổi 14 thì : ,<6,20 thì T còn =<7,20 là Đ
có file đính kèm nên đặt công thức ở f9 như thế nào vậy ? cám ơn các bạn trước nhé.

vo huu tuyen · 11/12/14

xin lỗi các bạn do hấp tấp nên ở trên nói không rõ nay xin trình bày rõ hơn nhờ các bạn trên diễn đàn giúp đỡ : tôi muốn đặt hàm if với ĐK sau : = =IF(AND(C14="NAM",D14=14,E14<5.2),"T",IF(AND(C14="NỮ",D14=14,E14<6.2),"T","Đ")),IF(AND(C14="NAM",D14=15,E14<5.1),"T",IF(AND(C14="NỮ",D14=15,E14<6.1),"T","Đ"))
nếu là "nam " ở tuổi 14 thì ,< 5,20 là T còn <= 6,20 là Đ . còn nếu là nữ ở tuổi 14 thì : ,<6,20 thì T còn =<7,20 là Đ , CÒN là nam ở tuổi 15 thì <5.10 là T còn <= 6.20 là Đ . nữ ở tuổi 15 thì <6.10 là T còn =< 7.10 là Đ .
có file đính kèm nên đặt công thức ở f9 như thế nào vậy ? cám ơn các bạn trước nhé.

Tập tin đính kèm

omachj992 · 3/4/15

Nếu 11 điều kiện dùng ham if như thế nào. Mình sai excel 2007.chỉ tối đa 7 ham if ak

phihndhsp · 3/4/15

vo huu tuyen đã viết:
xin lỗi các bạn do hấp tấp nên ở trên nói không rõ nay xin trình bày rõ hơn nhờ các bạn trên diễn đàn giúp đỡ : tôi muốn đặt hàm if với ĐK sau : = =IF(AND(C14="NAM",D14=14,E14<5.2),"T",IF(AND(C14="NỮ",D14=14,E14<6.2),"T","Đ")),IF(AND(C14="NAM",D14=15,E14<5.1),"T",IF(AND(C14="NỮ",D14=15,E14<6.1),"T","Đ"))
nếu là "nam " ở tuổi 14 thì ,< 5,20 là T còn <= 6,20 là Đ . còn nếu là nữ ở tuổi 14 thì : ,<6,20 thì T còn =<7,20 là Đ , CÒN là nam ở tuổi 15 thì <5.10 là T còn <= 6.20 là Đ . nữ ở tuổi 15 thì <6.10 là T còn =< 7.10 là Đ .
có file đính kèm nên đặt công thức ở f9 như thế nào vậy ? cám ơn các bạn trước nhé.

Tập tin đính kèm

còn trường hợp 17 tuổi thì sao bạn?????????????????

vit nhua · 24/4/15

=if(（and(D7=2,R7<P7),if(P7-R7)>=15,=if(（and(D7=2,R7<P7),if(P7-R7)>=15,(H7-G7)*250000+(J7-I7)*200000+(L7-K7)*100000+10000*R7,if(P7-R7)<15,0,if(or(D7=1，P7>0,R7>0,if(P7-R7)>=2,(H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7,,if(P7-R7)<2,0)))),if(P7-R7)<15,0,if(or(D7=1，P7>0,R7>0,if(P7-R7)>=2,(H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7,,if(P7-R7)<2,0)))). a/c nào giúp e với ạ ?? **~**

ý e quên k nói điều kiện : Nếu D7=2 mà P7-R7 >=15, thì (H7-G7)*250000+(J7-I7)*200000+(L7-K7)*100000+10000*R7, còn P7-R7<15 thi =0,Nếu D7=1 mà P7-R7 >=2, thì (H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7, còn nếu p7-r7>2 thì 0.

n0thing1988 · 24/4/15

vit nhua đã viết:
=if(（and(D7=2,R7<P7),if(P7-R7)>=15,(H7-G7)*250000+(J7-I7)*200000+(L7-K7)*100000+10000*R7,if(P7-R7)<15,0,if(or(D7=1，P7>0,R7>0,if(P7-R7)>=2,(H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7,,if(P7-R7)<2,0)))). a/c nào giúp e với ạ ??

Của bạn bị làm sao? Mà phải giúp

leonguyenz · 24/4/15

n0thing1988 đã viết:
Của bạn bị làm sao? Mà phải giúp

Nhìn IF thứ 2 là thấy sai cấu trúc rồi, chưa xem hết phần sau,
Có file đính kèm sẽ rõ hơn.

vit nhua · 24/4/15

công thức e áp dụng không ra đc kết quả ý ạ.

vit nhua · 24/4/15

a/c giúp e sửa lại công thức với ạ e đang rất cần ạ help me điều kiện e cũng đã ghi rõ rùi ạ

leonguyenz · 24/4/15

vit nhua đã viết:
a/c giúp e sửa lại công thức với ạ e đang rất cần ạ help me điều kiện e cũng đã ghi rõ rùi ạ

Bạn nên tìm hiểu lại cấu trúc hàm IF, có 3 đối số trong hàm IF, ví dụ: IF(a,b,c), hoặc: IF(mệnh đề logic đúng hoặc sai, trả về kết quả nếu mệnh đề đúng, trả về kết quả nếu mệnh đề sai).

vit nhua đã viết:
=if(（and(D7=2,R7<P7),if(P7-R7)>=15,=if(（and(D7=2,R7<P7),if(P7-R7)>=15,(H7-G7)*250000+(J7-I7)*200000+(L7-K7)*100000+10000*R7,if(P7-R7)<15,0,if(or(D7=1，P7>0,R7>0,if(P7-R7)>=2,(H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7,,if(P7-R7)<2,0)))),if(P7-R7)<15,0,if(or(D7=1，P7>0,R7>0,if(P7-R7)>=2,(H7-G7)*600000+(J7-I7)*400000+(L7-K7)*200000+20000*R7,,if(P7-R7)<2,0))))

Excel 2003 chỉ lồng được 7 IF, phiên bản cao hơn cho phép lồng nhiều IF hơn.
Tốt nhất bạn nên đưa file lên.

vit nhua · 24/4/15

e có gửi file đính kèm dưới đây mọi ng xem hộ e ạ

leonguyenz · 24/4/15

vit nhua đã viết:
e có gửi file đính kèm dưới đây mọi ng xem hộ e ạ

Tạm thời sửa công thức cho đúng cấu trúc:

Mã:

=IF(AND(B12=1,K6-L6>=2),(E6-F6)*600000+(G6-H6)*400000+(I6-J6)*200000+20000*L6,IF(K6-L6< 2,0,IF(AND(B12=2,K6-L6>=15),(E6-F6)*250000+(G6-H6)*200000+(I6-J6)*100000+10000*L6,0)))

Chưa rõ lắm cách tính của bạn, bạn chỉ ví dụ dòng 6 mà chưa nói rõ dòng 7.

vit nhua · 24/4/15

dòng 6 và dòng 7 như nhau thui ạ. tính thưởng giống như e áp dụng đấy a. Nếu b12=1 và k6-l6>=2 đc thưởng tổng đó ...còn nếu <2 k thưởng.còn nếu b12=2 và k6-l6>=15 đc thưởng .. còn <15 k thưởng

Hau151978 · 24/4/15

vit nhua đã viết:
dòng 6 và dòng 7 như nhau thui ạ. tính thưởng giống như e áp dụng đấy a. Nếu b12=1 và k6-l6>=2 đc thưởng tổng đó ...còn nếu <2 k thưởng.còn nếu b12=2 và k6-l6>=15 đc thưởng .. còn <15 k thưởng

Bạn dùng công thức sau
=IF(AND(B12=1,K6-L6>=2),(E6-F6)*6+(G6-H6)*4+(I6-J6)*2+L6/5,IF(AND(B12=2,K6-L6>=15),(E6-F6)*2.5+(G6-H6)*2+I6-J6+L6/10,0))*100000

vit nhua · 25/4/15

e cảm ơn mọi ng nha e update lại công thức như mọi ng sửa ra đáp án roài mừng quá /-*+/

vit nhua · 25/4/15

E gặp 1 chút vấn đề nữa là khi sao chép công thức xuống các dòng dưới cùng 1 cột lại k ra kết quả. Nhưng khi copy công thức xuống dòng phía dưới rùi sửa lại ô cần tìm kết quả thì lại ra đáp án là cớ làm sao ạ??

leonguyenz · 25/4/15

vit nhua đã viết:
E gặp 1 chút vấn đề nữa là khi sao chép công thức xuống các dòng dưới cùng 1 cột lại k ra kết quả. Nhưng khi copy công thức xuống dòng phía dưới rùi sửa lại ô cần tìm kết quả thì lại ra đáp án là cớ làm sao ạ??

Bạn cố định dòng 6, ví dụ K6 thì bạn phải sửa lại là K$6 (thêm dấu $ vào hoặc bôi đen K6 và nhấn F4 2 lần). Khi đã cố định dòng, sao chép công thức theo dòng thì tham chiếu (ở đây là các ô dòng 6) sẽ không thay đổi.

Hàm IF trong excel (1 người xem)

Người dùng đang xem chủ đề này

Thành viên tích cực

Thành viên gắn bó

Huyền thoại GPE

Thành viên gạo cội

Thành viên tiêu biểu

Thành viên gắn bó

Huyền thoại GPE

Thành viên tiêu biểu

File đính kèm

Thành viên gắn bó

Thành viên tiêu biểu

Thành viên gạo cội

Huyền thoại GPE

Thành viên tích cực

Thành viên tích cực

Thành viên gắn bó

Huyền thoại GPE

Thành viên gắn bó

Thành viên gạo cội

Thành viên gắn bó

Thành viên gạo cội

Huyền thoại GPE

Thành viên gạo cội

Huyền thoại GPE

Thành viên mới

File đính kèm

Thành viên gạo cội

Thành viên gắn bó

Huyền thoại GPE

Thành viên mới

Thành viên gắn bó

Thành viên mới

Thành viên mới

Thành viên gạo cội

Thành viên mới

Thành viên mới

Thành viên mới

File đính kèm

Thành viên gắn bó

Thành viên tiêu biểu

CMC

Thành viên mới

Thành viên mới

Thành viên mới

Thành viên gạo cội

Thành viên gạo cội

Thành viên mới

Thành viên mới

Thành viên bị đình chỉ hoạt động

Thành viên mới

File đính kèm

Thành viên gạo cội

Thành viên gắn bó

File đính kèm

Thành viên hoạt động

File đính kèm

/(hông là gì!

Thành viên thường trực

0901452không62

Thành viên hoạt động

Thành viên hoạt động

Thành viên mới

Thành viên mới

Thành viên gắn bó

Thành viên mới

Thành viên mới

Thành viên gạo cội

Thành viên mới

File đính kèm

Thành viên gạo cội

Thành viên mới

Thành viên mới

File đính kèm

Thành viên mới

File đính kèm

Thành viên mới

Thành viên gạo cội

Thành viên mới