Giúp mình đếm khoảng trống max trong 1 cột khi xuất hiện dữ liệu a?

[kienden9]

Đếm khoảng trống lớn nhất trong 1 hàng hay cột thì trong diễn đàn đã giải quyết xong rồi.
Bài toán của tôi đưa ra ở đây là đếm khoảng trống lớn nhất trong một hàng hay 1 cột sau khi xuất hiện dữ liệu A. (Có nghĩa là nếu xuất hiện dữ liệu khác A thì các ô trống tiếp đó ko cần quan tâm mà chỉ quan tâm các ô trống chỉ khi xuất hiện dữ liệu A)
Cụ thể tôi có đính kèm file, mong các pro sớm giúp tôi.
Xin chân thành cảm ơn đã lắng nghe và chỉ giáo!

 

[bebo021999]

Đếm khoảng trống lớn nhất trong 1 hàng hay cột thì trong diễn đàn đã giải quyết xong rồi.
Bài toán của tôi đưa ra ở đây là đếm khoảng trống lớn nhất trong một hàng hay 1 cột sau khi xuất hiện dữ liệu A. (Có nghĩa là nếu xuất hiện dữ liệu khác A thì các ô trống tiếp đó ko cần quan tâm mà chỉ quan tâm các ô trống chỉ khi xuất hiện dữ liệu A)
Cụ thể tôi có đính kèm file, mong các pro sớm giúp tôi.
Xin chân thành cảm ơn đã lắng nghe và chỉ giáo!

Mình dùng hàm nhé:
data là cột chứa dữ liệu gồm các ký tự; C9 là ô điều kiện(ví dụ: A)
1- Xác định vị trí của A trong data:
Đặt name POS=IF(data=$C$9,ROW(data),""){1;"";"";"";"";"";"";"";"";"";"";"";"";"";15;"";"";"";"";"";"";"";"";"";"";"";"";"";29;"";"";"";"";"";"";"";"";"";"";"";41;"";"";"";"";"";"";48;""}
2- Xác định Vị trí Khác Rỗng trong data::
Đặt name KR=IF(ISBLANK(data),"",ROW(INDIRECT("1:"&ROWS(data))))
{1;"";3;"";"";"";7;8;"";"";"";12;"";"";15;16;17;"";"";"";"";"";"";"";"";26;"";"";29;"";"";"";"";"";35;"";"";38;"";"";41;"";"";"";"";"";"";48;49}
3- Xác định Vị trí Khác Rỗng, xuất hiện trước A trong data:
IF(POS<>"",MATCH(POS-1,KR,1),"")
{#N/A;"";"";"";"";"";"";"";"";"";"";"";"";"";12;"";"";"";"";"";"";"";"";"";"";"";"";"";26;"";"";"";"";"";"";"";"";"";"";"";38;"";"";"";"";"";"";41;""}
4- Khoảng cách trống trước A:
Đặt name KC=IF(ISERROR(POS-IF(POS<>"",MATCH(POS-1,KR,1),"")-1),"",POS-IF(POS<>"",MATCH(POS-1,KR,1),"")-1)
{"";"";"";"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";6;""}
5- Khảng cách lớn nhất:
= Max(KC) = 6

<File đính kèm>

 

[huuthang_bd]

Đếm khoảng trống lớn nhất trong 1 hàng hay cột thì trong diễn đàn đã giải quyết xong rồi.
Bài toán của tôi đưa ra ở đây là đếm khoảng trống lớn nhất trong một hàng hay 1 cột sau khi xuất hiện dữ liệu A. (Có nghĩa là nếu xuất hiện dữ liệu khác A thì các ô trống tiếp đó ko cần quan tâm mà chỉ quan tâm các ô trống chỉ khi xuất hiện dữ liệu A)
Cụ thể tôi có đính kèm file, mong các pro sớm giúp tôi.
Xin chân thành cảm ơn đã lắng nghe và chỉ giáo!

Bạn dùng công thức mảng này:

=MAX(LOOKUP(MATCH(SMALL(IF(Data=C14,ROW(Data),""),ROW(INDIRECT("1:"&COUNTIF(Data,"A")))),SMALL(IF(Data<>"",ROW(Data),""),ROW(INDIRECT("1:"&COUNTA(Data)))),0),ROW(INDIRECT("1:"&COUNTA(Data))),FREQUENCY(IF(Data="",ROW(Data),Data),IF(Data<>"",ROW(Data),""))))

Với Data là cột dữ liệu của bạn.

 

[Mr L2m]

Diễn đàn thật nhiều bác pro wa'

 

[kienden9]

Mình dùng hàm nhé:
data là cột chứa dữ liệu gồm các ký tự; C9 là ô điều kiện(ví dụ: A)
1- Xác định vị trí của A trong data:
Đặt name POS=IF(data=$C$9,ROW(data),""){1;"";"";"";"";"";"";"";"";"";"";"";"";"";15;"";"";"";"";"";"";"";"";"";"";"";"";"";29;"";"";"";"";"";"";"";"";"";"";"";41;"";"";"";"";"";"";48;""}
2- Xác định Vị trí Khác Rỗng trong data::
Đặt name KR=IF(ISBLANK(data),"",ROW(INDIRECT("1:"&ROWS(data))))
{1;"";3;"";"";"";7;8;"";"";"";12;"";"";15;16;17;"";"";"";"";"";"";"";"";26;"";"";29;"";"";"";"";"";35;"";"";38;"";"";41;"";"";"";"";"";"";48;49}
3- Xác định Vị trí Khác Rỗng, xuất hiện trước A trong data:
IF(POS<>"",MATCH(POS-1,KR,1),"")
{#N/A;"";"";"";"";"";"";"";"";"";"";"";"";"";12;"";"";"";"";"";"";"";"";"";"";"";"";"";26;"";"";"";"";"";"";"";"";"";"";"";38;"";"";"";"";"";"";41;""}
4- Khoảng cách trống trước A:
Đặt name KC=IF(ISERROR(POS-IF(POS<>"",MATCH(POS-1,KR,1),"")-1),"",POS-IF(POS<>"",MATCH(POS-1,KR,1),"")-1)
{"";"";"";"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";"";"";"";"";"";2;"";"";"";"";"";"";6;""}
5- Khảng cách lớn nhất:
= Max(KC) = 6

Thanks bebo tôi đã làm đc rồi. Nếu chỉ dò tìm trong 1 cột thì cách này thật tuyệt.

 

[kienden9]

Bạn dùng công thức mảng này:

=MAX(LOOKUP(MATCH(SMALL(IF(Data=C14,ROW(Data),""),ROW(INDIRECT("1:"&COUNTIF(Data,"A")))),SMALL(IF(Data<>"",ROW(Data),""),ROW(INDIRECT("1:"&COUNTA(Data)))),0),ROW(INDIRECT("1:"&COUNTA(Data))),FREQUENCY(IF(Data="",ROW(Data),Data),IF(Data<>"",ROW(Data),""))))

Với Data là cột dữ liệu của bạn.

Thanks huuthang! công thức của bạn rất hay, với công thức này tôi có thể copy công thức để tìm trong những cột dữ liệu khác. (Bạn có nhầm chút xíu ở chỗ Data=C14, đúng ra là: Data="A" đúng ko ^^)

 

[kienden9]

Cả nhà ơi giúp tôi 1 vấn đề này nữa với:
Trong bài toán tôi đưa ra ở trên, các pro giúp tôi đếm số lần xuất hiện các khoảng trống (ví dụ như trong 1 cột dữ liệu rất dài, Khi xuất hiện dữ liệu A và có các khoảng trống phía trên nó, thì số lần xuất hiện 3 khoảng trống hay x khoảng trống là bao nhiêu?)
Thanks các pro đã giúp đỡ @@

 

[huuthang_bd]

Cả nhà ơi giúp tôi 1 vấn đề này nữa với:
Trong bài toán tôi đưa ra ở trên, các pro giúp tôi đếm số lần xuất hiện các khoảng trống (ví dụ như trong 1 cột dữ liệu rất dài, Khi xuất hiện dữ liệu A và có các khoảng trống phía trên nó, thì số lần xuất hiện 3 khoảng trống hay x khoảng trống là bao nhiêu?)
Thanks các pro đã giúp đỡ @@

Sửa công thức của tôi lại một chút xíu là được mà.

=SUM(--(LOOKUP(MATCH(SMALL(IF(Data="A",ROW(Data),""),ROW(INDIRECT("1:"&COUNTIF(Data,"A")))),SMALL(IF(Data<>"",ROW(Data),""),ROW(INDIRECT("1:"&COUNTA(Data)))),0),ROW(INDIRECT("1:"&COUNTA(Data))),FREQUENCY(IF(Data="",ROW(Data),Data),IF(Data<>"",ROW(Data),"")))=3))

Vẫn là công thức mảng nha.

 

[kienden9]

Sửa công thức của tôi lại một chút xíu là được mà.

=SUM(--(LOOKUP(MATCH(SMALL(IF(Data="A",ROW(Data),""),ROW(INDIRECT("1:"&COUNTIF(Data,"A")))),SMALL(IF(Data<>"",ROW(Data),""),ROW(INDIRECT("1:"&COUNTA(Data)))),0),ROW(INDIRECT("1:"&COUNTA(Data))),FREQUENCY(IF(Data="",ROW(Data),Data),IF(Data<>"",ROW(Data),"")))=3))

Vẫn là công thức mảng nha.

Thanks Huuthang nhé, tôi làm được rồi. Bạn quả là pro về excel. Công thức mảng tôi ko biết j mấy. Tôi đang tìm tài liệu đọc để học thêm mà chưa biết nên đọc tài liệu nào?