Xin giúp đỡ cho công thức kết hợp hàm OFFSET ạ

[HaViVi]

Xin các cao thủ chỉ giáo giúp em ạ. Em có file cần tính doanh thu của các mặt hàng theo khoảng thời gian mong muốn
Khi e tách rời CT thì hàm ra giá trị OK nhưng khi kết hợp lại thì không nhận diện được ạ
Chi tiết các bác xem file đính kèm và chỉ giáo giúp em ạ
Đa tạ các bác.

 

[huonglien1901]

Xin các cao thủ chỉ giáo giúp em ạ. Em có file cần tính doanh thu của các mặt hàng theo khoảng thời gian mong muốn
Khi e tách rời CT thì hàm ra giá trị OK nhưng khi kết hợp lại thì không nhận diện được ạ
Chi tiết các bác xem file đính kèm và chỉ giáo giúp em ạ
Đa tạ các bác.

=SUM(OFFSET($G5,0,MATCH($C$2,$G$4:$AJ$4,0)-1,1,MATCH($E$2,$G$4:$AJ$4,0)-1))
Thấy bạn có công thức ra đúng mà, chưa hiểu ý bạn làm gì nữa?

 

[HaViVi]

=SUM(OFFSET($G5,0,MATCH($C$2,$G$4:$AJ$4,0)-1,1,MATCH($E$2,$G$4:$AJ$4,0)-1))
Thấy bạn có công thức ra đúng mà, chưa hiểu ý bạn làm gì nữa?

SUM(OFFSET(ADDRESS(MATCH($B$5,$F:$F,0),COLUMN($G:$G),3),0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))
Nhưng khi mình kết hợp 2 công thức lại thì nó k nhận diện công thức

 

[Lê Hồng Minh83]

SUM(OFFSET(ADDRESS(MATCH($B$5,$F:$F,0),COLUMN($G:$G),3),0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))
Nhưng khi mình kết hợp 2 công thức lại thì nó k nhận diện công thức

Bạn thiếu 1 bước nữa để kết hợp công thức đúng
Hàm ADDRESS cho kết quả $G5 giống $G5 trong công thức của bạn nhưng thực tế nó không giống nhau
Trong công thức

=SUM(OFFSET($G5,0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

thì $G5 nó sẽ trả về giá trị ô G5 trong khi hàm ADDRESS cho kết quả $G5 nhưng nó chỉ là "nhóm" ký tự ghép lại với nhau, chưa phải là tham chiếu để nhận được giá trị ô cần tham chiếu. Do đó, trong trường hợp này bạn phải sử dụng thêm hàm INDIRECT để chuyển địa chỉ $G5 thành tham chiếu tới ô G5

=SUM(OFFSET(INDIRECT(ADDRESS(MATCH($B$5,$F:$F,0),COLUMN($G$1),3)),0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

 

[HaViVi]

Bạn thiếu 1 bước nữa để kết hợp công thức đúng
Hàm ADDRESS cho kết quả $G5 giống $G5 trong công thức của bạn nhưng thực tế nó không giống nhau
Trong công thức

=SUM(OFFSET($G5,0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

thì $G5 nó sẽ trả về giá trị ô G5 trong khi hàm ADDRESS cho kết quả $G5 nhưng nó chỉ là "nhóm" ký tự ghép lại với nhau, chưa phải là tham chiếu để nhận được giá trị ô cần tham chiếu. Do đó, trong trường hợp này bạn phải sử dụng thêm hàm INDIRECT để chuyển địa chỉ $G5 thành tham chiếu tới ô G5

=SUM(OFFSET(INDIRECT(ADDRESS(MATCH($B$5,$F:$F,0),COLUMN($G$1),3)),0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

À ra vậy. Em cảm ơn bác nhé

 

[hoangtuaotrang_hp_vn]

Bạn thiếu 1 bước nữa để kết hợp công thức đúng
Hàm ADDRESS cho kết quả $G5 giống $G5 trong công thức của bạn nhưng thực tế nó không giống nhau
Trong công thức

=SUM(OFFSET($G5,0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

thì $G5 nó sẽ trả về giá trị ô G5 trong khi hàm ADDRESS cho kết quả $G5 nhưng nó chỉ là "nhóm" ký tự ghép lại với nhau, chưa phải là tham chiếu để nhận được giá trị ô cần tham chiếu. Do đó, trong trường hợp này bạn phải sử dụng thêm hàm INDIRECT để chuyển địa chỉ $G5 thành tham chiếu tới ô G5

=SUM(OFFSET(INDIRECT(ADDRESS(MATCH($B$5,$F:$F,0),COLUMN($G$1),3)),0,MATCH($C$2,$H$4:$AK$4,0)-1,1,MATCH($E$2,$H$4:$AK$4,0)-1))

bác ơi, nhập công thức vào C5 thì OK, nhưng kết quả có vẻ không chính xác (tính tổng các mặt hàng từ ngày đến ngày)

 

[Ba Tê]

bác ơi, nhập công thức vào C5 thì OK, nhưng kéo xuống C6,....C10 thì không ổn ạ, bác chỉ giúp cho file nó hoàn thiện được không ạ

Bài đã được tự động gộp: 17/11/18

Thử với công thức này:

C5 =SUM(OFFSET($F$4;MATCH($B5;$F$5:$F$10;0);$C$2;;$E$2-$C$2+1))

Sort cột B5: C10 theo ý muốn.

 

[Lê Hồng Minh83]

bác ơi, nhập công thức vào C5 thì OK, nhưng kết quả có vẻ không chính xác (tính tổng các mặt hàng từ ngày đến ngày)

Trước đó thì mình không coi bạn kia cần làm cái gì, chỉ giải thích tại sao nó không đúng thôi
Bạn tham khảo 2 cách

=SUM(OFFSET($F$4,MATCH($B5,$F$5:$F$10,0),$C$2,1,$E$2-$C$2+1))

hoặc

=SUMPRODUCT(($F$5:$F$10=$B5)*($G$4:$AJ$4>=$C$2)*($G$4:$AJ$4<=$E$2)*$G$5:$AJ$10)

làm chi mà cho thêm ADDRESS vào nữa cho nó rối thêm

 

[hoangtuaotrang_hp_vn]

Thử với công thức này:

C5 =SUM(OFFSET($F$4;MATCH($B5;$F$5:$F$10;0);$C$2;;$E$2-$C$2+1))

tuyệt vời ạ, cháu cảm ơn chú, mỗi ngày cháu cứ vào ra diễn đàn 1 vài lần để xem có bài post nào hay hay để học, học với thực hành mà mãi vẫn chưa vào đầu được chút nào, cứ mong đợi 1 ngày nào đó giúp được các bạn mới trên diễn đàn mà giờ vẫn là con số "0" hihi,
một lần nữa cháu xin cảm ơn những người nhiệt tình như chú và các anh chị của diễn đàn ạ

 

[Lê Hồng Minh83]

Thử với công thức này:

C5 =SUM(OFFSET($F$4;MATCH($B5;$F$5:$F$10;0);$C$2;;$E$2-$C$2+1))

Sort cột B5: C10 theo ý muốn.

Cách 1 i xì xì của bác Ba tê luôn kìa

 

[Ba Tê]

Cách 1 i xì xì của bác Ba tê luôn kìa

Lì xì nhưng có "móc câu".
Ngày bắt đầu từ G4 không phải là 1, không liên tục (+1) sang phải, -----------> "dính câu".

 

[Lê Hồng Minh83]

Lì xì nhưng có "móc câu".
Ngày bắt đầu từ G4 không phải là 1, không liên tục (+1) sang phải, -----------> "dính câu".

Vụ không liên tục thì OFFSET dính câu thiệt...
Nhưng đối với SUMPRODUCT thì không thành vấn đề, chỉ có trường hợp tính ngắt quãng nhiều khúc thì cần thêm chút điều kiện nữa là được

 

[huonglien1901]

Xin các cao thủ chỉ giáo giúp em ạ. Em có file cần tính doanh thu của các mặt hàng theo khoảng thời gian mong muốn
Khi e tách rời CT thì hàm ra giá trị OK nhưng khi kết hợp lại thì không nhận diện được ạ
Chi tiết các bác xem file đính kèm và chỉ giáo giúp em ạ
Đa tạ các bác.

=SUMIFS(OFFSET($G$4:$AJ$4,MATCH(B5,$F$5:$F$10,),),$G$4:$AJ$4,">="&$C$2,$G$4:$AJ$4,"<="&$E$2)

Gửi tham khảo cho bạn. Cảm ơn một người Anh Cả rất nhiều!