Điền số lượng vào hóa đơn đã xuất

[pekute1990]

Dạ chào anh chị!
Nhờ anh chị hổ trợ em giúp vấn đề sau ạ.
Em có dữ liệu là bảng chi tiết hóa đơn đã xuất. Khách trả hàng về. Em muốn điền số lượng hàng hóa tương ứng theo hóa đơn xuất từ trên xuống dưới ạ. Cảm ơn anh chị

 

[hoangtuaotrang_hp_vn]

Dạ chào anh chị!
Nhờ anh chị hổ trợ em giúp vấn đề sau ạ.
Em có dữ liệu là bảng chi tiết hóa đơn đã xuất. Khách trả hàng về. Em muốn điền số lượng hàng hóa tương ứng theo hóa đơn xuất từ trên xuống dưới ạ. Cảm ơn anh chị

Dùng tạm cách này (chưa tối ưu lắm)

F2=MIN(SUMIFS($B$10:$B$11,$A$10:$A$11,B2),SUMIFS($C$2:C2,$B$2:B2,B2))

F3=MIN((SUMIFS($B$10:$B$11,$A$10:$A$11,B3)-SUMIFS($F$2:F2,$B$2:B2,B3)),SUMIFS($C$3:C3,$B$3:B3,B3))

rồi kéo xuống

 

[Phan Thế Hiệp]

(chưa tối ưu lắm)

Thử vầy: ô D2

=MIN(MAX(SUMIF(A$10:A$15,B2,B$10)-SUMIF(B$1:B1,B2,C$1),),C2)

Enter, fill xuống.

 

[cantl]

Cách phổ cập giáo dục:
E2=MIN(VLOOKUP(B2,A$10:B$11,2,0)-SUMIF(B$1:B1,B2,E$1:E1),C2)

Thử vầy: ô D2

=MIN(MAX(SUMIF(A$10:A$15,B2,B$10)-SUMIF(B$1:B1,B2,C$1),),C2)

Enter, fill xuống.

Sao cái công thức của bác, em chả hiểu cách hoạt động thế nào luôn. Mà lại chuẩn.

 

[pekute1990]

Em làm được rồi ạ, cảm ơn mọi người ạ!

 

[Phan Thế Hiệp]

Cách phổ cập giáo dục:
E2=MIN(VLOOKUP(B2,A$10:B$11,2,0)-SUMIF(B$1:B1,B2,E$1:E1),C2)


Sao cái công thức của bác, em chả hiểu cách hoạt động thế nào luôn. Mà lại chuẩn.

1/ Vlookup() chỉ tìm được dòng đầu tiên, Sumif() có thể gom cộng cùng 1 mã hàng có nhiều lần trả hàng, bao quát hơn.

2/ Sumif() chỉ cần định vùng ở mệnh đề đầu tiên, Vd: A10: A15, mệnh đề cuối chỉ cần ghi ô đầu tiên, Vd: B10, nó sẽ tự động tìm vùng tương ứng với mệnh đề đầu, tức nó sẽ là B10: B15.

3/ Nếu không dùng Max(....,0), khi có trường hợp số lượng hàng trả (SUMIF(A$10:A$15,B2,B$10)) < số lượng hàng trả cộng dồn (SUMIF(B$1:B1,B2,C$1)), thì nó ra kết quả số âm.

Thân

 

[cantl]

Sumif()

Chà, món này lạ, nếu không có bài này thì em cứ đi theo lối mòn là kéo cả dãy ô.
Về số âm thì đúng là lúc em dùng vlookup không trừ đi kết quả cùng cột mà dùng cột như của bác thì đúng là bị âm thật.
Thật là bá đạo.