Nhờ tìm lỗi trong công thức đếm (loại bỏ đếm trùng)

[tuanqnbd]

Chào mọi người,
Mình có tham khảo công thức đếm nhưng loại bỏ đếm trùng tại Link này, đặc biệt là công thức ở cuối thread đó nhưng khi áp dung vào bài của mình thì không ra kết quả. Nhờ các anh/chị hỗ trợ giải thích bị sai ở điểm nào, nghĩ mãi mà vẫn không biết tại sao

Rất cám ơn

 

[befaint]

F2=SUM(IFERROR(($C$2:$C$24=H2)/COUNTIFS($C$2:$C$24,H2,$B$2:$B$24,$B$2:$B$24),0))
'Hoặc:'
F2=SUM(IF(FREQUENCY(IF($C$2:$C$24=H2,MATCH(B$2:B$24,B$2:B$24,0)),ROW(B$2:B$24)-ROW(B$2)+1),1))
'Nhớ ấn Ctrl + Shift + Enter

 

[tuanqnbd]

Cám ơn bạn, mình vẫn thử mày mò sumproduct xem có đc kg

 

[Phan Thế Hiệp]

Cám ơn bạn, mình vẫn thử mày mò sumproduct xem có đc kg

Bạn muốn Sumproduct() thì thay hàm Sum() như anh @befaint hướng dẫn tại bài #2 là được rồi, nhưng cũng phải nhấn Ctrl+Shift+Enter khi kết thúc.
Tôi bổ sung thêm một số công thức loại trùng để bạn tiện tham khảo và "ngâm cứu"
1/ Kết thúc bằng Enter:

=SUMPRODUCT(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))

2/ Kết thúc bằng Ctrl+Shift+Enter:

=COUNT(1/(MATCH($B$4:$B$26,IF($C$4:$C$26=E4,$B$4:$B$26),)=ROW($1:$23)))
=SUM(IFERROR(($C$4:$C$26=E4)/COUNTIFS($C$4:$C$26,E4,$B$4:$B$26,$B$4:$B$26),0))
=SUM(--(FREQUENCY(IF($C$4:$C$26=E4,MATCH(B$4:B$26,B$4:B$26,0)),ROW($1:$23))>0))
=SUM(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))
=COUNT(1/(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))
=COUNT(1/(MATCH($A$4:$A$26&$B$4:$B$26,$A$4:$A$26&$B$4:$B$26,)=ROW($1:$23))/(E4=$C$4:$C$26))

​

Thân​

 

[khi ta 20]

Bạn muốn Sumproduct() thì thay hàm Sum() như anh @befaint hướng dẫn tại bài #2 là được rồi, nhưng cũng phải nhấn Ctrl+Shift+Enter khi kết thúc.
Tôi bổ sung thêm một số công thức loại trùng để bạn tiện tham khảo và "ngâm cứu"
1/ Kết thúc bằng Enter:

=SUMPRODUCT(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))

2/ Kết thúc bằng Ctrl+Shift+Enter:

=COUNT(1/(MATCH($B$4:$B$26,IF($C$4:$C$26=E4,$B$4:$B$26),)=ROW($1:$23)))
=SUM(IFERROR(($C$4:$C$26=E4)/COUNTIFS($C$4:$C$26,E4,$B$4:$B$26,$B$4:$B$26),0))
=SUM(--(FREQUENCY(IF($C$4:$C$26=E4,MATCH(B$4:B$26,B$4:B$26,0)),ROW($1:$23))>0))
=SUM(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))
=COUNT(1/(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))
=COUNT(1/(MATCH($A$4:$A$26&$B$4:$B$26,$A$4:$A$26&$B$4:$B$26,)=ROW($1:$23))/(E4=$C$4:$C$26))

​

Thân​

Thêm cái này luôn cho đủ bộ nha anh
E4=IFERROR(INDEX($C$4:$C$26,MATCH(,INDEX(COUNTIF($E$3:E3,$C$4:$C$26),,)),),"")

 

[Phan Thế Hiệp]

Thêm cái này luôn cho đủ bộ nha anh
E4=IFERROR(INDEX($C$4:$C$26,MATCH(,INDEX(COUNTIF($E$3:E3,$C$4:$C$26),,)),),"")

Khà khà khà!


Công thức này chỉ liệt kê danh sách loại bỏ trùng lắp và nó chạy theo từng dòng, chứ nó không có đếm trên 1 mảng loại bỏ trùng lắp, em trai!

Thân

 

[tuanqnbd]

Cám ơn mọi người

 

[MeThuongNho]

Bạn muốn Sumproduct() thì thay hàm Sum() như anh @befaint hướng dẫn tại bài #2 là được rồi, nhưng cũng phải nhấn Ctrl+Shift+Enter khi kết thúc.
Tôi bổ sung thêm một số công thức loại trùng để bạn tiện tham khảo và "ngâm cứu"
1/ Kết thúc bằng Enter:

=SUMPRODUCT(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))

Thân

Sumproduct tăng vùng lên thì bị lỗi #N/A.
Mong mọi người chỉ giúp

 

[Hoàng Tuấn 868]

Sumproduct tăng vùng lên thì bị lỗi #N/A.
Mong mọi người chỉ giúp

Bạn gửi file bị lỗi lên nhé.

 

[MeThuongNho]

Bạn gửi file bị lỗi lên nhé.

Dạ cám ơn Anh,
Em gửi file nhờ Anh và mọi người chỉ giúp.

=SUMPRODUCT(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))

Trân trọng!

 

[Phan Thế Hiệp]

Dạ cám ơn Anh,
Em gửi file nhờ Anh và mọi người chỉ giúp.

=SUMPRODUCT(N(FREQUENCY(MATCH($B$4:$B$26,$B$4:$B$26,)*($C$4:$C$26=E4),ROW($1:$23))>0))

Trân trọng!

Bạn nên dùng COUNT(1/(Mệnh đề điều kiện) ) dễ hơn, và không cần suy nghĩ thêm:

=COUNT(1/(MATCH($C$5:$C$1000,IF($A$5:$A$1000=G$2,$C$5:$C$1000),)=ROW($1:$1001)))

Bạn để ý thấy: tổng số dòng của các vùng tham chiếu, từ dòng 5 đến 1000 = 996 dòng, so với số dòng của Row(1: 1001) là 1001 dòng, tuy có sự khác biệt, nhưng hàm COUNT() sẽ phớt lờ dùm cho bạn.

Thân

 

[MeThuongNho]

Bạn nên dùng COUNT(1/(Mệnh đề điều kiện) ) dễ hơn, và không cần suy nghĩ thêm:

=COUNT(1/(MATCH($C$5:$C$1000,IF($A$5:$A$1000=G$2,$C$5:$C$1000),)=ROW($1:$1001)))

Bạn để ý thấy: tổng số dòng của các vùng tham chiếu, từ dòng 5 đến 1000 = 996 dòng, so với số dòng của Row(1: 1001) là 1001 dòng, tuy có sự khác biệt, nhưng hàm COUNT() sẽ phớt lờ dùm cho bạn.

Thân

Dạ cám ơn Anh nhiều.
Thân!