Giúp đỡ cách gom kích thước có cùng 1 tên

[hml89]

Xin chào các anh, chị, em trong diễn đàn!
Tôi có 1 bảng dữ liệu cùng 1 tên nhưng kích thước khác nhau, giờ tôi muốn tổng số lượng các bàn có kích thước chiều dài lớn hơn 900, và các bàn có kích thước chiều dài lớn hơn 900. Mong mọi người giúp đỡ tôi .



Trân thành cám ơn!

 

[Ba Tê]

giờ tôi muốn tổng số lượng các bàn có kích thước chiều dài lớn hơn 900, và các bàn có kích thước chiều dài lớn hơn 900.

- tổng số lượng các bàn có kích thước chiều dài lớn hơn 900,
- và các bàn có kích thước chiều dài lớn hơn 900.
- (Rộng x Sâu x cao)
?????????????????????????????????

 

[hml89]

- tổng số lượng các bàn có kích thước chiều dài lớn hơn 900,
- và các bàn có kích thước chiều dài lớn hơn 900.
- (Rộng x Sâu x cao)
?????????????????????????????????

Dạ, tôi xin lỗi vì đã không sửa tiêu đề cột ạ. (Rộng x Sâu x cao) . Phần " RỘng" , cái kích thước đầu tiên là chiều dài sản phẩm ạ.

 

[Ba Tê]

Dạ, tôi xin lỗi vì đã không sửa tiêu đề cột ạ. (Rộng x Sâu x cao) . Phần " RỘng" , cái kích thước đầu tiên là chiều dài sản phẩm ạ.

Spoiler: Rộng: Lớn hơn 900

=SUMPRODUCT((--TRIM(LEFT(SUBSTITUTE(UPPER(SUBSTITUTE($B$3:$B$66;"×";"X"));"X";REPT(" ";100));100))>900)*($C$3:$C$66))

 

[Mộng Thường 2001]

Xin chào các anh, chị, em trong diễn đàn!
Tôi có 1 bảng dữ liệu cùng 1 tên nhưng kích thước khác nhau, giờ tôi muốn tổng số lượng các bàn có kích thước chiều dài lớn hơn 900, và các bàn có kích thước chiều dài lớn hơn 900. Mong mọi người giúp đỡ tôi .
Trân thành cám ơn!

Góp vui thêm công thức mảng:

=SUM(IFERROR(1/(--LEFT(SUBSTITUTE($B$3:$B$66,{"x","×","X"},REPT(" ",100)),100)>900)*$C$3:$C$66,))

Kết thúc bằng Ctrl+Shift+Enter.
Xem file kèm.
hihi ^o^

 

[hml89]

Spoiler: Rộng: Lớn hơn 900

=SUMPRODUCT((--TRIM(LEFT(SUBSTITUTE(UPPER(SUBSTITUTE($B$3:$B$66;"×";"X"));"X";REPT(" ";100));100))>900)*($C$3:$C$66))

Xin cám ơn bạn!

 

[hml89]

Góp vui thêm công thức mảng:

=SUM(IFERROR(1/(--LEFT(SUBSTITUTE($B$3:$B$66,{"x","×","X"},REPT(" ",100)),100)>900)*$C$3:$C$66,))

Kết thúc bằng Ctrl+Shift+Enter.
Xem file kèm.
hihi ^o^

Cám ơn bạn!

 

[HieuCD]

Xin chào các anh, chị, em trong diễn đàn!
Tôi có 1 bảng dữ liệu cùng 1 tên nhưng kích thước khác nhau, giờ tôi muốn tổng số lượng các bàn có kích thước chiều dài lớn hơn 900, và các bàn có kích thước chiều dài lớn hơn 900. Mong mọi người giúp đỡ tôi .



Trân thành cám ơn!

Chắc không có bàn làm việc nào dài hơn 9m

=SUM(--(--IFERROR(--LEFT(B3:B66,{3,4}),0)>900)*C3:C66)

Kết thúc bằng Ctrl+Shift+Enter

 

[Mộng Thường 2001]

Chắc không có bàn làm việc nào dài hơn 9m

=SUM(--(--IFERROR(--LEFT(B3:B66,{3,4}),0)>900)*C3:C66)

Kết thúc bằng Ctrl+Shift+Enter

Suy luận bám quá chắc vào thực tế, nên công thức cũng giảm được 9 phân.

Khà khà khà.

 

[befaint]

Thử với số 13

=SUMPRODUCT((--LEFT(REPT("0",13-LEN($B$3:$B$66))&$B$3:$B$66,5)>900)*$C$3:$C$66)
'Enter

 

[Mộng Thường 2001]

Thử với số 13

=SUMPRODUCT((--LEFT(REPT("0",13-LEN($B$3:$B$66))&$B$3:$B$66,5)>900)*$C$3:$C$66)
'Enter

Cũng như nhiều lần trước, lần công thức này của em làm anh bất ngờ, và thán phục!

Khà khà khà.

 

[HieuCD]

Thử với số 13

=SUMPRODUCT((--LEFT(REPT("0",13-LEN($B$3:$B$66))&$B$3:$B$66,5)>900)*$C$3:$C$66)
'Enter

Cố tình đưa số 13 vào nên dùng hàm Rept, thử luôn số 8 cho dữ dằn hơn. Khà khà

 

[excel_lv1.5]

Xin chào các anh, chị, em trong diễn đàn!
Tôi có 1 bảng dữ liệu cùng 1 tên nhưng kích thước khác nhau, giờ tôi muốn tổng số lượng các bàn có kích thước chiều dài lớn hơn 900, và các bàn có kích thước chiều dài lớn hơn 900. Mong mọi người giúp đỡ tôi .



Trân thành cám ơn!

Thêm cách khác:

=SUMPRODUCT((TEXT(LEFT("0"&B3:B66,5),"000x")>"0900x")*C3:C66)

 

[Mộng Thường 2001]

Thêm cách khác:

=SUMPRODUCT((TEXT(LEFT("0"&B3:B66,5),"000x")>"0900x")*C3:C66)

Vui quá! chưa có ngày nào có đủ mặt "4 quái" như hôm nay.

Khà khà khà.

 

[batman1]

Bàn dài hơn 10 m cũng có trong thực tế.
Nếu không có bàn nào rộng và cao < 100 thì

=SUMPRODUCT((--MID(B3:B66,1,LEN(B3:B66)-8)>900)*C3:C66)

+ Enter

 

[befaint]

Cố tình đưa số 13 vào nên dùng hàm Rept, thử luôn số 8 cho dữ dằn hơn. Khà khà

Vậy là đủ số 8 rồi nhé anh.

 

[Mộng Thường 2001]

Vậy là đủ số 8 rồi nhé anh.

Anh vừa tham khảo trang "Kích thước bàn làm việc cho Giám đốc", và trang khác để xem thử các Nguyên thủ quốc gia có bàn làm việc bao lớn, thì may cho anh em mình không có bàn nào quá khổ chiều dài.
https://ghevanminh.vn/tin-tuc-kinh-...ec/#Kich_thuoc_ban_lam_viec_danh_cho_giam_doc
Tuy nhiên, chiều ngang thì có lúc lên đến 4 số.
Nên, cẩn thận nhé em!

Khà khà khà

 

[batman1]

Ba chiều ngắn dài tùy ý

=SUMPRODUCT((--MID(B3:B66,1,SEARCH("x",B3:B66)-1)>900)*C3:C66)

Tất nhiên dữ liệu phải chuẩn, tức "x" hoặc "X", chứ không phải là "trông giống x". Công thức không phục vụ những người cẩu thả. Làm ăn lương thì phải làm chu đáo. Thế thôi.

 

[VetMini]

Ba chiều ngắn dài tùy ý

=SUMPRODUCT((--MID(B3:B66,1,SEARCH("x",B3:B66)-1)>900)*C3:C66)

Tất nhiên dữ liệu phải chuẩn, tức "x" hoặc "X", chứ không phải là "trông giống x". Công thức không phục vụ những người cẩu thả. Làm ăn lương thì phải làm chu đáo. Thế thôi.

Từ lâu rồi, bà con vẫn phục vụ như thường.
Trên nguyên tắc thì khong được cẩu thả. Nhưng trên thực tế thì bà con ở đây rất thích thử thách cho nên vẫn vặn vẹo công thức để phục vụ những tường hợp dữ liệu loạn xà ngầu.

 

[hml89]

xin cảm ơn tất cả các bạn, do lâu ngày không vào diễn đàn, nay diễn đàn thay đổi giao diện nên tôi chưa quen, hơi khó nhìn. Hay do tôi đã già nên mắt kém nhỉ?