Các phương pháp tách họ và tên đề nghị post ở đây

[huuthang_bd]

Ngắn hơn chút:

=LOOKUP(2,1/COUNTIF(B3,{"*","*thị*","*văn*"}),{"Phân loại sau","Nữ","Nam"})

Theo em thì công thức của anh ndu nên sửa lại như thế này để tránh sai trong các trường hợp họ hoặc tên có chuỗi "Văn" hoặc "Thị" như Trần Quốc Thịnh, Nguyễn Thơ Văn.

=LOOKUP(2,1/COUNTIF(B3,{"*","* thị *","* văn *"}),{"Phân loại sau","Nữ","Nam"})

 

[phanquocviet1988]

Có thể dùng công thức sau:

=IF(MID(B3,FIND(" ",B3)+1,3)="Văn","nam",IF(MID(B3,FIND(" ",B3)+1,3)="Thị","nữ","phan loai sau"))

nếu tên họ là "nguyễn trần văn hùng" thì dùng ko dc bác ơi
bác có thể giải thích hàm bác dùng dc ko?

 

[ninhtom1]

Nhờ các anh chị chỉ giúp về chuỗi ký tự

Em có dùng hàm để cắt các ký tự sau dấu "-" của 1 chuỗi. Lỗi xảy ra khi chuỗi không có dấu "-". Mong nhờ các anh chị chỉ giúp. Em xin chân thành cảm ơn ạ.

 

[Quang_Hải]

Em có dùng hàm để cắt các ký tự sau dấu "-" của 1 chuỗi. Lỗi xảy ra khi chuỗi không có dấu "-". Mong nhờ các anh chị chỉ giúp. Em xin chân thành cảm ơn ạ.

Sửa lại thế này
=IF(ISERROR(FIND("-",B4,1)),B4,LEFT(B4,FIND("-",B4,1)-2))

 

[ninhtom1]

Cảm ơn bác nhiều nhé, chính xác rồi. Nhưng nhờ bác dịch hộ câu lệnh trên được không ?

 

[hoamattroicoi]

Cảm ơn bác nhiều nhé, chính xác rồi. Nhưng nhờ bác dịch hộ câu lệnh trên được không ?

=IF(ISERROR(FIND("-",B4,1)),B4,LEFT(B4,FIND("-",B4,1)-2))
Dịch là :
Nếu không tìm thấy ký tự "-" của chuỗi đặt trong ô B4 thì trả về giá trị của ô B4 còn lại thì sẽ trích ra những ký tự nằm bên trái dấu "-"

 

[NHT2000]

Có cách nào lấy Chữ lót và tên (không lấy họ) được không bạn?
Ví dụ: phòng Công nghê Thông tin
chỉ lấy: Công nghệ Thông tin thôi, bỏ chữ phòng đi ấy!

Thân.

 

[bebo021999]

Có cách nào lấy Chữ lót và tên (không lấy họ) được không bạn?
Ví dụ: phòng Công nghê Thông tin
chỉ lấy: Công nghệ Thông tin thôi, bỏ chữ phòng đi ấy!

Thân.

Dùng
=MID(A1,FIND(" ",A1)+1,255)

 

[simonp]

Có cách nào tách được tên ra khỏi chữ lót không ạ ! ví dụ: Trần Thị KimNga là sao tách ra được là Trần Thị Kim Nga
Thân

 

[Quang_Hải]

Có cách nào tách được tên ra khỏi chữ lót không ạ ! ví dụ: Trần Thị KimNga là sao tách ra được là Trần Thị Kim Nga
Thân

Cái này dùng code thì đơn giản, công thức thì pótay

 

[huuthang_bd]

Có cách nào tách được tên ra khỏi chữ lót không ạ ! ví dụ: Trần Thị KimNga là sao tách ra được là Trần Thị Kim Nga
Thân

Nếu bạn dùng bản mã VNI Windows thì có thể dùng công thức như trong file đính kèm.

 

[quandrc]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

 

[xuan.nguyen82]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

=LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))

Với A1 chứa chuỗi đó.

 

[ndu96081631]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

Tạm thời nghĩ ra được cái này:

=LOOKUP(2,1/(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)= " "),LEN(A1)+1-ROW(INDIRECT("1:"&LEN(A1))))

 

[concogia]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

"Rặn" ra thêm một cách

=LEN(TRIM(RIGHT(SUBSTITUTE(TRIM(A1)," ",REPT(" ",LEN(A1))),LEN(A1))))+1

Híc, lỡ ký tự cuối cùng là khoảng trắng thì lấy thứ tự là 1 hay loại khoảng trắng vô nghĩa đó nhỉ ???
Thân

 

[nghiaphuc]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

Nếu có nhu cầu sử dụng nhiều việc tìm kiếm này thì có thể xây dựng hàm tự tạo (xem như một tham khảo cho vui):
[GPECODE=vb]Function mFind(c As String, S As String, Optional Rev As Boolean = False) As Long
If Rev Then S = StrReverse(S)
mFind = InStr(S, c)
End Function[/GPECODE]
Cú pháp: =mFind(c,S,Rev)
Trong đó: c là chuỗi cần tìm; S là chuỗi gốc; Rev là tùy chọn hướng tìm: Nếu là True (hoặc 1) thì tìm từ bên phải, nếu là False (hoặc 0, hoặc để trống) thì tìm từ bên trái.
Chức năng hàm này giống hàm Find trên Excel, chỉ bổ sung thêm hướng tìm.

Với ví dụ trên, có thể lập công thức thế này: =mFind(" ",A1,1) với A1 là ô chứa chuỗi gốc.

 

[ndu96081631]

"Rặn" ra thêm một cách

=LEN(TRIM(RIGHT(SUBSTITUTE(TRIM(A1)," ",REPT(" ",LEN(A1))),LEN(A1))))+1

Híc, lỡ ký tự cuối cùng là khoảng trắng thì lấy thứ tự là 1 hay loại khoảng trắng vô nghĩa đó nhỉ ???
Thân

Anh ơi! Nếu chuổi không có khoảng trắng nào thì nó cho kết quả sai
Thà rằng bị lỗi, chứ kết quả sai thì không thể chấp nhận
Bài này đương nhiên dùng VBA là quá dễ rồi

 

[concogia]

Anh ơi! Nếu chuổi không có khoảng trắng nào thì nó cho kết quả sai
Thà rằng bị lỗi, chứ kết quả sai thì không thể chấp nhận
Bài này đương nhiên dùng VBA là quá dễ rồi

Híc, nếu xảy ra trường hợp không có khoảng trắng nào trong chuỗi thì làm 2 việc:
1)- Bẫy lỗi cho công thức
2)- "Phang" cho chủ nhân của chuỗi một câu: "dzô dziên bà cố"
Híc, Thầy Ndu chưa...............rửa màu áo đó à nha, tính "để lầu ............hóa bùn" hả ??????????

 

[VMH0307]

Có hàm nào tìm ký tự trắng đầu tiên từ phải sang không các bạn ?. Nhờ các bạn chỉ giúp...!
ví dụ: ký tự trắng đầu tiên trong chuổi ký tự " Nhờ các bạn chỉ giúp" là: thứ 5

Thử thêm cách nữa xem:
Đếm xuôi từ trái sang phải:

=MAX((MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)=" ")*ROW(INDIRECT("1:"&LEN(A1))))

Đếm từ phải qua trái:

=(LEN(A1)-MAX((MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)=" ")*ROW(INDIRECT("1:"&LEN(A1)))))*(LEN(A1)<>LEN(SUBSTITUTE(A1," ","")))+1

 

[Good-Luck]

đếm vị trí ký tự trắng cuoi cung (tức từ phải sang trái thì là ký tự đầu tiên)

=LEN(A1)-FIND("_",SUBSTITUTE(A1," ","_",(LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))+1

đếm vị trí ký tự trắng cuối cùng (tức từ trái sang phải thì là ký tự trắng cuối cùng)

=FIND("_",SUBSTITUTE(A1," ","_",(LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))