Tìm hàm thể hiện giá trị tên chữ cái của một cột !!

[quangthanhdu]

Mọi người cho mình hỏi, trong excel có hàm nào, hay có cách nào mình lấy tên chữ cái của một cột không? (không quan tâm tới dòng thứ bao nhiêu). ví dụ: dòng thứ bất kỳ của cột A sẽ là chữ cái A, hay dòng thứ bất kỳ của cột UU sẽ là chữ cái UU...

 

[ndu96081631]

Mọi người cho mình hỏi, trong excel có hàm nào, hay có cách nào mình lấy tên chữ cái của một cột không? (không quan tâm tới dòng thứ bao nhiêu). ví dụ: dòng thứ bất kỳ của cột A sẽ là chữ cái A, hay dòng thứ bất kỳ của cột UU sẽ là chữ cái UU...

Dùng công thức này:

=SUBSTITUTE(ADDRESS(1,COLUMN(J1),4),1,"")

Nó sẽ lấy tên của cột J
Muốn lấy tên cột tại vị trí hiện hành thì

=SUBSTITUTE(ADDRESS(1,COLUMN(),4),1,"")

 

[Quang Tinh]

Có thể dùng công thức này:
Left(address(1;column();4))

 

[ndu96081631]

Có thể dùng công thức này:
Left(address(1;column();4))

Công thức này sai nha!
Bạn thử đặt công thức này tại cell AB1 xem!

 

[Quang Tinh]

quên là có cột có hai chữ số nữa thế nếu dùng left nữa chắc phải dài hơn bác Ndu nhỉ
ví dụ thế này: =LEFT(ADDRESS(1;COLUMN();2);FIND("$";ADDRESS(1;COLUMN();2))-1)

 

[sealand]

Thêm 1 cách, nếu cột ít ít thôi ta có thể dùng:

=CHAR(64+COLUMN(Ref.))

Công thức chung:

=CHOOSE(INT(COLUMN(A1)/27)+1,"","A","B","C","D","E","F","G","H","I")&CHAR(65+MOD(COLUMN(A1)-1,26))

Neu là ô chứa công thức hay cột chứa công thức ta bỏ tham chiếu đi:

=CHOOSE(INT(COLUMN()/27)+1,"","A","B","C","D","E","F","G","H","I")&CHAR(65+MOD(COLUMN()-1,26))

 

[Lê Duy Thương]

thêm 1 cách, nếu cột ít ít thôi ta có thể dùng:

=char(64+column(ref.))

cái của bác cũng hay, nếu cột là 1 chữ cái
nhưng công thức của ndu là hoàn hảo hơn kể khi sử dụng ở bất kỳ loại office đang có
nếu không ai thích công thức ngắn như của NDU thì tôi cũng xin góp thêm 1 công thức cho phong phú GPE mặc dù biết không thể ngắn bằng công thức của bác NDU
=LEFT(ADDRESS(ROW(),COLUMN(),2),FIND("$",ADDRESS(ROW(),COLUMN(),2))-1)

 

[Hieu07061984]

Còn thêm 1 cách nửa:
=LEFT(ADDRESS(1,COLUMN(),4),IF(LEN(ADDRESS(1,COLUMN(),4))=2,1,2))

 

[Lê Duy Thương]

Còn thêm 1 cách nửa:
=LEFT(ADDRESS(1,COLUMN(),4),IF(LEN(ADDRESS(1,COLUMN(),4))=2,1,2))

cái này chỉ đúng đối với excel 2003 trở về trước thôi nha
còn từ 2007 đến 2010 thì sai đấy
xem hình nhé