Đếm số xe bỏ trùng lập và nhiều điều kiện

[kingsouth]

Các anh chị giúp em với, em muốn đếm số xe bỏ trùng lập trong bảng TH kèm nhiều điều kiện như sheet Data MOT, HÌNH THỨC, THÁNG
Em có dùng hàm =SUMPRODUCT((DATA!C2:C64<>"")*(1/COUNTIF(DATA!C2:C64;DATA!C2:C64));(DATA!O2:O64="HM");(DATA!E2:E64="H02")) nhưng không được
Cám ơn các anh chị

 

[dazkangel]

Các anh chị giúp em với, em muốn đếm số xe bỏ trùng lập trong bảng TH kèm nhiều điều kiện như sheet Data MOT, HÌNH THỨC, THÁNG
Em có dùng hàm =SUMPRODUCT((DATA!C2:C64<>"")*(1/COUNTIF(DATA!C2:C64;DATA!C2:C64));(DATA!O2:O64="HM");(DATA!E2:E64="H02")) nhưng không được
Cám ơn các anh chị

Thử công thức sau, copy qua các ô tháng khác đều được.

=IF($B4="","",SUMPRODUCT(N(ISNUMBER((DATA!$P$2:$P$64=C$1)/(DATA!$O$2:$O$64=LOOKUP(2,1/($B$3:$B3=""),$A$3:$A3))/SEARCH($A4,DATA!$E$2:$E$64)^0))))

 

[excel_lv1.5]

Các anh chị giúp em với, em muốn đếm số xe bỏ trùng lập trong bảng TH kèm nhiều điều kiện như sheet Data MOT, HÌNH THỨC, THÁNG
Em có dùng hàm =SUMPRODUCT((DATA!C2:C64<>"")*(1/COUNTIF(DATA!C2:C64;DATA!C2:C64));(DATA!O2:O64="HM");(DATA!E2:E64="H02")) nhưng không được
Cám ơn các anh chị

Bạn dùng công thức mảng này ở C4:

C4=COUNT(MATCH(ROW(DATA!$A$1:$A$64),(C$1=DATA!$P$2:$P$64)*(DATA!$O$2:$O$64=LOOKUP("z",$A$3:$A4))*("H"&TEXT($A4,"00")=DATA!$E$2:$E$64)*MATCH(DATA!$C$2:$C$64,DATA!$C$2:$C$64,),))

Yêu cầu bấm Ctrl+Shift+Enter rồi copy xuống!!!

Thử công thức sau, copy qua các ô tháng khác đều được.

=IF($B4="","",SUMPRODUCT(N(ISNUMBER((DATA!$P$2:$P$64=C$1)/(DATA!$O$2:$O$64=LOOKUP(2,1/($B$3:$B3=""),$A$3:$A3))/SEARCH($A4,DATA!$E$2:$E$64)^0))))

Công thức này chưa loại trùng!!!

 

[batman1]

Hoặc merge các ô hoặc không. Không thể hổ lốn được. Tôi đề nghị không merge. Tức hàng 1 bỏ merge và nhập vào C1, E1, G1, ... các số 1, 2, 3, ...
Công thức cho C4

=SUM(--(FREQUENCY(IF((DATA!$O$2:$O$64=LOOKUP("zzz",$A$1:$A4))*(DATA!$E$2:$E$64="H"&TEXT($A4,"00"))*(DATA!$P$2:$P$64=C$1),MATCH(DATA!$C$2:$C$64,DATA!$C$2:$C$64,0)),ROW($1:$63))>0))

Công thức kết thúc bởi Ctrl+Shift+Enter

chọn C4 -> Ctrl+C -> chọn lần lượt E4, G4, ... và sau mỗi lần chọn thì Ctrl+V
Công thức C4, E4, G4, ... copy xuống dưới.

Nhưng chả lý gì lại phải có 0 khi cột B rỗng (ứng với GMD, TIỀN GIANG, VL, ... tại cột A). Vì thế tôi đề nghị công thức cho C4

=IF($B4="","",SUM(--(FREQUENCY(IF((DATA!$O$2:$O$64=LOOKUP("zzz",$A$1:$A4))*(DATA!$E$2:$E$64="H"&TEXT($A4,"00"))*(DATA!$P$2:$P$64=C$1),MATCH(DATA!$C$2:$C$64,DATA!$C$2:$C$64,0)),ROW($1:$63))>0)))

 

[HieuCD]

Các anh chị giúp em với, em muốn đếm số xe bỏ trùng lập trong bảng TH kèm nhiều điều kiện như sheet Data MOT, HÌNH THỨC, THÁNG
Em có dùng hàm =SUMPRODUCT((DATA!C2:C64<>"")*(1/COUNTIF(DATA!C2:C64;DATA!C2:C64));(DATA!O2:O64="HM");(DATA!E2:E64="H02")) nhưng không được
Cám ơn các anh chị

Dùng cột phụ cho đơn giản và nhẹ file

 

[kingsouth]

cám ơn các anh chị emlàm được rồi