Chuyên đề giải đáp các bài tập

[hoangminhtien]

Tính số tuần chẵn (7 ngày là 1 tuần)

=INT((E3-D3)/7)

Số ngày lẻ

=MOD(E3-D3,7)

 

[jindolee]

thx bác hoangminhtien nhìu.
Cho em hỏi tiếp câu này với:
Ô: C3HÒNG; L31
D3: NGÀY ĐẾN:05/01/03
E3: NGÀY ĐI: 16/08/03
F3: SỐ TUẦN CHẴN: 31
G3: SỐ NGÀY LẺ: 6
H3: TIỀN TUẦN: 1395
I3: TIỀN NGÀY: ?

Câu hỏi: Tiền ngày= số ngày * đơn giá ngày (đơn giá ngày dựa vào 2 kí tự đầu của mã phòng và bàng tham chiếu). Tuy nhiên nếu tích số này lớn hơn đơn giá 1 tuần thì lấy đơn giá 1 tuần.

Câu màu đỏ mình không hiểu, không bít làm như thế nào.

File đính kèm đây không bít em làm đúng không, các bác vô xem hộ em với. thx các bác nhìu


Bác nào chỉ em với

 

[hoangminhtien]

Câu hỏi: Tiền ngày= số ngày * đơn giá ngày (đơn giá ngày dựa vào 2 kí tự đầu của mã phòng và bàng tham chiếu). Tuy nhiên nếu tích số này lớn hơn đơn giá 1 tuần thì lấy đơn giá 1 tuần.

Câu màu đỏ mình không hiểu, không bít làm như thế nào.

Bạn dùng công thức sau xem có được không nhé!

I3=MIN(G3*VLOOKUP(LEFT(C3,2),$B$13:$D$16,3,0),VLOOKUP(LEFT(C3,2),$B$13:$D$16,2,0))

 

[jindolee]

Bạn dùng công thức sau xem có được không nhé!

Cám ơn bác nhiều, em làm bài được rùi.

 

[wormwon]

Nhờ các bác trên đây giúp đỡ:

số là có cái đơn giá nó được tính bằng cái bảng giá hàng hóa bên dưới mà mình không biết nhập cú pháp thế nào

ví dụ C1 hay C1G là 80
còn C2 là 82

 

[Lê Duy Thương]

Nhờ các bác trên đây giúp đỡ:

số là có cái đơn giá nó được tính bằng cái bảng giá hàng hóa bên dưới mà mình không biết nhập cú pháp thế nào

ví dụ C1 hay C1G là 80
còn C2 là 82

bạn thử ct này xem sao
=VLOOKUP(LEFT(A3),$G$14:$I$19,MID(A3,2,1)+1,0)

 

[nhut142]

Giải dùm em bài này

Bài Đại lý gạo ở sheet 3 câu 7 rút trích. thank.

 

[usagi90]

Bài Đại lý gạo ở sheet 3 câu 7 rút trích. thank.

Bạn xem file này nhé

 

[kimdung1980]

Hàm và công thức Excel

Mình cũng giống bạn đã tìm hiểu rất nhiều về các bài tập hướng dẫn. Hôm vừa rồi mình vào chương trình vi tính thật là đơn giản xem trên Blog có địa chỉ của Thầy Dương Mạnh Hùng nên đã thiết lập một số hàm công thức và các biểu mẫu có gửi cả tệp đính kèm gửi nhờ thầy làm hộ và đăng ký mua luôn một đĩa CD tổng hợp về các hàm.
Chúc bạn sớm tìm được các vấn đề mà bạn đang quan tâm.

 

[nhut142]

Anh dùng hàm gì để rút trích vậy. Em dùng advance filter nhưng khi rút trích nó lại hiện ra hết cả bảng luôn chứ không hiện theo yêu cầu. Và anh chỉ dùm em cách chuyển từ font VNI sang TIME NEW ROMAN giống như trong bài anh trả lời.Thank.

 

[usagi90]

Anh dùng hàm gì để rút trích vậy. Em dùng advance filter nhưng khi rút trích nó lại hiện ra hết cả bảng luôn chứ không hiện theo yêu cầu. Và anh chỉ dùm em cách chuyển từ font VNI sang TIME NEW ROMAN giống như trong bài anh trả lời.Thank.

Mình cũng dùng advance filter..Mình nghĩ bạn bị ra cả bảng là vì điều kiện của bạn bị sai. Còn chuyển sang font chữ thì dùng add in chuyển đổi font. trên diễn đàn mình có nhiều nắm đó

 

[deepsea433]

Cho mình hỏi về cách xuất thông tin đường dẫn file vào excel

Giả sử mình có một file excel, mình phải làm cách nào để nhập hàm hoặc code vào một ô để ô đó trả về chuỗi đường dẫn của file excel đó?

Ví dụ: file nằm trong D:\baitap\Excel1 thì nó sẽ in ra chuỗi "D:\baitap\Excel1"

Mong pro nào biết chỉ giáo. Thanks nhiều!

 

[leonguyenz]

Nhập vào 1 ô nào đó: =CELL("filename",A1)

 

[deepsea433]

Nhập vào 1 ô nào đó: =CELL("filename",A1)

Đơn giản thật vậy mà mình nghĩ phải phức tạp lắm! Thanks sự nhiệt tình của mấy pro!

 

[trunguy146]

Tớ cũng đang học EX, tớ chưa nghĩ được công thức gọn hơn bạn tham khảo cách ni xem :
=IF(RIGHT(B10)="A";VLOOKUP((LEFT(B10;FIND("-";B10;1)-1));$B$5:$F$7;2;0);IF(RIGHT(B10)="B";VLOOKUP((LEFT(B10;FIND("-";B10;1)-1));$B$5:$F$7;3;0);IF(RIGHT(B10)="C";VLOOKUP((LEFT(B10;FIND("-";B10;1)-1));$B$5:$F$7;4;0))))
Mong nhận được sự chỉ giáo từ phía anh em !

 

[leonguyenz]

=IF(RIGHT(B10)="A";VLOOKUP((LEFT(B10;FIND("-";B10;1)-1));$B$5:$F$7;2;0);IF(RIGHT(B10)="B";VLOOKUP((LEFT (B10;FIND("-";B10;1)-1));$B$5:$F$7;3;0);IF(RIGHT(B10)="C";VLOOKUP((LEFT (B10;FIND("-";B10;1)-1));$B$5:$F$7;4;0))))
Rút gọn thành:
=VLOOKUP((LEFT(B10;FIND("-";B10;1)-1));$B$5:$F$7;IF(RIGHT(B10)="A";2;IF(RIGHT(B10)="B";3;4));0)
Bạn nên đưa file lên để xem dùng công thức nào sẽ gọn hơn.

 

[hvn8006]

Nhờ mọi người giải giùm e bài tập về hàm thời gian này.

Em không rõ về bài tập này. Mong mọi người vào chỉ giùm. Thanks giải pháp excel

 

[Ba Tê]

Em không rõ về bài tập này. Mong mọi người vào chỉ giùm. Thanks giải pháp excel

Nhập Công thức vào các ô đầu cột, chú ý dấu chấm phẩy hoặc dấu phẩy là tùy máy từng người.

D6=C6+2+(WEEKDAY(C6)=6)+(WEEKDAY(C6)=7)
E6=DATE(YEAR(D6);MONTH(D6)+HLOOKUP(LEFT(B6);$C$19:$E$20;2;0);DAY(D6))
H6=DATE(YEAR(E6);MONTH(E6);0)
I6=IF(AND(F6>=HLOOKUP(LEFT(B6);$C$19:$E$21;3;0);G6<=H6);"Được Thi";"")

 

[hvn8006]

Nhập Công thức vào các ô đầu cột, chú ý dấu chấm phẩy hoặc dấu phẩy là tùy máy từng người.

D6=C6+2+(WEEKDAY(C6)=6)+(WEEKDAY(C6)=7)
E6=DATE(YEAR(D6);MONTH(D6)+HLOOKUP(LEFT(B6);$C$19:$E$20;2;0);DAY(D6))
H6=DATE(YEAR(E6);MONTH(E6);0)
I6=IF(AND(F6>=HLOOKUP(LEFT(B6);$C$19:$E$21;3;0);G6<=H6);"Được Thi";"")

Chào chú ba tê rất cảm ơn chú về bài trả lời trên. Có vấn đề không hiểu mong chú giải thích cho cháu biết àh.
trong hàm D6=C6+2+(WEEKDAY(C6)=6)+(WEEKDAY(C6)=7) ý nghĩa của nó như thế nào àh. (WEEKDAY(C6)=6) và (WEEKDAY(C6)=7) có ý nghĩa gì àh?

 

[hoamattroicoi]

Chào chú ba tê rất cảm ơn chú về bài trả lời trên. Có vấn đề không hiểu mong chú giải thích cho cháu biết àh.
trong hàm D6=C6+2+(WEEKDAY(C6)=6)+(WEEKDAY(C6)=7) ý nghĩa của nó như thế nào àh. (WEEKDAY(C6)=6) và (WEEKDAY(C6)=7) có ý nghĩa gì àh?

Hàm Weekday()

Hàm WEEKDAY

Chức năng : Hàm WEEKDAY trả về một giá trị, là số thứ tự của Ngày trong tuần.

Cấu trúc : WEEKDAY(serial_number, return_type)

- Serial_number : là một biểu thức thời gian, Serial_number có thể là Number hay Value_date.
+ Number là số có giá trị tương ứng với giá trị của Ngày nào đó. VD ngày 27/04/08 ứng với số 39565.
+ Value_date có thể là tham chiếu đến ô nào đó có giá trị Ngày tháng, hoặc từ kết quả của một số hàm như Today, Date..

-return_type: là tùy chọn để xác định kiểu giá trị sẽ trả về trong công thức, option có giá trị từ 1 đến 3 :
+ option = 1 hoặc để trống : Ngày chủ nhật được xem là 1, Ngày thứ bảy là 7.
+ option = 2 : Ngày thứ hai được xem là 1, Ngày chủ nhật là 7.
+ option = 3 : Ngày thứ hai được xem là 0, Ngày chủ nhật là 6.

Ghi chú : Nếu trong công thức có option =1 và ô có kiểu định dạng là dddd thì kết quả trả về là Tên của Ngày trong tuần.

Trong công thức trên vì yêu cầu của đề bài :
Yêu cầu : Học viên đăng ký trúng vào buổi học nào (2-4-6 hoặcc 3-5-7) thì học vào buổi đó và Ngày Bắt Đầu Học là ngày của buổi kế tiếp.
Vì ngày bắt đầu học là ngày của buổi kế tiếp nên Ngày bắt đầu học = Ngày đăng ký học + 2 (do mỗi buổi học cách nhau 2 ngày -- 2-4-6, 3-5-7)
Hơn nữa ta nhận thấy nếu ngày đăng ký học rơi vào 2 ngày là thứ 6 và thứ 7 nó sẽ cách ngày học của tuần sau 3 buổi nên kẹp thêm cái weekday(C6)=6 và weekday(C6)=7 (weekday(C6)=6,weekday(C6)=7 : trả về giá trị True tương ứng với giá trị 1 hoặc False tương ứng với giá trị 0) có nghĩa nếu ngày đăng ký học rơi vào thứ 6 hoặc thứ 7 thì Ngày bắt đầu học = Ngày đăng ký học cộng 2 và cộng thêm 1 nữa.