Cách đặt đơn vị Inches, Centimeters

[thuong_mdc80]

Chào các bạn
Cách đặt đơn vị Inches, Centimeters trong Ex ?
Cảm ơn!

 

[PhanTuHuong]

Theo tôi biết, Word thì có nhưng Excel lại không. Cũng chẳng hiểu tại sao??

 

[OverAC]

Trong word thì mọi thứ được canh lề theo kích thước trang, và dùng đó làm chuẩn, còn trong Excel do tính chất là bảng tính cho nên việc trình bày và in ấn không theo chuẩn đó. Trong Excel bạn có thể điều chỉnh khổ in có kích thước phóng to thu nhỏ theo ý muốn. Việc phóng to theo ý muốn như vậy thì liệu dùng đơn vị do kích thước có ý nghĩa gì đâu. Quan trọng là trong nội bộ file đó có tỷ lệ cân đối thế nào thôi.

 

[nvson]

Calc của OpenOffice có chức năng này còn Excel của MS thì không.
Nhưng nếu bạn muốn thay đổi độ rộng của cột và chiều cao của hàng dùng đơn vị là Milimeter thì hãy dùng VBA.

......
Đầu tiên các bạn copy đoạn mã sau vào module của bạn (tên module tùy bạn):

Sub SetColumnWidthMM(ColNo As Long, mmWidth As Integer) 
' Thay doi chieu rong cot sang mm
Dim w As Single 
If ColNo < 1 Or ColNo > 255 Then Exit Sub 
Application.ScreenUpdating = False 
w = Application.CentimetersToPoints(mmWidth / 10) 
While Columns(ColNo + 1).Left - Columns(ColNo).Left - 0.1 > w 
Columns(ColNo).ColumnWidth = Columns(ColNo).ColumnWidth - 0.1 
Wend 
While Columns(ColNo + 1).Left - Columns(ColNo).Left + 0.1 < w 
Columns(ColNo).ColumnWidth = Columns(ColNo).ColumnWidth + 0.1 
Wend 
End Sub 
Sub SetRowHeightMM(RowNo As Long, mmHeight As Integer) 
' Thay doi chieu cao cot sang mm
If RowNo < 1 Or RowNo > 65536 Then Exit Sub 
Rows(RowNo).RowHeight = Application.CentimetersToPoints(mmHeight / 10) 
End Sub

Giả sử rằng bạn muốn rằng khi Right Click vào một ô nào ở sheet1 để thay đổi độ rộng của cột hay độ cao của hàng thì bạn hãy chép đoạn mã sau và dán vào mã của sheet1:

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean) 
Dim bNumber As Integer, bText As String 
' Dung phuong thuc (Method) INPUTBOX chi de nhan so thoi
On Error GoTo Thongbao1 
bText = Application.InputBox("Ban muon thay doi do Rong cot hay chieu Cao cua hang (R/C)?" , "Ban chi nhap vao R hay C", 2) 
bText = UCase(bText) 
Select Case bText 
Case "R" 
On Error GoTo Thongbao2 
bNumber = Application.InputBox("Xin ban nhap vao do rong cua cot (mm)" , "Ban chi nhap vao so tu nhien thoi", 1) 
Call SetColumnWidthMM(Target.Column, bNumber) 
Case "C" 
On Error GoTo Thongbao2 
bNumber = Application.InputBox("Xin ban nhap vao do cao cua hang (mm)" , "Ban chi nhap vao so tu nhien thoi", 1) 
Call SetRowHeightMM(Target.Row, bNumber) 
Case Else 
On Error GoTo Thongbao2 
MsgBox "Xin ban chi nhap vao R hay C ma thoi !", vbOKOnly, "Thong bao" 
End Select 
Cancel = True 
Exit Sub 
Thongbao1: 
MsgBox "Ban chi go vao R (Rong) hay C (Cao) thoi !", vbOKOnly, "Thong bao" 
Cancel = True 
Exit Sub 
Thongbao2: 
MsgBox "Ban chi go vao so ma thoi !", vbOKOnly, "Thong bao" 
Cancel = True 
Exit Sub 
End Sub

Vậy, bây giờ bạn có thể trở về màn hình Excel để thử xem sao.
Chúc các bạn thành công.
Lê Văn Duyệt

Chi tiết các bạn xem tại đây!
(Quảng cáo hộ anh Duyệt đấy nhé!)