Chuyên đề giải đáp các bài tập Excel (Phần 3)

[kiet321]

Anh chị giúp em câu 2 nhập tên khách hàng với ạ, em chưa hình dung ra, hix. Em cảm ơn.

 

[leonguyenz]

Anh chị giúp em câu 2 nhập tên khách hàng với ạ, em chưa hình dung ra, hix. Em cảm ơn.

Câu 2 yêu cầu sử dụng Data Validation: Chọn Đ18 > Tab Data > Data Validation > Settings > Allow: List; Source: =$I$21:$I$30 > Error Alert: Nhập cảnh báo.

 

[kiet321]

Anh chị cho em hỏi với ạ. Trong sheet: đề chẵn, file bên dưới, câu số 7. Em giải phải dùng cột phụ để tính số tháng. Vậy anh chị cho em hỏi: có cách nào không dùng cột phụ không. Em cảm ơn ạ.

 

[mhung12005]

Anh chị cho em hỏi với ạ. Trong sheet: đề chẵn, file bên dưới, câu số 7. Em giải phải dùng cột phụ để tính số tháng. Vậy anh chị cho em hỏi: có cách nào không dùng cột phụ không. Em cảm ơn ạ.

Bạn dùng công thức sau cho ô C32:

=SUMPRODUCT(((MONTH($E$9:$E$18)=RIGHT($B32)*1)*($C$9:$C$18=C$31)),$F$9:$F$18)

 

[kiet321]

Bạn dùng công thức sau cho ô C32:

C32=SUMIFS($F$9:$F$18,$C$9:$C$18,C$31,$E$9:$E$18,MONTH($E$9:$E$18)=RIGHT($B32,1)*1)

Anh xem giúp em công thức này với ạ. Em đổi sang như vầy mà không tính được. Còn công thức anh đưa ok rồi hihi.

 

[duongvannam27]

Tính trung bình theo điều kiện

Các anh chị giúp em câu 5 khó quá. Em làm bằng averageif mà hoài không ra hix

 

[Ba Tê]

Các anh chị giúp em câu 5 khó quá. Em làm bằng averageif mà hoài không ra hix

Công thức của bạn:
=AVERAGEIF($K$5:$K$14;">$E$41";$H$5:$H$14)
Phải là vầy mới đúng:
=AVERAGEIF($K$5:$K$14;">" & $E$41;$H$5:$H$14)

 

[huonglanngoc0001]

=if(c5<3000,hlookup(vlookup($a5,$a$19:$d$25,4,0),$f$19:$i$21,2,0),hlookup(vlookup($a5,$a$19:$d$25,4,0),$f$19:$i$21,3,0))

 

[ptm0412]

=if(c5<3000,hlookup(vlookup($a5,$a$19:$d$25,4,0),$f$19:$i$21,2,0),hlookup(vlookup($a5,$a$19:$d$25,4,0),$f$19:$i$21,3,0))

Nếu dùng h và v như trên thì có thể ngắn thế này thôi:

=hlookup(vlookup($a5,$a$19:$d$25,4,0),$f$19:$i$21,if(c5<3000,2,3),0)

Và có thể dùng cách khác ngắn hơn nữa

 

[masukkent]

anh chị giúp em với em làm ở cột sheet điểm lập công thức xong enter nó không ra kết quả mà ra nguyên cái công thức.

 

[thanhsangnguyen1982]

anh chị giúp em với em làm ở cột sheet điểm lập công thức xong enter nó không ra kết quả mà ra nguyên cái công thức.

Bạn chọn vùng lập công thức Sau đó vào Home -> Format -> Chọn Format Cells-> hiện ra hộp thoại chọn Number -> Chọn định dạng là General->ok
Sau đó lập công thức của bạn lại tại ô đó

 

[kiet321]

Anh chị cho em hỏi để thiết kế như file bên dưới thì mình phải học phần nào ạ.

 

[Let'GâuGâu]

Anh chị cho em hỏi để thiết kế như file bên dưới thì mình phải học phần nào ạ.

BẠN chọn tất cả các cột mà bạn không muốn nó hiển thị nhấp chuột phải chọn column with rối set nó =0
tương tư như vậy là cho các dòng còn lại

để bỏ các thanh, bạn vào tab File-->option-->advance---> mục display, bạn muốn bỏ cái gì thì gởi bỏ tick của ô đó,,,,cứ thử từng cái sẻ biết

 

[binhvandk]

Mấy anh chị làm giúp em lọc ngày tháng trong file bên dưới với

 

[thanhsangnguyen1982]

Mấy anh chị làm giúp em lọc ngày tháng trong file bên dưới với

Công thức tại ô D27 =COUNTIF($B$3:$B$22;">="&DATE(2013;8;5))
Công thức tại ô E27 =SUMPRODUCT(MAX(IF((LEFT($H$3:$H$22;2)="HU")*($B$3:$B$22<=DATE(2013;8;10));$D$3:$D$22;0))) kết thúc công thúc công thức bằng tổ hợp phím Ctrl Shift Enter (Vì là công thức mảng)

 

[duongvannam27]

Thống kê trung bình theo điều kiện khó quá anh chị giúp em với.

Câu 5: Tính trung bình số lượng bán ra của những khách mua mà có thành tiền VNĐ lớn hơn trung bình mức thành tiền VNĐ của tất cả khách hàng trong bảng (1đ)
Đã có anh chị trong diễn đàn hướng dẫn em là =AVERAGEIF($K$5:$K$14,">"&$E$41,$H$5:$H$14)
tuy nhiên e tính nhẫm thì chỉ có 3 KH là có số tiền lớn hơn mức trung bình và số lượng đúng phải ra là 45 mới đúng. Mong các bạn hướng dẫn lại dùm em xin cám ơn!

 

[hotdevil_cr7]

giúp em bài này với ạ. em xin cảm ơn

 

[thanhsangnguyen1982]

giúp em bài này với ạ. em xin cảm ơn

Công thức tại các ô:
C2 =LOOKUP(LEFT($B2,1),{"D","N","X"},{"Dầu","Nhớt","Xăng"})
D2 =LOOKUP(RIGHT($B2,2),{"BP","CA","ES","MO","SH","TN"},{"British Petro","Castrol","Esso","Mobil","Shell","Trong nước"})
E2 =LOOKUP(LEFT($B2,1),{"D","N","X"},{1400,2500,4500})
G2 =($E2*$F2)*(LOOKUP(LEFT($B2,1),{"D","N","X"},{0.025,0.02,0.03}))
H2 =$E2*$G2
Ngoài cách này bạn có thể dùng hàm if để giải các câu trên và một số cách khác (Bạn tự nghiên cứu)


Trong công thức nếu báo lỗi thì thay dấu , bằng dấu ; trong mỗi đối số của công thức nha bạn

 

[leonguyenz]

Công thức tại các ô:
C2 =LOOKUP(LEFT($B2,1),{"D","N","X"},{"Dầu","Nhớt","Xăng"})
D2 =LOOKUP(RIGHT($B2,2),{"BP","CA","ES","MO","SH","TN"},{"British Petro","Castrol","Esso","Mobil","Shell","Trong nước"})
E2 =LOOKUP(LEFT($B2,1),{"D","N","X"},{1400,2500,4500})
G2 =($E2*$F2)*(LOOKUP(LEFT($B2,1),{"D","N","X"},{0.025,0.02,0.03}))
H2 =$E2*$G2
Ngoài cách này bạn có thể dùng hàm if để giải các câu trên và một số cách khác (Bạn tự nghiên cứu)
Trong công thức nếu báo lỗi thì thay dấu , bằng dấu ; trong mỗi đối số của công thức nha bạn

Mình nghĩ đây là bài tập tin căn bản, LOOKUP thì quá tầm. Bài này chủ yếu là tập luyện IF, LEFT, RIGHT và các toán tử:
C2: =IF(LEFT(B2,1)="X","Xăng",IF(LEFT(B2,1)="D","Dầu","Nhớt"))
D2: =IF(RIGHT(B2,2)="BP","British Petro",IF(RIGHT(B2,2)="MO","Mobil",IF(RIGHT(B2,2)="ES","Esso",IF(RIGHT(B2,2)="SH","Shell",IF(RIGHT(B2,2)="CA","Castrol","Trong nước")))))
E2: =IF(C2="Xăng",4500,IF(C2="Dầu",1400,2500))
G2: =IF(D2="Trong nước",0,IF(C2="Xăng",3%,IF(C2="Dầu",2.5%,2%)))
H2: =E2*F2*(1+G2)
Câu Thành tiền: sao lại là nguyên giá * thuế? Phải là nguyên giá + thuế chứ?

 

[minhtu10385]

Bạn thử xem file của mình xem. Thuế thì ok. Nhưng yêu cầu số 5 mình không hiểu