Dùng Class Module để tạo sự kiện người dùng

Liên hệ QC
anhtuan1066

anhtuan1066

Thành viên gạo cội
Tham gia
10/3/07
Bài viết
5,802
Được thích
6,911
Tôi đang trong những bước đầu tiên nghiên cứu về Class Module nên sẽ viết theo sự hiểu biết của tôi. Nếu có sai sót, mong các cao thủ bổ sung thêm
Mục đích của bài viết này là:
- Tạo sự kiện người dùng khi mà các sự kiện cung cấp sẳn không đáp ứng được nhu cầu
- Khi mà chúng ta có nhu cầu "thu gom" tất cả các code của 1 số object (có cùng chức năng) về chung thành 1 code
------------------------------------------------------------------------------------------------
Giả định tình huống thế này:
- Tôi có 1 Workbook bao gồm 9 sheet, trong đó có 1 sheet Menu và 8 sheet con
- Tại sheet Menu, tôi vẽ 8 CommandButton để link đến 8 sheet con
- Tại các sheet con, mỗi sheet tôi vẽ 1 CommandButton để link đến sheet Menu
Thông thường bài toán này người ta sẽ viết cho mỗi CommandButton 1 đoạn code riêng lẻ. Như vậy, nếu số lượng object càng nhiều thì code của chúng ta sẽ trở nên dài dòng
Đàng nào thì các đoạn code ấy cũng có chung 1 mục đích... Vậy liệu có cách nào gom toàn bộ chúng thành 1 code duy nhất hay không? Câu trả lời là: Hoàn toàn có thể nếu biết dùng đến Class Module
Chúng ta cùng tiến hành giải pháp nhé
- Cứ cho rằng toàn bộ các CommandButton đã được vẽ xong
- Chuỗi mà ta gõ trên Caption của CommandButton chính là tên của sheet cần link
Vậy code của chúng ta sẽ bao gồm 2 phần
1> Trong Class Module
Hãy chèn 1 Class Module và nhớ đặt tên cho nó (trong file tôi đặt tên là MyClass) rồi đặt vào nó đoạn code này:
PHP: 
Public WithEvents CB As CommandButton
Private Sub CB_Click()
  On Error Resume Next
  Sheets(CB.Caption).Select
End Sub
2> Trong Module
Chèn 1 Module và đặt vào nó đoạn code này:
PHP: 
Public Button() As New MyClass
Sub Auto_Open()
  Dim i As Long, Obj As OLEObject, Ws As Worksheet
  For Each Ws In ThisWorkbook.Worksheets
    For Each Obj In Ws.OLEObjects
      If InStr(Obj.progID, "Forms.CommandButton") Then
        ReDim Preserve Button(i)
        Set Button(i).CB = Obj.Object
        i = i + 1
      End If
    Next Obj
  Next Ws
End Sub
Vậy là xong! Hãy chạy Auto_Open rồi nhấn nút thử
Nếu có ý định cho hiện 1 sheet duy nhất, các sheet khác ẩn thì sửa lại code trong Class Module như sau:
PHP: 
Public WithEvents CB As CommandButton
Private Sub CB_Click()
  Dim Sh As Worksheet
  On Error Resume Next
  Application.ScreenUpdating = False
  Set Sh = ActiveSheet
  Sheets(CB.Caption).Visible = True
  Sheets(CB.Caption).Select
  Sh.Visible = 2
  Application.ScreenUpdating = True
End Sub
Cũng chạy Auto_Open và thử bấm các nút
Điểm mấu chốt mà ta cần ghi nhớ trong toàn bộ code chỉ có 2 đoạn:
Public WithEvents CB As CommandButton (Khai báo)
và
Set Button(i).CB = Obj.Object (thiết lập để chúng "bắt tay" nhau)
Không có chúng thì toàn bộ sẽ "tan rã"
------------------------------------------------------------------------------------------------
Tóm lại công việc của chúng ta chỉ là:
- Đặt 2 đoạn code vào đúng vị trí
- Đặt tên cho Class Module
- Vẽ các CommandButton và gõ tên sheet cần link vào caption của chúng
- Chạy Auto_Open để khởi động việc "thu gom"
Điểm thú vị ở đây là:
- Chỉ có các CommandButton (thuộc ActiveX Control) mới bị ảnh hưởng bởi code này (các object khác hoàn toàn không bị ảnh hưởng)
- Với các CommandButton, chỉ cái nào có caption là tên sheet mới bị ảnh hưởng bởi code này
------------------------------------------------------------------------------------------------
Xin lưu ý với các bạn rằng:
- Việc dùng CommandButton để link với các sheet không phải là mục đích chính của bài viết này (chỉ lấy ví dụ để minh họa), vì thế mà tôi đã không đặt nó vào chung với topic: Tạo nút nhấn để link đến các sheet
- Mục đích chính của bài viết này là hướng dẩn cách dùng Class Module để tự tạo 1 sự kiện người dùng
- Code này chỉ thuộc dạng cơ bản, có thể tùy biến đề áp dụng cho rất nhiều bài toán khác
------------------------------------------------------------------------------------------------
Chỉ với 1 bài viết thì chưa đủ để nói về EventClass, vậy nên rất mong các cao thủ khác cùng góp sức hoàn thiện bài viết này
 

File đính kèm

  • CmdEventClass_1.xls
    84 KB · Đọc: 577
  • CmdEventClass_2.xls
    86.5 KB · Đọc: 471
Sắp xếp theo thời gian sắp xếp theo bầu chọn
khi làm các thao tác như bài trước em nói và ấn F5 thì dòng lệnh bị báo lỗi:
Public Button() As New MyClass (từ but...myclass)
và hộp thoại cảnh báo lỗi:

Compile error
invalid use of ..keyword
 
Upvote 0
minhcong.tckt đã viết:
khi làm các thao tác như bài trước em nói và ấn F5 thì dòng lệnh bị báo lỗi:
Public Button() As New MyClass (từ but...myclass)
và hộp thoại cảnh báo lỗi:

Compile error
invalid use of ..keyword
Nhấp chuột vào đây để mở rộng...
Thì bạn cứ làm xong hết đi, báo lỗi thế nào cứ mặc kệ, post file lên để mọi người tim nguyên nhân nhé
 
Upvote 0
Bạn làm bước này chưa, nhất là chỗ màu đỏ:

1> Trong Class Module
Hãy chèn 1 Class Module và nhớ đặt tên cho nó (trong file tôi đặt tên là MyClass) rồi đặt vào nó đoạn code này:
Nhấp chuột vào đây để mở rộng...
 
Upvote 0
minhcong.tckt đã viết:
Giờ lại được rùi, cảm ơn tất cả các huynh tỷ

Chắc em Inset/class module mới và đặt tên cho class2 trong khi Code là class1.
Nhấp chuột vào đây để mở rộng...

Không phải "chắc là lỗi do ..." theo kiểu đoán mò mà phải nói chinh xác "Rõ ràng là lỗi do ..."

Bởi vì báo lỗi compile Error ngay dòng code sau:

Public Button() As New MyClass

Chữ Public là từ khoá nên không thể sai, chữ Button là tên biến đang khai báo và có quyền khai báo tuỳ ý, nên không ai bắt sai, As New là từ khoá nên không thể sai.

Chỉ còn chữ MyClass. Bắt lỗi MyClass thì chỉ có 1 lỗi duy nhất là "MyClass" chưa khai báo. Hoặc khai báo 1 đằng sử dụng 1 nẻo.
 
Lần chỉnh sửa cuối:
Upvote 0
anhtuan1066 đã viết:
Tôi đang trong những bước đầu tiên nghiên cứu về Class Module nên sẽ viết theo sự hiểu biết của tôi. Nếu có sai sót, mong các cao thủ bổ sung thêm
Mục đích của bài viết này là:
- Tạo sự kiện người dùng khi mà các sự kiện cung cấp sẳn không đáp ứng được nhu cầu
- Khi mà chúng ta có nhu cầu "thu gom" tất cả các code của 1 số object (có cùng chức năng) về chung thành 1 code
------------------------------------------------------------------------------------------------
Giả định tình huống thế này:
- Tôi có 1 Workbook bao gồm 9 sheet, trong đó có 1 sheet Menu và 8 sheet con
- Tại sheet Menu, tôi vẽ 8 CommandButton để link đến 8 sheet con
- Tại các sheet con, mỗi sheet tôi vẽ 1 CommandButton để link đến sheet Menu
Thông thường bài toán này người ta sẽ viết cho mỗi CommandButton 1 đoạn code riêng lẻ. Như vậy, nếu số lượng object càng nhiều thì code của chúng ta sẽ trở nên dài dòng
Đàng nào thì các đoạn code ấy cũng có chung 1 mục đích... Vậy liệu có cách nào gom toàn bộ chúng thành 1 code duy nhất hay không? Câu trả lời là: Hoàn toàn có thể nếu biết dùng đến Class Module
Chúng ta cùng tiến hành giải pháp nhé
- Cứ cho rằng toàn bộ các CommandButton đã được vẽ xong
- Chuỗi mà ta gõ trên Caption của CommandButton chính là tên của sheet cần link
Vậy code của chúng ta sẽ bao gồm 2 phần
1> Trong Class Module
Hãy chèn 1 Class Module và nhớ đặt tên cho nó (trong file tôi đặt tên là MyClass) rồi đặt vào nó đoạn code này:
PHP: 
Public WithEvents CB As CommandButton
Private Sub CB_Click()
  On Error Resume Next
  Sheets(CB.Caption).Select
End Sub
2> Trong Module
Chèn 1 Module và đặt vào nó đoạn code này:
PHP: 
Public Button() As New MyClass
Sub Auto_Open()
  Dim i As Long, Obj As OLEObject, Ws As Worksheet
  For Each Ws In ThisWorkbook.Worksheets
    For Each Obj In Ws.OLEObjects
      If InStr(Obj.progID, "Forms.CommandButton") Then
        ReDim Preserve Button(i)
        Set Button(i).CB = Obj.Object
        i = i + 1
      End If
    Next Obj
  Next Ws
End Sub
Vậy là xong! Hãy chạy Auto_Open rồi nhấn nút thử
Nếu có ý định cho hiện 1 sheet duy nhất, các sheet khác ẩn thì sửa lại code trong Class Module như sau:
PHP: 
Public WithEvents CB As CommandButton
Private Sub CB_Click()
  Dim Sh As Worksheet
  On Error Resume Next
  Application.ScreenUpdating = False
  Set Sh = ActiveSheet
  Sheets(CB.Caption).Visible = True
  Sheets(CB.Caption).Select
  Sh.Visible = 2
  Application.ScreenUpdating = True
End Sub
Cũng chạy Auto_Open và thử bấm các nút
Điểm mấu chốt mà ta cần ghi nhớ trong toàn bộ code chỉ có 2 đoạn:
Public WithEvents CB As CommandButton (Khai báo)
và
Set Button(i).CB = Obj.Object (thiết lập để chúng "bắt tay" nhau)
Không có chúng thì toàn bộ sẽ "tan rã"
------------------------------------------------------------------------------------------------
Tóm lại công việc của chúng ta chỉ là:
- Đặt 2 đoạn code vào đúng vị trí
- Đặt tên cho Class Module
- Vẽ các CommandButton và gõ tên sheet cần link vào caption của chúng
- Chạy Auto_Open để khởi động việc "thu gom"
Điểm thú vị ở đây là:
- Chỉ có các CommandButton (thuộc ActiveX Control) mới bị ảnh hưởng bởi code này (các object khác hoàn toàn không bị ảnh hưởng)
- Với các CommandButton, chỉ cái nào có caption là tên sheet mới bị ảnh hưởng bởi code này
------------------------------------------------------------------------------------------------
Xin lưu ý với các bạn rằng:
- Việc dùng CommandButton để link với các sheet không phải là mục đích chính của bài viết này (chỉ lấy ví dụ để minh họa), vì thế mà tôi đã không đặt nó vào chung với topic: Tạo nút nhấn để link đến các sheet
- Mục đích chính của bài viết này là hướng dẩn cách dùng Class Module để tự tạo 1 sự kiện người dùng
- Code này chỉ thuộc dạng cơ bản, có thể tùy biến đề áp dụng cho rất nhiều bài toán khác
------------------------------------------------------------------------------------------------
Chỉ với 1 bài viết thì chưa đủ để nói về EventClass, vậy nên rất mong các cao thủ khác cùng góp sức hoàn thiện bài viết này
Nhấp chuột vào đây để mở rộng...

Xin cho em hỏi lại về vấn đề này ạ. Nếu giờ thay bằng tạo một sheet menu như trên em muốn là form có tên menu " trên đó chứa các commanbutton link tới các sheet như sheet menu kia" thì có làm được không ạ
--------------------------------------
Ở trên code viết vào module class
Mã: 
[COLOR=#000000][COLOR=#0000BB]Sheets[/COLOR][COLOR=#007700]([/COLOR][COLOR=#0000BB]CB[/COLOR][COLOR=#007700].[/COLOR][COLOR=#0000BB]Caption[/COLOR][COLOR=#007700]).[/COLOR][COLOR=#0000BB]Select[/COLOR][/COLOR]
giờ em thay bằng
Mã: 
userforms(CB.caption).select
thì có chạy được không hả anh?
em đã thay nhưng không được?
vậy nếu được thì phải làm như thế nào ạh???
 
Upvote 0
maytinhvp01 đã viết:
Xin cho em hỏi lại về vấn đề này ạ. Nếu giờ thay bằng tạo một sheet menu như trên em muốn là form có tên menu " trên đó chứa các commanbutton link tới các sheet như sheet menu kia" thì có làm được không ạ
--------------------------------------
Ở trên code viết vào module class
Mã: 
[COLOR=#000000][COLOR=#0000BB]Sheets[/COLOR][COLOR=#007700]([/COLOR][COLOR=#0000BB]CB[/COLOR][COLOR=#007700].[/COLOR][COLOR=#0000BB]Caption[/COLOR][COLOR=#007700]).[/COLOR][COLOR=#0000BB]Select[/COLOR][/COLOR]
giờ em thay bằng
Mã: 
userforms(CB.caption).select
thì có chạy được không hả anh?
em đã thay nhưng không được?
vậy nếu được thì phải làm như thế nào ạh???
Nhấp chuột vào đây để mở rộng...

Muốn thế nào bạn phải cho file lên đây chứ (chẳng lẽ tôi phải giả lập file để test giúp bạn sao)
 
Upvote 0
ndu96081631 đã viết:
Muốn thế nào bạn phải cho file lên đây chứ (chẳng lẽ tôi phải giả lập file để test giúp bạn sao)
Nhấp chuột vào đây để mở rộng...
Anh giúp em bài này theo modulle class và thay bằng dùng sheet menu như trên mà em muốn thay bằng form menu như trong file đính kèm ạ.
 

File đính kèm

  • Menuform_linksheet.xlsm
    25.5 KB · Đọc: 30
Upvote 0
maytinhvp01 đã viết:
Anh giúp em bài này theo modulle class và thay bằng dùng sheet menu như trên mà em muốn thay bằng form menu như trong file đính kèm ạ.
Nhấp chuột vào đây để mở rộng...

Với 3 cái sheet, làm class chi cho mệt vậy bạn? Làm hẳn trên form với sự kiện Click của các nút được rồi!
 
Lần chỉnh sửa cuối:
Upvote 0
maytinhvp01 đã viết:
Anh giúp em bài này theo modulle class và thay bằng dùng sheet menu như trên mà em muốn thay bằng form menu như trong file đính kèm ạ.
Nhấp chuột vào đây để mở rộng...

Chèn 1 Class (tên mặc định của nó là Class1) với code:
Mã: 
Public WithEvents cmd As MSForms.CommandButton
Private Sub cmd_Click()
  On Error Resume Next
  With ThisWorkbook.Worksheets(cmd.Caption)
    .Visible = -1
    .Activate
  End With
End Sub
Code trong UserForm menu
Mã: 
Dim Buttons() As New [COLOR=#ff0000][B]Class1[/B][/COLOR]
Private Sub UserForm_Initialize()
  Dim Ctrl As Control, n As Long
  For Each Ctrl In Me.Controls
    If TypeOf Ctrl Is MSForms.CommandButton Then
      n = n + 1
      ReDim Preserve Buttons(1 To n)
      Set Buttons(n).cmd = Ctrl
    End If
  Next
End Sub
 
Upvote 0
maytinhvp01 đã viết:
Đó là file test thôi mà bạn. Hơn nữa mình muốn học hỏi là chính mà!!!!
Nhấp chuột vào đây để mở rộng...
OK, nó cũng chỉ đơn giản vậy thôi:

1) Code trong Class Module:

[GPECODE=vb]Option Explicit
Public WithEvents CmdBttn As MSForms.CommandButton

Private Sub CmdBttn_Click()
Sheets(CmdBttn.Caption).Select
Range("A1").Select
Unload menu
End Sub
[/GPECODE]

2) Code trong UserForm Module:

Mã: 
Option Explicit
Private MyCmdBttn(1 To 3) As New EventClass

Private Sub UserForm_Initialize()
    Dim i As Long
    For i = 1 To 3
        Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)
    Next
End Sub
 

File đính kèm

  • Menuform_linksheet.xlsm
    30.3 KB · Đọc: 57
Upvote 0
Hoàng Trọng Nghĩa đã viết:
OK, nó cũng chỉ đơn giản vậy thôi:

1) Code trong Class Module:

[GPECODE=vb]Option Explicit
Public WithEvents CmdBttn As MSForms.CommandButton

Private Sub CmdBttn_Click()
Sheets(CmdBttn.Caption).Select
Range("A1").Select
Unload menu
End Sub
[/GPECODE]

2) Code trong UserForm Module:

Mã: 
Option Explicit
Private MyCmdBttn(1 To 3) As New EventClass

Private Sub UserForm_Initialize()
    Dim i As Long
    For i = 1 To 3
        Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)
    Next
End Sub
Nhấp chuột vào đây để mở rộng...
Mã: 
CmdBttn As MSForms.CommandButton
Cái này mình hiểu là: Cmdbttn có kiểu của commandbutton trên form đúng không vây?
Mã: 
Private Sub UserForm_Initialize()
Giải thích giúp mình tẹo ý nghĩa của nó "Initialize"
Mã: 
For i = 1 To 3
        Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)
    Next
Mình không hiểu câu lệnh này, giải thích giúp thêm với bạn?
 
Upvote 0
maytinhvp01 đã viết:
Mã: 
CmdBttn As MSForms.CommandButton
Cái này mình hiểu là: Cmdbttn có kiểu của commandbutton trên form đúng không vây?
Mã: 
Private Sub UserForm_Initialize()
Giải thích giúp mình tẹo ý nghĩa của nó "Initialize"
Mã: 
For i = 1 To 3
        Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)
    Next
Mình không hiểu câu lệnh này, giải thích giúp thêm với bạn?
Nhấp chuột vào đây để mở rộng...

Private Sub UserForm_Initialize()

Nếu như các controls trên UserForm đều có sự kiện, thì UserForm cũng có sự kiện. Câu lệnh trên là một trong các sự kiện mà khi bắt đầu load form (form show), trước khi sự kiện Activate của form xảy ra thì xuất hiện sự kiện Initialize. Đây là sự kiện đầu tiên của UserForm, các thủ tục trong sự kiện này chạy ngầm cho đến khi form hiện trước mặt chúng ta là đã kết thúc.

Private MyCmdBttn(1 To 3) As New EventClass

MyCmdBttn là một mảng 1 chiều, tôi tạo ra mảng này nhằm mục đích để nó là mảng kiểu Object Data, nó có 3 phần tử (nếu ta chắc chắn biết số phần tử nằm bên trong nó, trong trường hợp này ta biết chắc có 3 nút lệnh), mỗi phần tử là một object. Mảng này được điều khiển bởi ClassModule EventClass.

Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)

Khi chạy vòng lặp i từ 1 đến 3, vì mỗi phần tử là một object nên chúng ta phải SET chúng, và gán chúng có thuộc tính mà ta đã thực hiện trong ClassModule, đó chính là CmdBttn.

Me("CommandButton" & i) Ở đây Me là đại diện cho UserForm, thay vì ta viết Controls("CommandButton" & i) thì ta viết như thế. Bởi các Button có Name giống nhau (CommandButton) chỉ khác số cuối nên ta lợi dụng điểm này mà thực hiện vòng lặp.

Thay vì ta SET đến 3 lần, mỗi lần như sau:

Set MyCmdBttn(1).CmdBttn = CommandButton1
Set MyCmdBttn(2).CmdBttn = CommandButton2
Set MyCmdBttn(3).CmdBttn = CommandButton3

Thì chúng ta dùng vòng lặp cho nó gọn lại.

Hy vọng tôi nói nôm na như thế bạn sẽ hiểu được những gì tôi nói.
 
Lần chỉnh sửa cuối:
Upvote 0
Mã: 
Public WithEvents cmd As MSForms.CommandButton
Private Sub cmd_Click()
  On Error Resume Next
  With ThisWorkbook.Worksheets(cmd.Caption)
    .Visible = -1
    .Activate
  End With
End Sub
Mã: 
Dim Buttons() As New [COLOR=#ff0000][B]Class1[/B][/COLOR]
Private Sub UserForm_Initialize()
  Dim Ctrl As Control, n As Long
  For Each Ctrl In Me.Controls
    If TypeOf Ctrl Is MSForms.CommandButton Then
      n = n + 1
      ReDim Preserve Buttons(1 To n)
      Set Buttons(n).cmd = Ctrl
    End If
  Next
End Sub
Mã: 
Option Explicit
Private MyCmdBttn(1 To 3) As New EventClass

Private Sub UserForm_Initialize()
    Dim i As Long
    For i = 1 To 3
        Set MyCmdBttn(i).CmdBttn = Me("CommandButton" & i)
    Next
End Sub
Cảm ơn 2 anh nhé! 2 code đều cho kết qquar đúng ạ
 
Upvote 0
maytinhvp01 đã viết:
Cảm ơn 2 anh nhé! 2 code đều cho kết qquar đúng ạ
Nhấp chuột vào đây để mở rộng...

Tùy theo trường hợp mà dùng 2 thủ tục vòng lặp, nếu tất cả các nút lệnh đều là nút mà chọn sheet thì vòng lặp For Each ... Next sẽ thực hiện đúng, giả sử có nhiếu nút lệnh với các chức năng khác nhau, thì vô hình chung vòng lặp loại này sẽ mang thuộc tính của sự kiện mà ta vừa tạo tại ClassModule. Đồng thời ta có trên form nào là label, nào là textbox, combobox, frame, v.v... thì vòng lặp này quét qua tất cả để chỉ tìm đúng loại CommandButton thôi nên sẽ "phí" thời gian.

Với trường hợp vòng lặp For i ... Next thì không hữu dụng với các Name không có điểm chung. Với tôi sẽ chọn cách này và đặt tên cho chúng giống nhau, chỉ khác số cuối cùng (chẳng hạn cmdSheet1, cmdSheet2, v.v...) thì sẽ làm cho code gọn đi rất nhiều.
 
Upvote 0
Hoàng Trọng Nghĩa đã viết:
Tùy theo trường hợp mà dùng 2 thủ tục vòng lặp, nếu tất cả các nút lệnh đều là nút mà chọn sheet thì vòng lặp For Each ... Next sẽ thực hiện đúng, giả sử có nhiếu nút lệnh với các chức năng khác nhau, thì vô hình chung vòng lặp loại này sẽ mang thuộc tính của sự kiện mà ta vừa tạo tại ClassModule. Đồng thời ta có trên form nào là label, nào là textbox, combobox, frame, v.v... thì vòng lặp này quét qua tất cả để chỉ tìm đúng loại CommandButton thôi nên sẽ "phí" thời gian.

Với trường hợp vòng lặp For i ... Next thì không hữu dụng với các Name không có điểm chung. Với tôi sẽ chọn cách này và đặt tên cho chúng giống nhau, chỉ khác số cuối cùng (chẳng hạn cmdSheet1, cmdSheet2, v.v...) thì sẽ làm cho code gọn đi rất nhiều.
Nhấp chuột vào đây để mở rộng...

Mình gặp phải vấn đề không biết xử lý sao
Mình vào vấn đề luôn, xóa một commandbutton chạy trương trình báo lỗi dù đã thử nhiều cách:
1> Bổ xung lại commandbutton với tên đúng như tên đã sóa nhưng không được
2> Sóa nốt sheet tương ứng tên của commandbutton đó cũng không được
gặp phải cái này mình phải xử lý như thế nào ? bạn có thể thử trên file bạn up cho mình!!!
 
Upvote 0
maytinhvp01 đã viết:
Mình gặp phải vấn đề không biết xử lý sao
Mình vào vấn đề luôn, xóa một commandbutton chạy trương trình báo lỗi dù đã thử nhiều cách:
1> Bổ xung lại commandbutton với tên đúng như tên đã sóa nhưng không được
2> Sóa nốt sheet tương ứng tên của commandbutton đó cũng không được
gặp phải cái này mình phải xử lý như thế nào ? bạn có thể thử trên file bạn up cho mình!!!
Nhấp chuột vào đây để mở rộng...


Bạn hơi bị lạ đời đấy! File bạn làm bị lỗi, thì bạn post cái file đó lên để người ta xem nó bị lỗi gì, tôi có làm cái file nào đâu mà bạn bảo tôi up file lên?
 
Upvote 0
ndu96081631 đã viết:
Chèn 1 Class (tên mặc định của nó là Class1) với code:
Mã: 
Public WithEvents cmd As MSForms.CommandButton
Private Sub cmd_Click()
  On Error Resume Next
  With ThisWorkbook.Worksheets(cmd.Caption)
    .Visible = -1
    .Activate
  End With
End Sub
Code trong UserForm menu
Mã: 
Dim Buttons() As New [COLOR=#ff0000][B]Class1[/B][/COLOR]
Private Sub UserForm_Initialize()
  Dim Ctrl As Control, n As Long
  For Each Ctrl In Me.Controls
    If TypeOf Ctrl Is MSForms.CommandButton Then
      n = n + 1
      ReDim Preserve Buttons(1 To n)
      Set Buttons(n).cmd = Ctrl
    End If
  Next
End Sub
Nhấp chuột vào đây để mở rộng...
Khi chạy code của HOANG TRONG NGHIA không áp dụng được trong quá trình sửa chữa nhưng code của anh thì rất thuận lợi cho sửa chữa theo nhu cầu sử dụng ạ
 
Upvote 0
Bạn phải đăng nhập hoặc đăng ký để trả lời bài viết tại đây.
Web KT

Bài viết mới nhất

PhanTuHuong
Bàn về môn thể thao bóng bàn nào!
    • Thích
    • Yêu thích
    • Cười
2
Trả lời
36
Đọc
2K
Tuấn Bụng Bự
Tuấn Bụng Bự
Tuấn Bụng Bự
  • Question
Tìm Bộ 8 số xuất hiện nhiều nhất trong random( 1 - 80)
2
Trả lời
31
Đọc
740
Tuấn Bụng Bự
Tuấn Bụng Bự
triplet123
GIÚP EM VỚI Ạ EM CẢM ƠN MỌI NGƯỜI NHIỀU Ạ
    • Phẫn nộ
Trả lời
1
Đọc
45
VetMini
V
S
  • Question
Xin file excel bảng giá quần áo, trang phục, phụ kiện
Trả lời
2
Đọc
29
VetMini
V
P
Tổng hợp dữ liệu từ các sheet theo chọn lọc
Trả lời
19
Đọc
344
VetMini
V
dung09031989
Xin giúp công thức tô màu các ô phía sau khi kế hoạch đặt hàng thiếu so với tồn kho.?
Trả lời
4
Đọc
131
VetMini
V
C
Chia sẻ: Kết quả xổ số Keno
    • Cười
    • Thích
Trả lời
13
Đọc
341
VetMini
V
P
Nhờ giúp đỡ hàm lọc dữ liệu theo tỉnh
Trả lời
9
Đọc
118
VetMini
V
H
Tính và sắp xếp theo thư tự tăng dần có điều kiệu (có dữ liệu trùng nhau)
Trả lời
2
Đọc
63
longtay1111
L
nobita994
Trừ số lượng dần theo dòng khi quét Sumif tổng có tên sản phẩm bị trùng.
Trả lời
0
Đọc
37
nobita994
nobita994
kimtanmap
  • Question
Nhờ viết code VBA Macro lập lại.
Trả lời
6
Đọc
207
kimtanmap
kimtanmap
20050911
File Excel lỗi ''The file could not be accessed. Try one of the following:.."
Trả lời
4
Đọc
181
VetMini
V
ongke0711
  • Question
Trộn dữ liệu từ Excel sang Word mở rộng (phiên bản ongke0711)
    • Thích
    • Yêu thích
    • Cảm ơn
11 12 13
Trả lời
257
Đọc
25K
Pham Ha 233
Pham Ha 233
C
Công thức tự nhập liệu số lượng nhập khi bị âm
Trả lời
2
Đọc
121
cherry0187
C
N
Vẽ biểu đồ kết hợp nhiều yếu tố trong excel
Trả lời
4
Đọc
127
Ny Ny 2024
N
ongke0711
  • Question
Tải hóa đơn điện tử (https://hoadondientu.gdt.gov.vn/) Excel Vba
    • Thích
    • Yêu thích
11 12 13
Trả lời
251
Đọc
13K
ongke0711
ongke0711
N
Định mức nguyên vật liệu
Trả lời
1
Đọc
175
yeudoi
yeudoi
GPE-Trợ Lý
KHÓA HỌC BỨT PHÁ KỸ NĂNG EXCEL
    • Thích
Trả lời
1
Đọc
325
PhanTuHuong
PhanTuHuong
B
Định dạng condition formatting, đếm hỗn hợp dữ liệu merge và không merge
Trả lời
17
Đọc
210
batista911
B
V
  • Question
Lấy dữ liệu lãi suất từ website Sbv.gov.vn bằng Power Query
Trả lời
1
Đọc
527
Minhhanhsgu
M
Xem thêm…

Thành viên có số lượng bài viết cao nhất tháng

Thành viên có điểm tương tác cao nhất tháng

Back
Top Bottom